perl/Spot.pm

   1 #
   2 # the dx spot handler
   3 #
   4 # Copyright (c) - 1998 Dirk Koopman G1TLH
   5 #
   6 # $Id$
   7 #
   8
   9 package Spot;
  10
  11 use IO::File;
  12 use DXVars;
  13 use DXDebug;
  14 use DXUtil;
  15 use DXLog;
  16 use Julian;
  17 use Prefix;
  18 use DXDupe;
  19 use Data::Dumper;
  20 use QSL;
  21
  22 use strict;
  23
  24 use vars qw($VERSION $BRANCH);
  25 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  26 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  27 $main::build += $VERSION;
  28 $main::branch += $BRANCH;
  29
  30 use vars qw($fp $statp $maxspots $defaultspots $maxdays $dirprefix $duplth $dupage $filterdef $totalspots $hfspots $vhfspots $maxcalllth);
  31
  32 $fp = undef;
  33 $statp = undef;
  34 $maxspots = 100;                                        # maximum spots to return
  35 $defaultspots = 10;                             # normal number of spots to return
  36 $maxdays = 100;                         # normal maximum no of days to go back
  37 $dirprefix = "spots";
  38 $duplth = 20;                                   # the length of text to use in the deduping
  39 $dupage = 3*3600;               # the length of time to hold spot dups
  40 $maxcalllth = 12;                               # the max length of call to take into account for dupes
  41 $filterdef = bless ([
  42                           # tag, sort, field, priv, special parser
  43                           ['freq', 'r', 0, 0, \&decodefreq],
  44                           ['on', 'r', 0, 0, \&decodefreq],
  45                           ['call', 'c', 1],
  46                           ['info', 't', 3],
  47                           ['by', 'c', 4],
  48                           ['call_dxcc', 'nc', 5],
  49                           ['by_dxcc', 'nc', 6],
  50                           ['origin', 'c', 7, 9],
  51                           ['call_itu', 'ni', 8],
  52                           ['call_zone', 'nz', 9],
  53                           ['by_itu', 'ni', 10],
  54                           ['by_zone', 'nz', 11],
  55                           ['call_state', 'ns', 12],
  56                           ['by_state', 'ns', 13],
  57                           ['channel', 'c', 14],
  58
  59                          ], 'Filter::Cmd');
  60 $totalspots = $hfspots = $vhfspots = 0;
  61
  62 # create a Spot Object
  63 sub new
  64 {
  65         my $class = shift;
  66         my $self = [ @_ ];
  67         return bless $self, $class;
  68 }
  69
  70 sub decodefreq
  71 {
  72         my $dxchan = shift;
  73         my $l = shift;
  74         my @f = split /,/, $l;
  75         my @out;
  76         my $f;
  77
  78         foreach $f (@f) {
  79                 my ($a, $b);
  80                 if (m{^\d+/\d+$}) {
  81                         push @out, $f;
  82                 } elsif (($a, $b) = $f =~ m{^(\w+)(?:/(\w+))?$}) {
  83                         $b = lc $b if $b;
  84                         my @fr = Bands::get_freq(lc $a, $b);
  85                         if (@fr) {
  86                                 while (@fr) {
  87                                         $a = shift @fr;
  88                                         $b = shift @fr;
  89                                         push @out, "$a/$b";  # add them as ranges
  90                                 }
  91                         } else {
  92                                 return ('dfreq', $dxchan->msg('dfreq1', $f));
  93                         }
  94                 } else {
  95                         return ('dfreq', $dxchan->msg('e20', $f));
  96                 }
  97         }
  98         return (0, join(',', @out));
  99 }
 100
 101 sub init
 102 {
 103         mkdir "$dirprefix", 0777 if !-e "$dirprefix";
 104         $fp = DXLog::new($dirprefix, "dat", 'd');
 105         $statp = DXLog::new($dirprefix, "dys", 'd');
 106 }
 107
 108 sub prefix
 109 {
 110         return $fp->{prefix};
 111 }
 112
 113 # fix up the full spot data from the basic spot data
 114 sub prepare
 115 {
 116         # $freq, $call, $t, $comment, $spotter = @_
 117         my @out = @_[0..4];      # just up to the spotter
 118
 119         # normalise frequency
 120         $_[0] = sprintf "%.1f", $_[0];
 121
 122         # remove ssids and /xxx if present on spotter
 123         $out[4] =~ s/-\d+$//o;
 124
 125         # remove leading and trailing spaces
 126         $_[3] = unpad($_[3]);
 127
 128
 129         # add the 'dxcc' country on the end for both spotted and spotter, then the cluster call
 130         my @spd = Prefix::cty_data($out[1]);
 131         push @out, $spd[0];
 132         my @spt = Prefix::cty_data($out[4]);
 133         push @out, $spt[0];
 134         push @out, $_[5];
 135         return (@out, @spd[1,2], @spt[1,2], $spd[3], $spt[3]);
 136 }
 137
 138 sub add
 139 {
 140         my $buf = join('^', @_);
 141         $fp->writeunix($_[2], $buf);
 142         $totalspots++;
 143         if ($_[0] <= 30000) {
 144                 $hfspots++;
 145         } else {
 146                 $vhfspots++;
 147         }
 148         if ($_[3] =~ /(?:QSL|VIA)/i) {
 149                 my $q = QSL::get($_[1]) || new QSL $_[1];
 150                 $q->update($_[3], $_[2], $_[4]);
 151         }
 152 }
 153
 154 # search the spot database for records based on the field no and an expression
 155 # this returns a set of references to the spots
 156 #
 157 # the expression is a legal perl 'if' statement with the possible fields indicated
 158 # by $f<n> where :-
 159 #
 160 #   $f0 = frequency
 161 #   $f1 = call
 162 #   $f2 = date in unix format
 163 #   $f3 = comment
 164 #   $f4 = spotter
 165 #   $f5 = spotted dxcc country
 166 #   $f6 = spotter dxcc country
 167 #   $f7 = origin
 168 #
 169 #
 170 # In addition you can specify a range of days, this means that it will start searching
 171 # from <n> days less than today to <m> days less than today
 172 #
 173 # Also you can select a range of entries so normally you would get the 0th (latest) entry
 174 # back to the 5th latest, you can specify a range from the <x>th to the <y>the oldest.
 175 #
 176 # This routine is designed to be called as Spot::search(..)
 177 #
 178
 179 sub search
 180 {
 181         my ($expr, $dayfrom, $dayto, $from, $to, $hint, $dxchan) = @_;
 182         my $eval;
 183         my @out;
 184         my $ref;
 185         my $i;
 186         my $count;
 187         my $today = Julian::Day->new(time());
 188         my $fromdate;
 189         my $todate;
 190
 191         $dayfrom = 0 if !$dayfrom;
 192         $dayto = $maxdays unless $dayto;
 193         $dayto = $dayfrom + $maxdays if $dayto < $dayfrom;
 194         $fromdate = $today->sub($dayfrom);
 195         $todate = $fromdate->sub($dayto);
 196         $from = 0 unless $from;
 197         $to = $defaultspots unless $to;
 198         $hint = $hint ? "next unless $hint" : "";
 199         $expr = "1" unless $expr;
 200
 201         $to = $from + $maxspots if $to - $from > $maxspots || $to - $from <= 0;
 202
 203         $expr =~ s/\$f(\d\d?)/\$ref->[$1]/g; # swap the letter n for the correct field name
 204         #  $expr =~ s/\$f(\d)/\$spots[$1]/g;               # swap the letter n for the correct field name
 205
 206         my $checkfilter;
 207         $checkfilter = qq (
 208                       if (\@s < 9) {
 209                           my \@a = (Prefix::cty_data(\$s[1]))[1..3];
 210                           my \@b = (Prefix::cty_data(\$s[4]))[1..3];
 211                           push \@s, \@a[0,1], \@b[0,1], \$a[2], \$a[2];
 212                       }
 213                           my (\$filter, \$hops) = \$dxchan->{spotsfilter}->it(\@s);
 214                           next unless (\$filter);
 215                       ) if $dxchan;
 216         $checkfilter ||= ' ';
 217
 218         dbg("hint='$hint', expr='$expr', spotno=$from-$to, day=$dayfrom-$dayto\n") if isdbg('search');
 219
 220         # build up eval to execute
 221         $eval = qq(
 222                            while (<\$fh>) {
 223                                    $hint;
 224                                    chomp;
 225                                    my \@s = split /\\^/;
 226                    $checkfilter;
 227                    push \@spots, \\\@s;
 228                            }
 229                            my \$c;
 230                            my \$ref;
 231                            for (\$c = \$#spots; \$c >= 0; \$c--) {
 232                                         \$ref = \$spots[\$c];
 233                                         if ($expr) {
 234                                                 \$count++;
 235                                                 next if \$count < \$from; # wait until from
 236                                                 push(\@out, \$ref);
 237                                                 last if \$count >= \$to; # stop after to
 238                                         }
 239                                 }
 240                           );
 241
 242         dbg("Spot eval: $eval") if isdbg('searcheval');
 243
 244
 245         $fp->close;                                     # close any open files
 246
 247         for ($i = $count = 0; $i < $maxdays; ++$i) {    # look thru $maxdays worth of files only
 248                 my $now = $fromdate->sub($i); # but you can pick which $maxdays worth
 249                 last if $now->cmp($todate) <= 0;
 250
 251                 my @spots = ();
 252                 my $fh = $fp->open($now); # get the next file
 253                 if ($fh) {
 254                         my $in;
 255                         eval $eval;                     # do the search on this file
 256                         last if $count >= $to; # stop after to
 257                         return ("Spot search error", $@) if $@;
 258                 }
 259         }
 260
 261         return @out;
 262 }
 263
 264 # change a freq range->regular expression
 265 sub ftor
 266 {
 267         my ($a, $b) = @_;
 268         return undef unless $a < $b;
 269         $b--;
 270         my $d = $b - $a;
 271         my @a = split //, $a;
 272         my @b = split //, $b;
 273         my $out;
 274         while (@b > @a) {
 275                 $out .= shift @b;
 276         }
 277         while (@b) {
 278                 my $aa = shift @a;
 279                 my $bb = shift @b;
 280                 if (@b < (length $d)) {
 281                         $out .= '\\d';
 282                 } elsif ($aa eq $bb) {
 283                         $out .= $aa;
 284                 } elsif ($aa < $bb) {
 285                         $out .= "[$aa-$bb]";
 286                 } else {
 287                         $out .= "[0-$bb$aa-9]";
 288                 }
 289         }
 290         return $out;
 291 }
 292
 293 # format a spot for user output in list mode
 294 sub formatl
 295 {
 296         my $t = ztime($_[2]);
 297         my $d = cldate($_[2]);
 298         return sprintf "%8.1f  %-11s %s %s  %-28.28s%7s>", $_[0], $_[1], $d, $t, $_[3], "<$_[4]" ;
 299 }
 300
 301 #
 302 # return all the spots from a day's file as an array of references
 303 # the parameter passed is a julian day
 304 sub readfile($)
 305 {
 306         my @spots;
 307
 308         my $fh = $fp->open(shift);
 309         if ($fh) {
 310                 my $in;
 311                 while (<$fh>) {
 312                         chomp;
 313                         push @spots, [ split '\^' ];
 314                 }
 315         }
 316         return @spots;
 317 }
 318
 319 # enter the spot for dup checking and return true if it is already a dup
 320 sub dup
 321 {
 322         my ($freq, $call, $d, $text, $by) = @_;
 323
 324         # dump if too old
 325         return 2 if $d < $main::systime - $dupage;
 326
 327         # turn the time into minutes (should be already but...)
 328         $d = int ($d / 60);
 329         $d *= 60;
 330
 331         $freq = sprintf "%.1f", $freq;       # normalise frequency
 332         $call = substr($call, 0, $maxcalllth) if length $call > $maxcalllth;
 333
 334         chomp $text;
 335         $text =~ s/\%([0-9A-F][0-9A-F])/chr(hex($1))/eg;
 336         $text = unpad($text);
 337         $text = substr($text, 0, $duplth) if length $text > $duplth;
 338         $text = pack("C*", map {$_ & 127} unpack("C*", $text));
 339         $text =~ s/[^a-zA-Z0-9]//g;
 340         my $ldupkey = "X$freq|$call|" . uc $text;
 341         my $sdupkey = "X$freq|$call|$by";
 342         my $t = DXDupe::find($ldupkey);
 343         return 1 if $t && $t - $main::systime > 0;
 344     $t = DXDupe::find($sdupkey);
 345         return 1 if $t && $t - $main::systime > 0;
 346         DXDupe::add($ldupkey, $main::systime+$dupage);
 347         DXDupe::add($sdupkey, $main::systime+$dupage);
 348         return 0;
 349 }
 350
 351 sub listdups
 352 {
 353         return DXDupe::listdups('X', $dupage, @_);
 354 }
 355
 356 sub genstats($)
 357 {
 358         my $date = shift;
 359         my $in = $fp->open($date);
 360         my $out = $statp->open($date, 'w');
 361         my @freq;
 362         my %list;
 363         my @tot;
 364
 365         if ($in && $out) {
 366                 my $i = 0;
 367                 @freq = map {[$i++, Bands::get_freq($_)]} qw(136khz 160m 80m 60m 40m 30m 20m 17m 15m 12m 10m 6m 4m 2m 220 70cm 23cm 13cm 9cm 6cm 3cm 12mm 6mm);
 368                 while (<$in>) {
 369                         chomp;
 370                         my ($freq, $by, $dxcc) = (split /\^/)[0,4,6];
 371                         my $ref = $list{$by} || [0, $dxcc];
 372                         for (@freq) {
 373                                 next unless defined $_;
 374                                 if ($freq >= $_->[1] && $freq <= $_->[2]) {
 375                                         $$ref[$_->[0]+2]++;
 376                                         $tot[$_->[0]+2]++;
 377                                         $$ref[0]++;
 378                                         $tot[0]++;
 379                                         $list{$by} = $ref;
 380                                         last;
 381                                 }
 382                         }
 383                 }
 384
 385                 for ($i = 0; $i < @freq+2; $i++) {
 386                         $tot[$i] ||= 0;
 387                 }
 388                 $statp->write($date, join('^', 'TOTALS', @tot));
 389
 390                 for (sort {$list{$b}->[0] <=> $list{$a}->[0]} keys %list) {
 391                         my $ref = $list{$_};
 392                         my $call = $_;
 393                         for ($i = 0; $i < @freq+2; ++$i) {
 394                                 $ref->[$i] ||= 0;
 395                         }
 396                         $statp->write($date, join('^', $call, @$ref));
 397                 }
 398                 $statp->close;
 399         }
 400 }
 401
 402 # return true if the stat file is newer than than the spot file
 403 sub checkstats($)
 404 {
 405         my $date = shift;
 406         my $in = $fp->mtime($date);
 407         my $out = $statp->mtime($date);
 408         return defined $out && defined $in && $out >= $in;
 409 }
 410
 411 # daily processing
 412 sub daily
 413 {
 414         my $date = Julian::Day->new($main::systime)->sub(1);
 415         genstats($date) unless checkstats($date);
 416 }
 417 1;
 418
 419
 420
 421