perl/Route/Node.pm

   1 #
   2 # Node routing routines
   3 #
   4 # Copyright (c) 2001 Dirk Koopman G1TLH
   5 #
   6 # $Id$
   7 #
   8
   9 package Route::Node;
  10
  11 use DXDebug;
  12 use Route;
  13 use Route::User;
  14
  15 use strict;
  16
  17 use vars qw($VERSION $BRANCH);
  18 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  19 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/ ) || 0;
  20 $main::build += $VERSION;
  21 $main::branch += $BRANCH;
  22
  23 use vars qw(%list %valid @ISA $max $filterdef);
  24 @ISA = qw(Route);
  25
  26 %valid = (
  27                   parent => '0,Parent Calls,parray',
  28                   nodes => '0,Nodes,parray',
  29                   users => '0,Users,parray',
  30                   usercount => '0,User Count',
  31                   version => '0,Version',
  32                   pc90 => '0,Using PC90,yesno',
  33                   lastpc90 => '0,Last PC90 time,cldatetime',
  34 );
  35
  36 $filterdef = $Route::filterdef;
  37 %list = ();
  38 $max = 0;
  39
  40 sub count
  41 {
  42         my $n = scalar (keys %list);
  43         $max = $n if $n > $max;
  44         return $n;
  45 }
  46
  47 sub max
  48 {
  49         count();
  50         return $max;
  51 }
  52
  53 #
  54 # this routine handles the possible adding of an entry in the routing
  55 # table. It will only add an entry if it is new. It may have all sorts of
  56 # other side effects which may include fixing up other links.
  57 #
  58 # It will return a node object if (and only if) it is a completely new
  59 # object with that callsign. The upper layers are expected to do something
  60 # sensible with this!
  61 #
  62 # called as $parent->add(call, dxchan, version, flags)
  63 #
  64
  65 sub add
  66 {
  67         my $parent = shift;
  68         my $call = uc shift;
  69         confess "Route::add trying to add $call to myself" if $call eq $parent->{call};
  70         my $self = get($call);
  71         if ($self) {
  72                 $self->_addparent($parent);
  73                 $parent->_addnode($self);
  74                 return undef;
  75         }
  76         $self = $parent->new($call, @_);
  77         $parent->_addnode($self);
  78         return $self;
  79 }
  80
  81 #
  82 # this routine is the opposite of 'add' above.
  83 #
  84 # It will return an object if (and only if) this 'del' will remove
  85 # this object completely
  86 #
  87
  88 sub del
  89 {
  90         my $self = shift;
  91         my $pref = shift;
  92
  93         # delete parent from this call's parent list
  94         $pref->_delnode($self);
  95     $self->_delparent($pref);
  96         my @nodes;
  97         my $ncall = $self->{call};
  98
  99         # is this the last connection, I have no parents anymore?
 100         unless (@{$self->{parent}}) {
 101                 foreach my $rcall (@{$self->{nodes}}) {
 102                         next if grep $rcall eq $_, @_;
 103                         my $r = Route::Node::get($rcall);
 104                         push @nodes, $r->del($self, $ncall, @_) if $r;
 105                 }
 106                 $self->_del_users;
 107                 delete $list{$self->{call}};
 108                 push @nodes, $self;
 109         }
 110         return @nodes;
 111 }
 112
 113 sub del_nodes
 114 {
 115         my $parent = shift;
 116         my @out;
 117         foreach my $rcall (@{$parent->{nodes}}) {
 118                 my $r = get($rcall);
 119                 push @out, $r->del($parent, $parent->{call}, @_) if $r;
 120         }
 121         return @out;
 122 }
 123
 124 sub _del_users
 125 {
 126         my $self = shift;
 127         for (@{$self->{users}}) {
 128                 my $ref = Route::User::get($_);
 129                 $ref->del($self) if $ref;
 130         }
 131         $self->{users} = [];
 132 }
 133
 134 # add a user to this node
 135 sub add_user
 136 {
 137         my $self = shift;
 138         my $ucall = shift;
 139
 140         confess "Trying to add NULL User call to routing tables" unless $ucall;
 141
 142         my $uref = Route::User::get($ucall);
 143         my @out;
 144         if ($uref) {
 145                 @out = $uref->addparent($self);
 146         } else {
 147                 $uref = Route::User->new($ucall, $self->{call}, @_);
 148                 @out = $uref;
 149         }
 150         $self->_adduser($uref);
 151         $self->{usercount} = scalar @{$self->{users}};
 152
 153         return @out;
 154 }
 155
 156 # delete a user from this node
 157 sub del_user
 158 {
 159         my $self = shift;
 160         my $ref = shift;
 161         my @out;
 162
 163         if ($ref) {
 164                 @out = $self->_deluser($ref);
 165                 $ref->del($self);
 166         } else {
 167                 confess "tried to delete non-existant $ref->{call} from $self->{call}";
 168         }
 169         $self->{usercount} = scalar @{$self->{users}};
 170         return @out;
 171 }
 172
 173 sub usercount
 174 {
 175         my $self = shift;
 176         if (@_ && @{$self->{users}} == 0) {
 177                 $self->{usercount} = shift;
 178         }
 179         return $self->{usercount};
 180 }
 181
 182 sub users
 183 {
 184         my $self = shift;
 185         return @{$self->{users}};
 186 }
 187
 188 sub nodes
 189 {
 190         my $self = shift;
 191         return @{$self->{nodes}};
 192 }
 193
 194 sub parents
 195 {
 196         my $self = shift;
 197         return @{$self->{parent}};
 198 }
 199
 200 sub rnodes
 201 {
 202         my $self = shift;
 203         my @out;
 204         foreach my $call (@{$self->{nodes}}) {
 205                 next if grep $call eq $_, @_;
 206                 push @out, $call;
 207                 my $r = get($call);
 208                 push @out, $r->rnodes($call, @_) if $r;
 209         }
 210         return @out;
 211 }
 212
 213
 214 sub new
 215 {
 216         my $pkg = shift;
 217         my $call = uc shift;
 218
 219         confess "already have $call in $pkg" if $list{$call};
 220
 221         my $self = $pkg->SUPER::new($call);
 222         $self->{parent} = ref $pkg ? [ $pkg->{call} ] : [ ];
 223         $self->{version} = shift;
 224         $self->{flags} = shift;
 225         $self->{users} = [];
 226         $self->{nodes} = [];
 227
 228         $list{$call} = $self;
 229
 230         return $self;
 231 }
 232
 233 sub get
 234 {
 235         my $call = shift;
 236         $call = shift if ref $call;
 237         my $ref = $list{uc $call};
 238         dbg("Failed to get Node $call" ) if !$ref && isdbg('routerr');
 239         return $ref;
 240 }
 241
 242 sub get_all
 243 {
 244         return values %list;
 245 }
 246
 247 sub _addparent
 248 {
 249         my $self = shift;
 250     return $self->_addlist('parent', @_);
 251 }
 252
 253 sub _delparent
 254 {
 255         my $self = shift;
 256     return $self->_dellist('parent', @_);
 257 }
 258
 259
 260 sub _addnode
 261 {
 262         my $self = shift;
 263     return $self->_addlist('nodes', @_);
 264 }
 265
 266 sub _delnode
 267 {
 268         my $self = shift;
 269     return $self->_dellist('nodes', @_);
 270 }
 271
 272
 273 sub _adduser
 274 {
 275         my $self = shift;
 276     return $self->_addlist('users', @_);
 277 }
 278
 279 sub _deluser
 280 {
 281         my $self = shift;
 282     return $self->_dellist('users', @_);
 283 }
 284
 285 sub DESTROY
 286 {
 287         my $self = shift;
 288         my $pkg = ref $self;
 289         my $call = $self->{call} || "Unknown";
 290
 291         dbg("destroying $pkg with $call") if isdbg('routelow');
 292 }
 293
 294 #
 295 # generic AUTOLOAD for accessors
 296 #
 297
 298 sub AUTOLOAD
 299 {
 300         no strict;
 301
 302         my $self = shift;
 303         $name = $AUTOLOAD;
 304         return if $name =~ /::DESTROY$/;
 305         $name =~ s/.*:://o;
 306
 307         confess "Non-existant field '$AUTOLOAD'" unless $valid{$name} || $Route::valid{$name};
 308
 309         # this clever line of code creates a subroutine which takes over from autoload
 310         # from OO Perl - Conway
 311 #       print "AUTOLOAD: $AUTOLOAD\n";
 312 #       *{$AUTOLOAD} = sub {my $self = shift; @_ ? $self->{$name} = shift : $self->{$name}} ;
 313     @_ ? $self->{$name} = shift : $self->{$name} ;
 314 }
 315
 316 1;
 317