perl/Route.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the abstracted routing for all protocols and
   4 # is probably what I SHOULD have done the first time.
   5 #
   6 # Heyho.
   7 #
   8 # This is just a container class which I expect to subclass
   9 #
  10 # Copyright (c) 2001 Dirk Koopman G1TLH
  11 #
  12 # $Id$
  13 #
  14
  15 package Route;
  16
  17 use DXDebug;
  18 use DXChannel;
  19 use Prefix;
  20
  21 use strict;
  22
  23
  24 use vars qw($VERSION $BRANCH);
  25 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  26 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  27 $main::build += $VERSION;
  28 $main::branch += $BRANCH;
  29
  30 use vars qw(%list %valid $filterdef);
  31
  32 %valid = (
  33                   call => "0,Callsign",
  34                   flags => "0,Flags,phex",
  35                   dxcc => '0,Country Code',
  36                   itu => '0,ITU Zone',
  37                   cq => '0,CQ Zone',
  38                   state => '0,State',
  39                   city => '0,City',
  40                  );
  41
  42 $filterdef = bless ([
  43                           # tag, sort, field, priv, special parser
  44                           ['channel', 'c', 0],
  45                           ['channel_dxcc', 'nc', 1],
  46                           ['channel_itu', 'ni', 2],
  47                           ['channel_zone', 'nz', 3],
  48                           ['call', 'c', 4],
  49                           ['by', 'c', 4],
  50                           ['call_dxcc', 'nc', 5],
  51                           ['by_dxcc', 'nc', 5],
  52                           ['call_itu', 'ni', 6],
  53                           ['by_itu', 'ni', 6],
  54                           ['call_zone', 'nz', 7],
  55                           ['by_zone', 'nz', 7],
  56                           ['channel_state', 'ns', 8],
  57                           ['call_state', 'ns', 9],
  58                           ['by_state', 'ns', 9],
  59                          ], 'Filter::Cmd');
  60
  61
  62 sub new
  63 {
  64         my ($pkg, $call) = @_;
  65         $pkg = ref $pkg if ref $pkg;
  66
  67         my $self = bless {call => $call}, $pkg;
  68         dbg("create $pkg with $call") if isdbg('routelow');
  69
  70         # add in all the dxcc, itu, zone info
  71         ($self->{dxcc}, $self->{itu}, $self->{cq}, $self->{state}, $self->{city}) =
  72                 Prefix::cty_data($call);
  73
  74         $self->{flags} = here(1);
  75
  76         return $self;
  77 }
  78
  79 #
  80 # get a callsign from a passed reference or a string
  81 #
  82
  83 sub _getcall
  84 {
  85         my $self = shift;
  86         my $thingy = shift;
  87         $thingy = $self unless $thingy;
  88         $thingy = $thingy->call if ref $thingy;
  89         $thingy = uc $thingy if $thingy;
  90         return $thingy;
  91 }
  92
  93 #
  94 # add and delete a callsign to/from a list
  95 #
  96
  97 sub _addlist
  98 {
  99         my $self = shift;
 100         my $field = shift;
 101         my @out;
 102         foreach my $c (@_) {
 103                 confess "Need a ref here" unless ref($c);
 104
 105                 my $call = $c->{call};
 106                 unless (grep $_ eq $call, @{$self->{$field}}) {
 107                         push @{$self->{$field}}, $call;
 108                         dbg(ref($self) . " adding $call to " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 109                         push @out, $c;
 110                 }
 111         }
 112         return @out;
 113 }
 114
 115 sub _dellist
 116 {
 117         my $self = shift;
 118         my $field = shift;
 119         my @out;
 120         foreach my $c (@_) {
 121                 confess "Need a ref here" unless ref($c);
 122                 my $call = $c->{call};
 123                 if (grep $_ eq $call, @{$self->{$field}}) {
 124                         $self->{$field} = [ grep {$_ ne $call} @{$self->{$field}} ];
 125                         dbg(ref($self) . " deleting $call from " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 126                         push @out, $c;
 127                 }
 128         }
 129         return @out;
 130 }
 131
 132 sub is_empty
 133 {
 134         my $self = shift;
 135         return @{$self->{$_[0]}} == 0;
 136 }
 137
 138 #
 139 # flag field constructors/enquirers
 140 #
 141 # These can be called in various ways:-
 142 #
 143 # Route::here or $ref->here returns 1 or 0 depending on value of the here flag
 144 # Route::here(1) returns 2 (the bit value of the here flag)
 145 # $ref->here(1) or $ref->here(0) sets the here flag
 146 #
 147
 148 sub here
 149 {
 150         my $self = shift;
 151         my $r = shift;
 152         return $self ? 2 : 0 unless ref $self;
 153         return ($self->{flags} & 2) ? 1 : 0 unless defined $r;
 154         $self->{flags} = (($self->{flags} & ~2) | ($r ? 2 : 0));
 155         return $r ? 1 : 0;
 156 }
 157
 158 sub conf
 159 {
 160         my $self = shift;
 161         my $r = shift;
 162         return $self ? 1 : 0 unless ref $self;
 163         return ($self->{flags} & 1) ? 1 : 0 unless defined $r;
 164         $self->{flags} = (($self->{flags} & ~1) | ($r ? 1 : 0));
 165         return $r ? 1 : 0;
 166 }
 167
 168 sub parents
 169 {
 170         my $self = shift;
 171         return @{$self->{parent}};
 172 }
 173
 174 #
 175 # display routines
 176 #
 177
 178 sub user_call
 179 {
 180         my $self = shift;
 181         my $call = sprintf "%s", $self->{call};
 182         return $self->here ? "$call" : "($call)";
 183 }
 184
 185 sub config
 186 {
 187         my $self = shift;
 188         my $nodes_only = shift;
 189         my $level = shift;
 190         my $seen = shift;
 191         my @out;
 192         my $line;
 193         my $call = $self->user_call;
 194         my $printit = 1;
 195
 196         # allow ranges
 197         if (@_) {
 198                 $printit = grep $call =~ m|$_|, @_;
 199         }
 200
 201         if ($printit) {
 202                 my $pcall = "$call:" . $self->obscount;
 203
 204                 $line = ' ' x ($level*2) . "$pcall";
 205                 $call = ' ' x length $pcall;
 206
 207                 # recursion detector
 208                 if ((DXChannel::get($self->{call}) && $level > 1) || grep $self->{call} eq $_, @$seen) {
 209                         $line .= ' ...';
 210                         push @out, $line;
 211                         return @out;
 212                 }
 213                 push @$seen, $self->{call};
 214
 215                 # print users
 216                 unless ($nodes_only) {
 217                         if (@{$self->{users}}) {
 218                                 $line .= '->';
 219                                 foreach my $ucall (sort @{$self->{users}}) {
 220                                         my $uref = Route::User::get($ucall);
 221                                         my $c;
 222                                         if ($uref) {
 223                                                 $c = $uref->user_call;
 224                                         } else {
 225                                                 $c = "$ucall?";
 226                                         }
 227                                         if ((length $line) + (length $c) + 1 < 79) {
 228                                                 $line .= $c . ' ';
 229                                         } else {
 230                                                 $line =~ s/\s+$//;
 231                                                 push @out, $line;
 232                                                 $line = ' ' x ($level*2) . "$call->$c ";
 233                                         }
 234                                 }
 235                         }
 236                 }
 237                 $line =~ s/->$//g;
 238                 $line =~ s/\s+$//;
 239                 push @out, $line if length $line;
 240         }
 241
 242         # deal with more nodes
 243         foreach my $ncall (sort @{$self->{nodes}}) {
 244                 my $nref = Route::Node::get($ncall);
 245
 246                 if ($nref) {
 247                         my $c = $nref->user_call;
 248 #                       dbg("recursing from $call -> $c") if isdbg('routec');
 249                         push @out, $nref->config($nodes_only, $level+1, $seen, @_);
 250                 } else {
 251                         push @out, ' ' x (($level+1)*2)  . "$ncall?" if @_ == 0 || (@_ && grep $ncall =~ m|$_|, @_);
 252                 }
 253         }
 254
 255         return @out;
 256 }
 257
 258 sub cluster
 259 {
 260         my $nodes = Route::Node::count();
 261         my $tot = Route::User::count();
 262         my $users = scalar DXCommandmode::get_all();
 263         my $maxusers = Route::User::max();
 264         my $uptime = main::uptime();
 265
 266         return " $nodes nodes, $users local / $tot total users  Max users $maxusers  Uptime $uptime";
 267 }
 268
 269 #
 270 # routing things
 271 #
 272
 273 sub get
 274 {
 275         my $call = shift;
 276         return Route::Node::get($call) || Route::User::get($call);
 277 }
 278
 279 # find all the possible dxchannels which this object might be on
 280 sub alldxchan
 281 {
 282         my $self = shift;
 283         my @dxchan;
 284 #       dbg("Trying node $self->{call}") if isdbg('routech');
 285
 286         my $dxchan = DXChannel::get($self->{call});
 287         push @dxchan, $dxchan if $dxchan;
 288
 289         # it isn't, build up a list of dxchannels and possible ping times
 290         # for all the candidates.
 291         unless (@dxchan) {
 292                 foreach my $p (@{$self->{parent}}) {
 293 #                       dbg("Trying parent $p") if isdbg('routech');
 294                         next if $p eq $main::mycall; # the root
 295                         my $dxchan = DXChannel::get($p);
 296                         if ($dxchan) {
 297                                 push @dxchan, $dxchan unless grep $dxchan == $_, @dxchan;
 298                         } else {
 299                                 next if grep $p eq $_, @_;
 300                                 my $ref = Route::Node::get($p);
 301 #                               dbg("Next node $p " . ($ref ? 'Found' : 'NOT Found') if isdbg('routech') );
 302                                 push @dxchan, $ref->alldxchan($self->{call}, @_) if $ref;
 303                         }
 304                 }
 305         }
 306 #       dbg('routech', "Got dxchan: " . join(',', (map{ $_->call } @dxchan)) );
 307         return @dxchan;
 308 }
 309
 310 sub dxchan
 311 {
 312         my $self = shift;
 313
 314         # ALWAYS return the locally connected channel if present;
 315         my $dxchan = DXChannel::get($self->call);
 316         return $dxchan if $dxchan;
 317
 318         my @dxchan = $self->alldxchan;
 319         return undef unless @dxchan;
 320
 321         # determine the minimum ping channel
 322         my $minping = 99999999;
 323         foreach my $dxc (@dxchan) {
 324                 my $p = $dxc->pingave;
 325                 if (defined $p  && $p < $minping) {
 326                         $minping = $p;
 327                         $dxchan = $dxc;
 328                 }
 329         }
 330         $dxchan = shift @dxchan unless $dxchan;
 331         return $dxchan;
 332 }
 333
 334
 335
 336 #
 337 # track destruction
 338 #
 339
 340 sub DESTROY
 341 {
 342         my $self = shift;
 343         my $pkg = ref $self;
 344
 345         dbg("$pkg $self->{call} destroyed") if isdbg('routelow');
 346 }
 347
 348 no strict;
 349 #
 350 # return a list of valid elements
 351 #
 352
 353 sub fields
 354 {
 355         my $pkg = shift;
 356         $pkg = ref $pkg if ref $pkg;
 357     my $val = "${pkg}::valid";
 358         my @out = keys %$val;
 359         push @out, keys %valid;
 360         return @out;
 361 }
 362
 363 #
 364 # return a prompt for a field
 365 #
 366
 367 sub field_prompt
 368 {
 369         my ($self, $ele) = @_;
 370         my $pkg = ref $self;
 371     my $val = "${pkg}::valid";
 372         return $val->{$ele} || $valid{$ele};
 373 }
 374
 375 #
 376 # generic AUTOLOAD for accessors
 377 #
 378 sub AUTOLOAD
 379 {
 380         no strict;
 381         my $name = $AUTOLOAD;
 382         return if $name =~ /::DESTROY$/;
 383         $name =~ s/^.*:://o;
 384
 385         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 386
 387         # this clever line of code creates a subroutine which takes over from autoload
 388         # from OO Perl - Conway
 389         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 390        goto &$AUTOLOAD;
 391
 392 }
 393
 394 1;