perl/Route.pm

   1 #
   2 #
   3 # This module impliments the abstracted routing for all protocols and
   4 # is probably what I SHOULD have done the first time.
   5 #
   6 # Heyho.
   7 #
   8 # This is just a container class which I expect to subclass
   9 #
  10 # Copyright (c) 2001 Dirk Koopman G1TLH
  11 #
  12 #
  13 #
  14
  15 package Route;
  16
  17 use DXDebug;
  18 use DXChannel;
  19 use Prefix;
  20 use DXUtil;
  21
  22 use strict;
  23
  24
  25 use vars qw(%list %valid $filterdef);
  26
  27 %valid = (
  28                   call => "0,Callsign",
  29                   flags => "0,Flags,phex",
  30                   dxcc => '0,Country Code',
  31                   itu => '0,ITU Zone',
  32                   cq => '0,CQ Zone',
  33                   state => '0,State',
  34                   city => '0,City',
  35                  );
  36
  37 $filterdef = bless ([
  38                           # tag, sort, field, priv, special parser
  39                           ['channel', 'c', 0],
  40                           ['channel_dxcc', 'nc', 1],
  41                           ['channel_itu', 'ni', 2],
  42                           ['channel_zone', 'nz', 3],
  43                           ['call', 'c', 4],
  44                           ['by', 'c', 4],
  45                           ['call_dxcc', 'nc', 5],
  46                           ['by_dxcc', 'nc', 5],
  47                           ['call_itu', 'ni', 6],
  48                           ['by_itu', 'ni', 6],
  49                           ['call_zone', 'nz', 7],
  50                           ['by_zone', 'nz', 7],
  51                           ['channel_state', 'ns', 8],
  52                           ['call_state', 'ns', 9],
  53                           ['by_state', 'ns', 9],
  54                          ], 'Filter::Cmd');
  55
  56
  57 sub new
  58 {
  59         my ($pkg, $call) = @_;
  60         $pkg = ref $pkg if ref $pkg;
  61
  62         my $self = bless {call => $call}, $pkg;
  63         dbg("create $pkg with $call") if isdbg('routelow');
  64
  65         # add in all the dxcc, itu, zone info
  66         ($self->{dxcc}, $self->{itu}, $self->{cq}, $self->{state}, $self->{city}) =
  67                 Prefix::cty_data($call);
  68
  69         $self->{flags} = here(1);
  70
  71         return $self;
  72 }
  73
  74 #
  75 # get a callsign from a passed reference or a string
  76 #
  77
  78 sub _getcall
  79 {
  80         my $self = shift;
  81         my $thingy = shift;
  82         $thingy = $self unless $thingy;
  83         $thingy = $thingy->call if ref $thingy;
  84         $thingy = uc $thingy if $thingy;
  85         return $thingy;
  86 }
  87
  88 #
  89 # add and delete a callsign to/from a list
  90 #
  91
  92 sub _addlist
  93 {
  94         my $self = shift;
  95         my $field = shift;
  96         my @out;
  97         foreach my $c (@_) {
  98                 confess "Need a ref here" unless ref($c);
  99
 100                 my $call = $c->{call};
 101                 unless (grep $_ eq $call, @{$self->{$field}}) {
 102                         push @{$self->{$field}}, $call;
 103                         dbg(ref($self) . " adding $call to " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 104                         push @out, $c;
 105                 }
 106         }
 107         return @out;
 108 }
 109
 110 sub _dellist
 111 {
 112         my $self = shift;
 113         my $field = shift;
 114         my @out;
 115         foreach my $c (@_) {
 116                 confess "Need a ref here" unless ref($c);
 117                 my $call = $c->{call};
 118                 if (grep $_ eq $call, @{$self->{$field}}) {
 119                         $self->{$field} = [ grep {$_ ne $call} @{$self->{$field}} ];
 120                         dbg(ref($self) . " deleting $call from " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 121                         push @out, $c;
 122                 }
 123         }
 124         return @out;
 125 }
 126
 127 sub is_empty
 128 {
 129         my $self = shift;
 130         return @{$self->{$_[0]}} == 0;
 131 }
 132
 133 #
 134 # flag field constructors/enquirers
 135 #
 136 # These can be called in various ways:-
 137 #
 138 # Route::here or $ref->here returns 1 or 0 depending on value of the here flag
 139 # Route::here(1) returns 2 (the bit value of the here flag)
 140 # $ref->here(1) or $ref->here(0) sets the here flag
 141 #
 142
 143 sub here
 144 {
 145         my $self = shift;
 146         my $r = shift;
 147         return $self ? 2 : 0 unless ref $self;
 148         return ($self->{flags} & 2) ? 1 : 0 unless defined $r;
 149         $self->{flags} = (($self->{flags} & ~2) | ($r ? 2 : 0));
 150         return $r ? 1 : 0;
 151 }
 152
 153 sub conf
 154 {
 155         my $self = shift;
 156         my $r = shift;
 157         return $self ? 1 : 0 unless ref $self;
 158         return ($self->{flags} & 1) ? 1 : 0 unless defined $r;
 159         $self->{flags} = (($self->{flags} & ~1) | ($r ? 1 : 0));
 160         return $r ? 1 : 0;
 161 }
 162
 163 sub parents
 164 {
 165         my $self = shift;
 166         return @{$self->{parent}};
 167 }
 168
 169 #
 170 # display routines
 171 #
 172
 173 sub user_call
 174 {
 175         my $self = shift;
 176         my $call = sprintf "%s", $self->{call};
 177         return $self->here ? "$call" : "($call)";
 178 }
 179
 180 sub config
 181 {
 182         my $self = shift;
 183         my $nodes_only = shift || 0;
 184         my $width = shift || 79;
 185         my $level = shift;
 186         my $seen = shift;
 187         my @out;
 188         my $line;
 189         my $call = $self->{call};
 190         my $printit = 1;
 191
 192         dbg("config: $call nodes: $nodes_only level: $level calls: " . join(',', @_)) if isdbg('routec');
 193
 194         # allow ranges
 195         if (@_) {
 196                 $printit = grep $call =~ m|$_|, @_;
 197         }
 198
 199         if ($printit) {
 200                 my $pcall = $self->user_call;
 201                 $pcall .= ":" . $self->obscount if isdbg('obscount');
 202
 203
 204                 $line = ' ' x ($level*2) . $pcall;
 205                 $pcall = ' ' x length $pcall;
 206
 207                 # recursion detector
 208                 if ((DXChannel::get($call) && $level > 1) || $seen->{$call}) {
 209                         $line .= ' ...';
 210                         push @out, $line;
 211                         return @out;
 212                 }
 213                 $seen->{$call}++;
 214
 215                 # print users
 216                 unless ($nodes_only) {
 217                         if (@{$self->{users}}) {
 218                                 $line .= '->';
 219                                 foreach my $ucall (sort @{$self->{users}}) {
 220                                         my $uref = Route::User::get($ucall);
 221                                         my $c;
 222                                         if ($uref) {
 223                                                 $c = $uref->user_call;
 224                                         } else {
 225                                                 $c = "$ucall?";
 226                                         }
 227                                         if ((length $line) + (length $c) + 1 < $width) {
 228                                                 $line .= $c . ' ';
 229                                         } else {
 230                                                 $line =~ s/\s+$//;
 231                                                 push @out, $line;
 232                                                 $line = ' ' x ($level*2) . "$pcall->$c ";
 233                                         }
 234                                 }
 235                         }
 236                 }
 237                 $line =~ s/->$//g;
 238                 $line =~ s/\s+$//;
 239                 push @out, $line if length $line;
 240         } else {
 241                 # recursion detector
 242                 if ((DXChannel::get($call) && $level > 1) || $seen->{$call}) {
 243                         return @out;
 244                 }
 245                 $seen->{$call}++;
 246         }
 247
 248         # deal with more nodes
 249         foreach my $ncall (sort @{$self->{nodes}}) {
 250                 my $nref = Route::Node::get($ncall);
 251
 252                 if ($nref) {
 253                         my $c = $nref->user_call;
 254                         dbg("recursing from $call -> $c") if isdbg('routec');
 255                         my @rout = $nref->config($nodes_only, $width, $level+1, $seen, @_);
 256                         if (@rout && @_) {
 257                                 push @out, ' ' x ($level*2) . $self->user_call unless grep /^\s+$call/, @out;
 258                         }
 259                         push @out, @rout;
 260                 } else {
 261                         push @out, ' ' x (($level+1)*2)  . "$ncall?" if @_ == 0 || (@_ && grep $ncall =~ m|$_|, @_);
 262                 }
 263         }
 264
 265         return @out;
 266 }
 267
 268 sub cluster
 269 {
 270         my $nodes = Route::Node::count();
 271         my $tot = Route::User::count();
 272         my $users = scalar DXCommandmode::get_all();
 273         my $maxusers = Route::User::max();
 274         my $uptime = main::uptime();
 275
 276         return " $nodes nodes, $users local / $tot total users  Max users $maxusers  Uptime $uptime";
 277 }
 278
 279 #
 280 # routing things
 281 #
 282
 283 sub get
 284 {
 285         my $call = shift;
 286         return Route::Node::get($call) || Route::User::get($call);
 287 }
 288
 289 sub findroutes
 290 {
 291         my $call = shift;
 292         my %cand;
 293         my @out;
 294
 295         dbg("ROUTE: findroutes $call") if isdbg('findroutes');
 296
 297         my $nref = Route::get($call);
 298         return () unless $nref;
 299
 300         # we are directly connected, force "best possible" priority, but
 301         # carry on in case user is connected on other nodes.
 302         my $dxchan = DXChannel::get($call);
 303         if ($dxchan) {
 304                 dbg("ROUTE: findroutes $call -> directly connected") if isdbg('findroutes');
 305                 $cand{$call} = 99;
 306         }
 307
 308         # obtain the dxchannels that have seen this thingy
 309         my @parent = $nref->isa('Route::User') ? @{$nref->{parent}} : $call;
 310         foreach my $p (@parent) {
 311                 next if $p eq $main::mycall; # this is dealt with above
 312
 313                 # deal with directly connected nodes, again "best priority"
 314                 $dxchan = DXChannel::get($p);
 315                 if ($dxchan) {
 316                         dbg("ROUTE: findroutes $call -> connected direct via parent $p") if isdbg('findroutes');
 317                         $cand{$p} = 99;
 318                         next;
 319                 }
 320
 321                 my $r = Route::Node::get($p);
 322                 if ($r) {
 323                         my %r = $r->PC92C_dxchan;
 324                         while (my ($k, $v) = each %r) {
 325                                 $cand{$k} = $v if $v > ($cand{$k} || 0);
 326                         }
 327                 }
 328         }
 329
 330         # remove any dxchannels that have gone away
 331         while (my ($k, $v) = each %cand) {
 332                 if (my $dxc = DXChannel::get($k)) {
 333                         push @out, [$v, $dxc];
 334                 }
 335         }
 336
 337         # get a sorted list of dxchannels with the highest hop count first
 338         my @nout = sort {$b->[0] <=> $a->[0]} @out;
 339         if (isdbg('findroutes')) {
 340                 if (@nout) {
 341                         for (@nout) {
 342                                 dbg("ROUTE: findroutes $call -> $_->[0] " . $_->[1]->call);
 343                         }
 344                 }
 345         }
 346
 347         return @nout;
 348 }
 349
 350 # find all the possible dxchannels which this object might be on
 351 sub alldxchan
 352 {
 353         my $self = shift;
 354         my @dxchan = findroutes($self->{call});
 355         return map {$_->[1]} @dxchan;
 356 }
 357
 358 sub dxchan
 359 {
 360         my $self = shift;
 361
 362         # ALWAYS return the locally connected channel if present;
 363         my $dxchan = DXChannel::get($self->call);
 364         return $dxchan if $dxchan;
 365
 366         my @dxchan = $self->alldxchan;
 367         return undef unless @dxchan;
 368
 369         # dxchannels are now returned in order of "closeness"
 370         return $dxchan[0];
 371 }
 372
 373 sub delete_interface
 374 {
 375
 376 }
 377
 378 #
 379 # track destruction
 380 #
 381
 382 sub DESTROY
 383 {
 384         my $self = shift;
 385         my $pkg = ref $self;
 386
 387         dbg("$pkg $self->{call} destroyed") if isdbg('routelow');
 388 }
 389
 390 no strict;
 391 #
 392 # return a list of valid elements
 393 #
 394
 395 sub fields
 396 {
 397         my $pkg = shift;
 398         $pkg = ref $pkg if ref $pkg;
 399     my $val = "${pkg}::valid";
 400         my @out = keys %$val;
 401         push @out, keys %valid;
 402         return @out;
 403 }
 404
 405 #
 406 # return a prompt for a field
 407 #
 408
 409 sub field_prompt
 410 {
 411         my ($self, $ele) = @_;
 412         my $pkg = ref $self;
 413     my $val = "${pkg}::valid";
 414         return $val->{$ele} || $valid{$ele};
 415 }
 416
 417 #
 418 # generic AUTOLOAD for accessors
 419 #
 420 sub AUTOLOAD
 421 {
 422         no strict;
 423         my $name = $AUTOLOAD;
 424         return if $name =~ /::DESTROY$/;
 425         $name =~ s/^.*:://o;
 426
 427         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 428
 429         # this clever line of code creates a subroutine which takes over from autoload
 430         # from OO Perl - Conway
 431         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 432        goto &$AUTOLOAD;
 433
 434 }
 435
 436 1;