perl/DXUser.pm

   1 #
   2 # DX cluster user routines
   3 #
   4 # Copyright (c) 1998 - Dirk Koopman G1TLH
   5 #
   6 #
   7 #
   8
   9 package DXUser;
  10
  11 use DXLog;
  12 use DB_File;
  13 use Data::Dumper;
  14 use Fcntl;
  15 use IO::File;
  16 use DXDebug;
  17 use DXUtil;
  18 use LRU;
  19 use File::Copy;
  20
  21 use strict;
  22
  23 use vars qw(%u $dbm $filename %valid $lastoperinterval $lasttime $lru $lrusize $tooold $v3 $noips);
  24
  25 %u = ();
  26 $dbm = undef;
  27 $filename = undef;
  28 $lastoperinterval = 60*24*60*60;
  29 $lasttime = 0;
  30 $lrusize = 2000;
  31 $tooold = 86400 * 365;          # this marks an old user who hasn't given enough info to be useful
  32 $v3 = 0;
  33 $noips = 4;
  34
  35 # hash of valid elements and a simple prompt
  36 %valid = (
  37                   call => '0,Callsign',
  38                   alias => '0,Real Callsign',
  39                   name => '0,Name',
  40                   qth => '0,Home QTH',
  41                   lat => '0,Latitude,slat',
  42                   long => '0,Longitude,slong',
  43                   qra => '0,Locator',
  44                   email => '0,E-mail Address,parray',
  45                   priv => '9,Privilege Level',
  46                   lastin => '0,Last Time in,cldatetime',
  47                   passwd => '9,Password,yesno',
  48                   passphrase => '9,Pass Phrase,yesno',
  49                   addr => '0,Full Address',
  50                   'sort' => '0,Type of User', # A - ak1a, U - User, S - spider cluster, B - BBS
  51                   xpert => '0,Expert Status,yesno',
  52                   bbs => '0,Home BBS',
  53                   node => '0,Last Node',
  54                   homenode => '0,Home Node',
  55                   lockout => '9,Locked out?,yesno',     # won't let them in at all
  56                   dxok => '9,Accept DX Spots?,yesno', # accept his dx spots?
  57                   annok => '9,Accept Announces?,yesno', # accept his announces?
  58                   lang => '0,Language',
  59                   hmsgno => '0,Highest Msgno',
  60                   group => '0,Group,parray',    # used to create a group of users/nodes for some purpose or other
  61                   buddies => '0,Buddies,parray',
  62                   isolate => '9,Isolate network,yesno',
  63                   wantbeep => '0,Req Beep,yesno',
  64                   wantann => '0,Req Announce,yesno',
  65                   wantwwv => '0,Req WWV,yesno',
  66                   wantwcy => '0,Req WCY,yesno',
  67                   wantecho => '0,Req Echo,yesno',
  68                   wanttalk => '0,Req Talk,yesno',
  69                   wantwx => '0,Req WX,yesno',
  70                   wantdx => '0,Req DX Spots,yesno',
  71                   wantemail => '0,Req Msgs as Email,yesno',
  72                   pagelth => '0,Current Pagelth',
  73                   pingint => '9,Node Ping interval',
  74                   nopings => '9,Ping Obs Count',
  75                   wantlogininfo => '0,Login Info Req,yesno',
  76           wantgrid => '0,Show DX Grid,yesno',
  77                   wantann_talk => '0,Talklike Anns,yesno',
  78                   wantpc16 => '9,Want Users from node,yesno',
  79                   wantsendpc16 => '9,Send PC16,yesno',
  80                   wantroutepc19 => '9,Route PC19,yesno',
  81                   wantusstate => '0,Show US State,yesno',
  82                   wantdxcq => '0,Show CQ Zone,yesno',
  83                   wantdxitu => '0,Show ITU Zone,yesno',
  84                   wantgtk => '0,Want GTK interface,yesno',
  85                   wantpc9x => '0,Want PC9X interface,yesno',
  86                   lastoper => '9,Last for/oper,cldatetime',
  87                   nothere => '0,Not Here Text',
  88                   registered => '9,Registered?,yesno',
  89                   prompt => '0,Required Prompt',
  90                   version => '1,Version',
  91                   build => '1,Build',
  92                   believe => '1,Believable nodes,parray',
  93                   lastping => '1,Last Ping at,ptimelist',
  94                   maxconnect => '1,Max Connections',
  95                   ip => '1,IP address',
  96                  );
  97
  98 #no strict;
  99 sub AUTOLOAD
 100 {
 101         no strict;
 102         my $name = $AUTOLOAD;
 103
 104         return if $name =~ /::DESTROY$/;
 105         $name =~ s/^.*:://o;
 106
 107         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 108         # this clever line of code creates a subroutine which takes over from autoload
 109         # from OO Perl - Conway
 110         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 111        goto &$AUTOLOAD;
 112 }
 113
 114 #use strict;
 115
 116 #
 117 # initialise the system
 118 #
 119 sub init
 120 {
 121         my $mode = shift;
 122
 123         my $ufn;
 124         my $convert;
 125
 126         eval {
 127                 require Storable;
 128         };
 129
 130         my $fn = "users";
 131
 132         if ($@) {
 133                 $ufn = localdata("users.v2");
 134                 $v3 = $convert = 0;
 135                 dbg("the module Storable appears to be missing!!");
 136                 dbg("trying to continue in compatibility mode (this may fail)");
 137                 dbg("please install Storable from CPAN as soon as possible");
 138         } else {
 139                 import Storable qw(nfreeze thaw);
 140
 141                 $ufn = localdata("users.v3");
 142                 $v3 = 1;
 143                 $convert++ if -e localdata("users.v2") && !-e $ufn;
 144         }
 145
 146         if ($mode) {
 147                 $dbm = tie (%u, 'DB_File', $ufn, O_CREAT|O_RDWR, 0666, $DB_BTREE) or confess "can't open user file: $fn ($!) [rebuild it from user_asc?]";
 148         } else {
 149                 $dbm = tie (%u, 'DB_File', $ufn, O_RDONLY, 0666, $DB_BTREE) or confess "can't open user file: $fn ($!) [rebuild it from user_asc?]";
 150         }
 151
 152         die "Cannot open $ufn ($!)\n" unless $dbm;
 153
 154         $lru = LRU->newbase("DXUser", $lrusize);
 155
 156         # do a conversion if required
 157         if ($dbm && $convert) {
 158                 my ($key, $val, $action, $count, $err) = ('','',0,0,0);
 159
 160                 my %oldu;
 161                 dbg("Converting the User File to V3 ");
 162                 dbg("This will take a while, I suggest you go and have cup of strong tea");
 163                 my $odbm = tie (%oldu, 'DB_File', localdata("users.v2"), O_RDONLY, 0666, $DB_BTREE) or confess "can't open user file: $fn.v2 ($!) [rebuild it from user_asc?]";
 164         for ($action = R_FIRST; !$odbm->seq($key, $val, $action); $action = R_NEXT) {
 165                         my $ref;
 166                         eval { $ref = asc_decode($val) };
 167                         unless ($@) {
 168                                 if ($ref) {
 169                                         $ref->put;
 170                                         $count++;
 171                                 } else {
 172                                         $err++
 173                                 }
 174                         } else {
 175                                 Log('err', "DXUser: error decoding $@");
 176                         }
 177                 }
 178                 undef $odbm;
 179                 untie %oldu;
 180                 dbg("Conversion completed $count records $err errors");
 181         }
 182         $filename = $ufn;
 183 }
 184
 185 sub del_file
 186 {
 187         # with extreme prejudice
 188         unlink "$main::data/users.v3";
 189         unlink "$main::local_data/users.v3";
 190 }
 191
 192 #
 193 # periodic processing
 194 #
 195 sub process
 196 {
 197         if ($main::systime > $lasttime + 15) {
 198                 $dbm->sync if $dbm;
 199                 $lasttime = $main::systime;
 200         }
 201 }
 202
 203 #
 204 # close the system
 205 #
 206
 207 sub finish
 208 {
 209         undef $dbm;
 210         untie %u;
 211 }
 212
 213 #
 214 # new - create a new user
 215 #
 216
 217 sub alloc
 218 {
 219         my $pkg = shift;
 220         my $call = uc shift;
 221         my $self = bless {call => $call, 'sort'=>'U'}, $pkg;
 222         return $self;
 223 }
 224
 225 sub new
 226 {
 227         my $pkg = shift;
 228         my $call = shift;
 229         #  $call =~ s/-\d+$//o;
 230
 231 #       confess "can't create existing call $call in User\n!" if $u{$call};
 232
 233         my $self = $pkg->alloc($call);
 234         $self->put;
 235         return $self;
 236 }
 237
 238 #
 239 # get - get an existing user - this seems to return a different reference everytime it is
 240 #       called - see below
 241 #
 242
 243 sub get
 244 {
 245         my $call = uc shift;
 246         my $data;
 247
 248         # is it in the LRU cache?
 249         my $ref = $lru->get($call);
 250         return $ref if $ref && ref $ref eq 'DXUser';
 251
 252         # search for it
 253         unless ($dbm->get($call, $data)) {
 254                 eval { $ref = decode($data); };
 255
 256                 if ($ref) {
 257                         if (!UNIVERSAL::isa($ref, 'DXUser')) {
 258                                 dbg("DXUser::get: got strange answer from decode of $call". ref $ref. " ignoring");
 259                                 return undef;
 260                         }
 261                         # we have a reference and it *is* a DXUser
 262                 } else {
 263                         if ($@) {
 264                                 LogDbg('err', "DXUser::get decode error on $call '$@'");
 265                         } else {
 266                                 dbg("DXUser::get: no reference returned from decode of $call $!");
 267                         }
 268                         return undef;
 269                 }
 270                 $lru->put($call, $ref);
 271                 return $ref;
 272         }
 273         return undef;
 274 }
 275
 276 #
 277 # get an existing either from the channel (if there is one) or from the database
 278 #
 279 # It is important to note that if you have done a get (for the channel say) and you
 280 # want access or modify that you must use this call (and you must NOT use get's all
 281 # over the place willy nilly!)
 282 #
 283
 284 sub get_current
 285 {
 286         my $call = uc shift;
 287
 288         my $dxchan = DXChannel::get($call);
 289         if ($dxchan) {
 290                 my $ref = $dxchan->user;
 291                 return $ref if $ref && UNIVERSAL::isa($ref, 'DXUser');
 292
 293                 dbg("DXUser::get_current: got invalid user ref for $call from dxchan $dxchan->{call} ". ref $ref. " ignoring");
 294         }
 295         return get($call);
 296 }
 297
 298 #
 299 # get all callsigns in the database
 300 #
 301
 302 sub get_all_calls
 303 {
 304         return (sort keys %u);
 305 }
 306
 307 #
 308 # put - put a user
 309 #
 310
 311 sub put
 312 {
 313         my $self = shift;
 314         confess "Trying to put nothing!" unless $self && ref $self;
 315         my $call = $self->{call};
 316
 317         $dbm->del($call);
 318         delete $self->{annok} if $self->{annok};
 319         delete $self->{dxok} if $self->{dxok};
 320
 321         $lru->put($call, $self);
 322         my $ref = $self->encode;
 323         $dbm->put($call, $ref);
 324 }
 325
 326 # freeze the user
 327 sub encode
 328 {
 329         goto &asc_encode unless $v3;
 330         my $self = shift;
 331         return nfreeze($self);
 332 }
 333
 334 # thaw the user
 335 sub decode
 336 {
 337         goto &asc_decode unless $v3;
 338         my $ref;
 339         $ref = thaw(shift);
 340         return $ref;
 341 }
 342
 343 #
 344 # create a string from a user reference (in_ascii)
 345 #
 346 sub asc_encode
 347 {
 348         my $self = shift;
 349         my $strip = shift;
 350         my $p;
 351
 352         if ($strip) {
 353                 my $ref = bless {}, ref $self;
 354                 foreach my $k (qw(qth lat long qra sort call homenode node lastoper lastin)) {
 355                         $ref->{$k} = $self->{$k} if exists $self->{$k};
 356                 }
 357                 $ref->{name} = $self->{name} if exists $self->{name} && $self->{name} !~ /selfspot/i;
 358                 $p = dd($ref);
 359         } else {
 360                 $p = dd($self);
 361         }
 362         return $p;
 363 }
 364
 365 #
 366 # create a hash from a string (in ascii)
 367 #
 368 sub asc_decode
 369 {
 370         my $s = shift;
 371         my $ref;
 372         $s =~ s/\%([0-9A-F][0-9A-F])/chr(hex($1))/eg;
 373         eval '$ref = ' . $s;
 374         if ($@) {
 375                 LogDbg('err', "DXUser::asc_decode: on '$s' $@");
 376                 $ref = undef;
 377         }
 378         return $ref;
 379 }
 380
 381 #
 382 # del - delete a user
 383 #
 384
 385 sub del
 386 {
 387         my $self = shift;
 388         my $call = $self->{call};
 389         $lru->remove($call);
 390         $dbm->del($call);
 391 }
 392
 393 #
 394 # close - close down a user
 395 #
 396
 397 sub close
 398 {
 399         my $self = shift;
 400         $self->{lastin} = time;
 401         $self->put();
 402 }
 403
 404 #
 405 # sync the database
 406 #
 407
 408 sub sync
 409 {
 410         $dbm->sync;
 411 }
 412
 413 #
 414 # return a list of valid elements
 415 #
 416
 417 sub fields
 418 {
 419         return keys(%valid);
 420 }
 421
 422
 423 #
 424 # export the database to an ascii file
 425 #
 426
 427 sub export
 428 {
 429         my $name = shift || 'user_asc';
 430         my $basic_info_only = shift;
 431
 432         my $fn = $name ne 'user_asc' ? $name : "$main::local_data/$name";                       # force use of local
 433
 434         # save old ones
 435         move "$fn.oooo", "$fn.ooooo" if -e "$fn.oooo";
 436         move "$fn.ooo", "$fn.oooo" if -e "$fn.ooo";
 437         move "$fn.oo", "$fn.ooo" if -e "$fn.oo";
 438         move "$fn.o", "$fn.oo" if -e "$fn.o";
 439         move "$fn", "$fn.o" if -e "$fn";
 440
 441         my $count = 0;
 442         my $err = 0;
 443         my $del = 0;
 444         my $fh = new IO::File ">$fn" or return "cannot open $fn ($!)";
 445         if ($fh) {
 446                 my $key = 0;
 447                 my $val = undef;
 448                 my $action;
 449                 my $t = scalar localtime;
 450                 print $fh q{#!/usr/bin/perl
 451 #
 452 # The exported userfile for a DXSpider System
 453 #
 454 # Input file: $filename
 455 #       Time: $t
 456 #
 457
 458 package main;
 459
 460 # search local then perl directories
 461 BEGIN {
 462         umask 002;
 463
 464         # root of directory tree for this system
 465         $root = "/spider";
 466         $root = $ENV{'DXSPIDER_ROOT'} if $ENV{'DXSPIDER_ROOT'};
 467
 468         unshift @INC, "$root/perl";     # this IS the right way round!
 469         unshift @INC, "$root/local";
 470
 471         # try to detect a lockfile (this isn't atomic but
 472         # should do for now
 473         $lockfn = "$root/local_data/cluster.lck";       # lock file name
 474         if (-e $lockfn) {
 475                 open(CLLOCK, "$lockfn") or die "Can't open Lockfile ($lockfn) $!";
 476                 my $pid = <CLLOCK>;
 477                 chomp $pid;
 478                 die "Lockfile ($lockfn) and process $pid exists - cluster must be stopped first\n" if kill 0, $pid;
 479                 close CLLOCK;
 480         }
 481 }
 482
 483 use SysVar;
 484 use DXUser;
 485
 486 if (@ARGV) {
 487         $main::userfn = shift @ARGV;
 488         print "user filename now $userfn\n";
 489 }
 490
 491 package DXUser;
 492
 493 del_file();
 494 init(1);
 495 %u = ();
 496 my $count = 0;
 497 my $err = 0;
 498 while (<DATA>) {
 499         chomp;
 500         my @f = split /\t/;
 501         my $ref = asc_decode($f[1]);
 502         if ($ref) {
 503                 $ref->put();
 504                 $count++;
 505         DXUser::sync() unless $count % 10000;
 506         } else {
 507                 print "# Error: $f[0]\t$f[1]\n";
 508                 $err++
 509         }
 510 }
 511 DXUser::sync(); DXUser::finish();
 512 print "There are $count user records and $err errors\n";
 513 };
 514                 print $fh "__DATA__\n";
 515
 516         for ($action = R_FIRST; !$dbm->seq($key, $val, $action); $action = R_NEXT) {
 517                         if (!is_callsign($key) || $key =~ /^0/) {
 518                                 my $eval = $val;
 519                                 my $ekey = $key;
 520                                 $eval =~ s/([\%\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 521                                 $ekey =~ s/([\%\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 522                                 LogDbg('DXCommand', "Export Error1: $ekey\t$eval");
 523                                 eval {$dbm->del($key)};
 524                                 dbg(carp("Export Error1: $ekey\t$eval\n$@")) if $@;
 525                                 ++$err;
 526                                 next;
 527                         }
 528                         my $ref;
 529                         eval {$ref = decode($val); };
 530                         if ($ref) {
 531                                 my $t = $ref->{lastin} || 0;
 532                                 if ($ref->is_user && !$ref->{priv} && $main::systime > $t + $tooold) {
 533                                         unless ($ref->{lat} && $ref->{long} || $ref->{qth} || $ref->{qra}) {
 534                                                 eval {$dbm->del($key)};
 535                                                 dbg(carp("Export Error2: $key\t$val\n$@")) if $@;
 536                                                 LogDbg('DXCommand', "$ref->{call} deleted, too old");
 537                                                 $del++;
 538                                                 next;
 539                                         }
 540                                 }
 541                                 # only store users that are reasonably active or have useful information
 542                                 print $fh "$key\t" . $ref->asc_encode($basic_info_only) . "\n";
 543                                 ++$count;
 544                         } else {
 545                                 LogDbg('DXCommand', "Export Error3: $key\t" . carp($val) ."\n$@");
 546                                 eval {$dbm->del($key)};
 547                                 dbg(carp("Export Error3: $key\t$val\n$@")) if $@;
 548                                 ++$err;
 549                         }
 550                 }
 551         $fh->close;
 552     }
 553         my $s = qq{Exported users to $fn - $count Users $del Deleted $err Errors ('sh/log Export' for details)};
 554         LogDbg('command', $s);
 555         return $s;
 556 }
 557
 558 #
 559 # group handling
 560 #
 561
 562 # add one or more groups
 563 sub add_group
 564 {
 565         my $self = shift;
 566         my $ref = $self->{group} || [ 'local' ];
 567         $self->{group} = $ref if !$self->{group};
 568         push @$ref, @_ if @_;
 569 }
 570
 571 # remove one or more groups
 572 sub del_group
 573 {
 574         my $self = shift;
 575         my $ref = $self->{group} || [ 'local' ];
 576         my @in = @_;
 577
 578         $self->{group} = $ref if !$self->{group};
 579
 580         @$ref = map { my $a = $_; return (grep { $_ eq $a } @in) ? () : $a } @$ref;
 581 }
 582
 583 # does this thing contain all the groups listed?
 584 sub union
 585 {
 586         my $self = shift;
 587         my $ref = $self->{group};
 588         my $n;
 589
 590         return 0 if !$ref || @_ == 0;
 591         return 1 if @$ref == 0 && @_ == 0;
 592         for ($n = 0; $n < @_; ) {
 593                 for (@$ref) {
 594                         my $a = $_;
 595                         $n++ if grep $_ eq $a, @_;
 596                 }
 597         }
 598         return $n >= @_;
 599 }
 600
 601 # simplified group test just for one group
 602 sub in_group
 603 {
 604         my $self = shift;
 605         my $s = shift;
 606         my $ref = $self->{group};
 607
 608         return 0 if !$ref;
 609         return grep $_ eq $s, $ref;
 610 }
 611
 612 # set up a default group (only happens for them's that connect direct)
 613 sub new_group
 614 {
 615         my $self = shift;
 616         $self->{group} = [ 'local' ];
 617 }
 618
 619 # set up empty buddies (only happens for them's that connect direct)
 620 sub new_buddies
 621 {
 622         my $self = shift;
 623         $self->{buddies} = [  ];
 624 }
 625
 626 #
 627 # return a prompt for a field
 628 #
 629
 630 sub field_prompt
 631 {
 632         my ($self, $ele) = @_;
 633         return $valid{$ele};
 634 }
 635
 636 # some variable accessors
 637 sub sort
 638 {
 639         my $self = shift;
 640         @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 641 }
 642
 643 # some accessors
 644
 645 # want is default = 1
 646 sub _want
 647 {
 648         my $n = shift;
 649         my $self = shift;
 650         my $val = shift;
 651         my $s = "want$n";
 652         $self->{$s} = $val if defined $val;
 653         return exists $self->{$s} ? $self->{$s} : 1;
 654 }
 655
 656 # wantnot is default = 0
 657 sub _wantnot
 658 {
 659         my $n = shift;
 660         my $self = shift;
 661         my $val = shift;
 662         my $s = "want$n";
 663         $self->{$s} = $val if defined $val;
 664         return exists $self->{$s} ? $self->{$s} : 0;
 665 }
 666
 667 sub wantbeep
 668 {
 669         return _want('beep', @_);
 670 }
 671
 672 sub wantann
 673 {
 674         return _want('ann', @_);
 675 }
 676
 677 sub wantwwv
 678 {
 679         return _want('wwv', @_);
 680 }
 681
 682 sub wantwcy
 683 {
 684         return _want('wcy', @_);
 685 }
 686
 687 sub wantecho
 688 {
 689         return _want('echo', @_);
 690 }
 691
 692 sub wantwx
 693 {
 694         return _want('wx', @_);
 695 }
 696
 697 sub wantdx
 698 {
 699         return _want('dx', @_);
 700 }
 701
 702 sub wanttalk
 703 {
 704         return _want('talk', @_);
 705 }
 706
 707 sub wantgrid
 708 {
 709         return _want('grid', @_);
 710 }
 711
 712 sub wantemail
 713 {
 714         return _want('email', @_);
 715 }
 716
 717 sub wantann_talk
 718 {
 719         return _want('ann_talk', @_);
 720 }
 721
 722 sub wantpc16
 723 {
 724         return _want('pc16', @_);
 725 }
 726
 727 sub wantsendpc16
 728 {
 729         return _want('sendpc16', @_);
 730 }
 731
 732 sub wantroutepc16
 733 {
 734         return _want('routepc16', @_);
 735 }
 736
 737 sub wantusstate
 738 {
 739         return _want('usstate', @_);
 740 }
 741
 742 sub wantdxcq
 743 {
 744         return _want('dxcq', @_);
 745 }
 746
 747 sub wantdxitu
 748 {
 749         return _want('dxitu', @_);
 750 }
 751
 752 sub wantgtk
 753 {
 754         return _want('gtk', @_);
 755 }
 756
 757 sub wantpc9x
 758 {
 759         return _want('pc9x', @_);
 760 }
 761
 762 sub wantlogininfo
 763 {
 764         my $self = shift;
 765         my $val = shift;
 766         $self->{wantlogininfo} = $val if defined $val;
 767         return $self->{wantlogininfo};
 768 }
 769
 770 sub is_node
 771 {
 772         my $self = shift;
 773         return $self->{sort} =~ /^[ACRSX]$/;
 774 }
 775
 776 sub is_local_node
 777 {
 778         my $self = shift;
 779         return grep $_ eq 'local_node', @{$self->{group}};
 780 }
 781
 782 sub is_user
 783 {
 784         my $self = shift;
 785         return $self->{sort} =~ /^[UW]$/;
 786 }
 787
 788 sub is_web
 789 {
 790         my $self = shift;
 791         return $self->{sort} eq 'W';
 792 }
 793
 794 sub is_bbs
 795 {
 796         my $self = shift;
 797         return $self->{sort} eq 'B';
 798 }
 799
 800 sub is_spider
 801 {
 802         my $self = shift;
 803         return $self->{sort} eq 'S';
 804 }
 805
 806 sub is_clx
 807 {
 808         my $self = shift;
 809         return $self->{sort} eq 'C';
 810 }
 811
 812 sub is_dxnet
 813 {
 814         my $self = shift;
 815         return $self->{sort} eq 'X';
 816 }
 817
 818 sub is_arcluster
 819 {
 820         my $self = shift;
 821         return $self->{sort} eq 'R';
 822 }
 823
 824 sub is_ak1a
 825 {
 826         my $self = shift;
 827         return $self->{sort} eq 'A';
 828 }
 829
 830 sub unset_passwd
 831 {
 832         my $self = shift;
 833         delete $self->{passwd};
 834 }
 835
 836 sub unset_passphrase
 837 {
 838         my $self = shift;
 839         delete $self->{passphrase};
 840 }
 841
 842 sub set_believe
 843 {
 844         my $self = shift;
 845         my $call = uc shift;
 846         $self->{believe} ||= [];
 847         push @{$self->{believe}}, $call unless grep $_ eq $call, @{$self->{believe}};
 848 }
 849
 850 sub unset_believe
 851 {
 852         my $self = shift;
 853         my $call = uc shift;
 854         if (exists $self->{believe}) {
 855                 $self->{believe} = [grep {$_ ne $call} @{$self->{believe}}];
 856                 delete $self->{believe} unless @{$self->{believe}};
 857         }
 858 }
 859
 860 sub believe
 861 {
 862         my $self = shift;
 863         return exists $self->{believe} ? @{$self->{believe}} : ();
 864 }
 865
 866 sub lastping
 867 {
 868         my $self = shift;
 869         my $call = shift;
 870         $self->{lastping} ||= {};
 871         $self->{lastping} = {} unless ref $self->{lastping};
 872         my $b = $self->{lastping};
 873         $b->{$call} = shift if @_;
 874         return $b->{$call};
 875 }
 876 1;
 877 __END__
 878
 879
 880
 881
 882