perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35
  36 use strict;
  37
  38 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  39                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  40                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  41                         $investigation_int $pc19_version $myprot_version
  42                         %nodehops $baddx $badspotter $badnode $censorpc
  43                         $allowzero $decode_dk0wcy $send_opernam @checklist
  44                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  45                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  46                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  47                         $pc92filterdef
  48                    );
  49
  50 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  51 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  52 $pc92_slug_changes = 60*5;              # slug any changes going outward for this long
  53 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  54 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  55 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  56         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  57                                 # this is actually the partition between "yesterday" and "today" but old.
  58
  59 $pc92filterdef = bless ([
  60                           # tag, sort, field, priv, special parser
  61                           ['call', 'c', 0],
  62                           ['by', 'c', 0],
  63                           ['dxcc', 'nc', 1],
  64                           ['itu', 'ni', 2],
  65                           ['zone', 'nz', 3],
  66                          ], 'Filter::Cmd');
  67
  68
  69 # incoming talk commands
  70 sub handle_10
  71 {
  72         my $self = shift;
  73         my $pcno = shift;
  74         my $line = shift;
  75         my $origin = shift;
  76         my $pc = shift;
  77
  78         # this is to catch loops caused by bad software ...
  79         if (eph_dup($line, $pc10_dupe_age)) {
  80                 return;
  81         }
  82
  83         # will we allow it at all?
  84         if ($censorpc) {
  85                 my @bad;
  86                 if (@bad = BadWords::check($pc->[3])) {
  87                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  88                         return;
  89                 }
  90         }
  91
  92         # is it for me or one of mine?
  93         my ($from, $to, $via, $call, $dxchan);
  94         $from = $pc->[1];
  95         if ($pc->[5] gt ' ') {
  96                 $via = $pc->[2];
  97                 $to = $pc->[5];
  98         } else {
  99                 $to = $pc->[2];
 100         }
 101
 102         # if this is a 'nodx' node then ignore it
 103         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 104                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 105                 return;
 106         }
 107
 108         # if this is a 'bad spotter' user then ignore it
 109         my $nossid = $from;
 110         $nossid =~ s/-\d+$//;
 111         if ($badspotter->in($nossid)) {
 112                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 113                 return;
 114         }
 115
 116         # if we are converting announces to talk is it a dup?
 117         if ($ann_to_talk) {
 118                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 119                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 120                         return;
 121                 }
 122         }
 123
 124         # convert this to a PC93, coming from mycall with origin set and process it as such
 125         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]));
 126 }
 127
 128 # DX Spot handling
 129 sub handle_11
 130 {
 131         my $self = shift;
 132         my $pcno = shift;
 133         my $line = shift;
 134         my $origin = shift;
 135         my $pc = shift;
 136
 137         # route 'foreign' pc26s
 138         if ($pcno == 26) {
 139                 if ($pc->[7] ne $main::mycall) {
 140                         $self->route($pc->[7], $line);
 141                         return;
 142                 }
 143         }
 144
 145 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 146
 147         # is the spotted callsign blank? This should really be trapped earlier but it
 148         # could break other protocol sentences. Also check for lower case characters.
 149         if ($pc->[2] =~ /^\s*$/) {
 150                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 151                 return;
 152         }
 153         if ($pc->[2] =~ /[a-z]/) {
 154                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 155                 return;
 156         }
 157
 158
 159         # if this is a 'nodx' node then ignore it
 160         if ($badnode->in($pc->[7])) {
 161                 dbg("PCPROT: Bad Node $pc->[7], dropped") if isdbg('chanerr');
 162                 return;
 163         }
 164
 165         # if this is a 'bad spotter' or an unknown user then ignore it. BUT if it's got an IP address then allow it through
 166         my $nossid = $pc->[6];
 167         $nossid =~ s/-\d+$//;
 168         if ($badspotter->in($nossid)) {
 169                 dbg("PCPROT: Bad Spotter $pc->[6], dropped") if isdbg('chanerr');
 170                 return;
 171         }
 172 #       unless (is_ipaddr($pc->[8]) || DXUser::get_current($pc->[6])) {
 173 #               dbg("PCPROT: Unknown Spotter $pc->[6], dropped") if isdbg('chanerr');
 174 #               return;
 175 #       }
 176
 177         # convert the date to a unix date
 178         my $d = cltounix($pc->[3], $pc->[4]);
 179         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 180         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 181                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n") if isdbg('chanerr');
 182                 return;
 183         }
 184
 185         # is it 'baddx'
 186         if ($baddx->in($pc->[2]) || BadWords::check($pc->[2])) {
 187                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 188                 return;
 189         }
 190
 191         # do some de-duping
 192         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 193         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 194         if ($pc->[2] =~ /BUST\w*$/) {
 195                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 196                 return;
 197         }
 198         if ($censorpc) {
 199                 my @bad;
 200                 if (@bad = BadWords::check($pc->[5])) {
 201                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 202                         return;
 203                 }
 204         }
 205
 206         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 207         # global spot filtering on INPUT
 208         if ($self->{inspotsfilter}) {
 209                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 210                 unless ($filter) {
 211                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 212                         return;
 213                 }
 214         }
 215
 216         # this goes after the input filtering, but before the add
 217         # so that if it is input filtered, it isn't added to the dup
 218         # list. This allows it to come in from a "legitimate" source
 219         if (Spot::dup(@spot[0..4,5])) {
 220                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         # add it
 225         Spot::add(@spot);
 226
 227         my $ip = '';
 228         $ip ||= $spot[14] if exists $spot[14];
 229         if (isdbg('progress')) {
 230                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 231                 $sip ||= '';
 232                 my $d = ztime($spot[2]);
 233                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 234                 $s .= $spot[3] ? " '$spot[3]'" : q{ ''};
 235                 $s .=  " route: $origin";
 236                 dbg($s);
 237         }
 238
 239         #
 240         # @spot at this point contains:-
 241         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 242         # then  spotted itu, spotted cq, spotters itu, spotters cq
 243         # you should be able to route on any of these
 244         #
 245
 246         # fix up qra locators of known users
 247         my $user = DXUser::get_current($spot[4]);
 248         if ($user) {
 249                 my $qra = $user->qra;
 250                 unless ($qra && is_qra($qra)) {
 251                         my $lat = $user->lat;
 252                         my $long = $user->long;
 253                         if (defined $lat && defined $long) {
 254                                 $user->qra(DXBearing::lltoqra($lat, $long));
 255                                 $user->put;
 256                         }
 257                 }
 258
 259                 # send a remote command to a distant cluster if it is visible and there is no
 260                 # qra locator and we havn't done it for a month.
 261
 262                 unless ($user->qra) {
 263                         my $node;
 264                         my $to = $user->homenode;
 265                         my $last = $user->lastoper || 0;
 266                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 267                                 my $cmd = "forward/opernam $spot[4]";
 268                                 # send the rcmd but we aren't interested in the replies...
 269                                 my $dxchan = $node->dxchan;
 270                                 if ($dxchan && $dxchan->is_clx) {
 271                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 272                                 } else {
 273                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 274                                 }
 275                                 if ($to ne $pc->[7]) {
 276                                         $to = $pc->[7];
 277                                         $node = Route::Node::get($to);
 278                                         if ($node) {
 279                                                 $dxchan = $node->dxchan;
 280                                                 if ($dxchan && $dxchan->is_clx) {
 281                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 282                                                 } else {
 283                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 284                                                 }
 285                                         }
 286                                 }
 287                                 $user->lastoper($main::systime);
 288                                 $user->put;
 289                         }
 290                 }
 291         }
 292
 293         # local processing
 294         if (defined &Local::spot) {
 295                 my $r;
 296                 eval {
 297                         $r = Local::spot($self, @spot);
 298                 };
 299                 return if $r;
 300         }
 301
 302         # DON'T be silly and send on PC26s!
 303         return if $pcno == 26;
 304
 305         # send out the filtered spots
 306         send_dx_spot($self, $line, @spot) if @spot;
 307 }
 308
 309 # announces
 310 sub handle_12
 311 {
 312         my $self = shift;
 313         my $pcno = shift;
 314         my $line = shift;
 315         my $origin = shift;
 316         my $pc = shift;
 317
 318         # announce duplicate checking
 319         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 320
 321         if ($censorpc) {
 322                 my @bad;
 323                 if (@bad = BadWords::check($pc->[3])) {
 324                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 325                         return;
 326                 }
 327         }
 328
 329         # if this is a 'nodx' node then ignore it
 330         if ($badnode->in($pc->[5])) {
 331                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 332                 return;
 333         }
 334
 335         # if this is a 'bad spotter' user then ignore it
 336         my $nossid = $pc->[1];
 337         $nossid =~ s/-\d+$//;
 338         if ($badspotter->in($nossid)) {
 339                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 340                 return;
 341         }
 342
 343         # ignore PC12s from origins that use PCxx protocol
 344         my $oref = Route::get($origin);
 345         if ($oref->do_pc9x) {
 346                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 347                 return;
 348         }
 349
 350         my $dxchan;
 351
 352         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 353                 $self->send_chat(0, $line, @$pc[1..6]);
 354         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 355
 356                 # ignore something that looks like a chat line coming in with sysop
 357                 # flag - this is a kludge...
 358                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 359                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 360                         return;
 361                 }
 362
 363                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 364                 # or one saying 'to <call>' to a talk if we can route to the recipient
 365                 if ($ann_to_talk) {
 366                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 367                         if ($call) {
 368                                 my $ref = Route::get($call);
 369                                 if ($ref) {
 370                                         $dxchan = $ref->dxchan;
 371                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 372                                         return;
 373                                 }
 374                         }
 375                 }
 376
 377                 # send it
 378                 $self->send_announce(0, $line, @$pc[1..6]);
 379         } else {
 380                 $self->route($pc->[2], $line);
 381         }
 382
 383         # local processing
 384         if (defined &Local::ann) {
 385                 my $r;
 386                 eval {
 387                         $r = Local::ann($self, $line, @$pc[1..6]);
 388                 };
 389                 return if $r;
 390         }
 391 }
 392
 393 sub handle_15
 394 {
 395         my $self = shift;
 396         my $pcno = shift;
 397         my $line = shift;
 398         my $origin = shift;
 399         my $pc = shift;
 400
 401         if (eph_dup($line, $eph_pc15_restime)) {
 402                 return;
 403         } else {
 404                 unless ($self->{isolate}) {
 405                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 406                 }
 407         }
 408 }
 409
 410 # incoming user
 411 sub handle_16
 412 {
 413         my $self = shift;
 414         my $pcno = shift;
 415         my $line = shift;
 416         my $origin = shift;
 417         my $pc = shift;
 418
 419         # general checks
 420         my $dxchan;
 421         my $ncall = $pc->[1];
 422         my $newline = "PC16^";
 423
 424         # dos I want users from this channel?
 425         unless ($self->user->wantpc16) {
 426                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 427                 return;
 428         }
 429
 430         # is it me?
 431         if ($ncall eq $main::mycall) {
 432                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 433                 return;
 434         }
 435
 436         my $h;
 437         $h = 1 if DXChannel::get($ncall);
 438         if ($h && $self->{call} ne $ncall) {
 439                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 440                 return;
 441         }
 442
 443         if (eph_dup($line)) {
 444                 return;
 445         }
 446
 447         # isolate now means only accept stuff from this call only
 448         if ($self->{isolate} && $ncall ne $self->{call}) {
 449                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 450                 return;
 451         }
 452
 453         my $parent = Route::Node::get($ncall);
 454
 455         if ($parent) {
 456                 $dxchan = $parent->dxchan;
 457                 if ($dxchan && $dxchan ne $self) {
 458                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 459                         return;
 460                 }
 461
 462                 # input filter if required
 463                 return unless $self->in_filter_route($parent);
 464         } else {
 465                 $parent = Route::Node->new($ncall);
 466         }
 467
 468         unless ($h) {
 469                 if ($parent->via_pc92) {
 470                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 471                         return;
 472                 }
 473         }
 474
 475         my $i;
 476         my @rout;
 477         for ($i = 2; $i < $#$pc; $i++) {
 478                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 479                 next unless $call && $conf && defined $here && is_callsign($call);
 480                 next if $call eq $main::mycall;
 481
 482                 eph_del_regex("^PC17\\^$call\\^$ncall");
 483
 484                 $conf = $conf eq '*';
 485
 486                 # reject this if we think it is a node already
 487                 my $r = Route::Node::get($call);
 488                 my $u = DXUser::get_current($call) unless $r;
 489                 if ($r || ($u && $u->is_node)) {
 490                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 491                         next;
 492                 }
 493
 494                 $r = Route::User::get($call);
 495                 my $flags = Route::here($here)|Route::conf($conf);
 496
 497                 if ($r) {
 498                         my $au = $r->addparent($parent);
 499                         if ($r->flags != $flags) {
 500                                 $r->flags($flags);
 501                                 $au = $r;
 502                         }
 503                         push @rout, $r if $h && $au;
 504                 } else {
 505                         my @ans = $parent->add_user($call, $flags);
 506                         push @rout, @ans if $h && @ans;
 507                 }
 508
 509                 # add this station to the user database, if required
 510                 my $user = DXUser::get_current($ncall);
 511                 $user = DXUser->new($call) unless $user;
 512                 $user->homenode($parent->call) if !$user->homenode;
 513                 $user->node($parent->call);
 514                 $user->lastin($main::systime) unless DXChannel::get($call);
 515                 $user->put;
 516
 517                 # send info to all logged in thingies
 518                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 519                 $self->tell_buddies('loginb', $call, $ncall);
 520         }
 521         if (@rout) {
 522                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 523 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 524         }
 525 }
 526
 527 # remove a user
 528 sub handle_17
 529 {
 530         my $self = shift;
 531         my $pcno = shift;
 532         my $line = shift;
 533         my $origin = shift;
 534         my $pc = shift;
 535
 536         my $dxchan;
 537         my $ncall = $pc->[2];
 538         my $ucall = $pc->[1];
 539
 540         eph_del_regex("^PC16\\^$ncall.*$ucall");
 541
 542         # do I want users from this channel?
 543         unless ($self->user->wantpc16) {
 544                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 545                 return;
 546         }
 547
 548         if ($ncall eq $main::mycall) {
 549                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 550                 return;
 551         }
 552
 553         # isolate now means only accept stuff from this call only
 554         if ($self->{isolate} && $ncall ne $self->{call}) {
 555                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 556                 return;
 557         }
 558
 559         my $uref = Route::User::get($ucall);
 560         unless ($uref) {
 561                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 562                 return;
 563         }
 564         my $parent = Route::Node::get($ncall);
 565         unless ($parent) {
 566                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 567                 return;
 568         }
 569
 570         $dxchan = DXChannel::get($ncall);
 571         if ($dxchan && $dxchan ne $self) {
 572                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 573                 return;
 574         }
 575
 576         unless ($dxchan) {
 577                 if ($parent->via_pc92) {
 578                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 579                         return;
 580                 }
 581         }
 582
 583         if (DXChannel::get($ucall)) {
 584                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 585                 return;
 586         }
 587
 588         # input filter if required and then remove user if present
 589 #               return unless $self->in_filter_route($parent);
 590         $parent->del_user($uref);
 591
 592         # send info to all logged in thingies
 593         my $user = DXUser::get_current($ncall);
 594         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 595         $self->tell_buddies('logoutb', $ucall, $ncall);
 596
 597         if (eph_dup($line)) {
 598                 return;
 599         }
 600
 601         $self->route_pc17($origin, $line, $parent, $uref);
 602 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 603 }
 604
 605 # link request
 606 sub handle_18
 607 {
 608         my $self = shift;
 609         my $pcno = shift;
 610         my $line = shift;
 611         my $origin = shift;
 612         my $pc = shift;
 613
 614         $self->state('init');
 615
 616         my $parent = Route::Node::get($self->{call});
 617
 618         # record the type and version offered
 619         if (my ($version) = $pc->[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 620                 $self->{version} = 53 + $version;
 621                 $self->user->version(53 + $version);
 622                 $parent->version(0 + $version);
 623                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 624                 $self->{build} = 0 + $build;
 625                 $self->user->build(0 + $build);
 626                 $parent->build(0 + $build);
 627                 dbg("$self->{call} = DXSpider version $version build $build");
 628                 unless ($self->is_spider) {
 629                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 630                         $self->user->sort('S');
 631                         $self->user->put;
 632                         $self->sort('S');
 633                 }
 634 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 635         } else {
 636                 dbg("$self->{call} = Unknown software ($pc->[1] $pc->[2])");
 637                 $self->version(50.0);
 638                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 639                 $self->user->version($self->version);
 640         }
 641
 642         if ($pc->[1] =~ /\bpc9x/) {
 643                 if ($self->{isolate}) {
 644                         dbg("$self->{call} pc9x recognised, but node is isolated, using old protocol");
 645                 } elsif (!$self->user->wantpc9x) {
 646                         dbg("$self->{call} pc9x explicitly switched off, using old protocol");
 647                 } else {
 648                         $self->{do_pc9x} = 1;
 649                         dbg("$self->{call} Set do PC9x");
 650                 }
 651         }
 652
 653         # first clear out any nodes on this dxchannel
 654         my @rout = $parent->del_nodes;
 655         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 656         $self->send_local_config();
 657         $self->send(pc20());
 658 }
 659
 660 sub check_add_node
 661 {
 662         my $call = shift;
 663
 664         # add this station to the user database, if required (don't remove SSID from nodes)
 665         my $user = DXUser::get_current($call);
 666         unless ($user) {
 667                 $user = DXUser->new($call);
 668                 $user->priv(1);         # I have relented and defaulted nodes
 669                 $user->lockout(1);
 670                 $user->homenode($call);
 671                 $user->node($call);
 672                 $user->sort('A');
 673                 $user->lastin($main::systime); # this make it last longer than just this invocation
 674                 $user->put;                             # just to make sure it gets written away!!!
 675         }
 676         return $user;
 677 }
 678
 679 # incoming cluster list
 680 sub handle_19
 681 {
 682         my $self = shift;
 683         my $pcno = shift;
 684         my $line = shift;
 685         my $origin = shift;
 686         my $pc = shift;
 687
 688         my $i;
 689         my $newline = "PC19^";
 690
 691         # new routing list
 692         my (@rout, @pc92out);
 693
 694         # first get the INTERFACE node
 695         my $parent = Route::Node::get($self->{call});
 696         unless ($parent) {
 697                 dbg("PCPROT: my parent $self->{call} has disappeared");
 698                 $self->disconnect;
 699                 return;
 700         }
 701
 702         my $h;
 703
 704         # parse the PC19
 705         #
 706         # We are making a major change from now on. We are only going to accept
 707         # PC19s from directly connected nodes.  This means that we are probably
 708         # going to throw away most of the data that we are being sent.
 709         #
 710         # The justification for this is that most of it is wrong or out of date
 711         # anyway.
 712         #
 713         # From now on we are only going to believe PC92 data and locally connected
 714         # non-pc92 nodes.
 715         #
 716         for ($i = 1; $i < $#$pc-1; $i += 4) {
 717                 my $here = $pc->[$i];
 718                 my $call = uc $pc->[$i+1];
 719                 my $conf = $pc->[$i+2];
 720                 my $ver = $pc->[$i+3];
 721                 next unless defined $here && defined $conf && is_callsign($call);
 722
 723                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 724
 725                 # check for sane parameters
 726                 #                               $ver = 5000 if $ver eq '0000';
 727                 next unless $ver && $ver =~ /^\d+$/;
 728                 next if $ver < 5000;    # only works with version 5 software
 729                 next if length $call < 3; # min 3 letter callsigns
 730                 next if $call eq $main::mycall || $call eq $main::myalias;
 731
 732                 # check that this PC19 isn't trying to alter the wrong dxchan
 733                 $h = 0;
 734                 my $dxchan = DXChannel::get($call);
 735                 if ($dxchan) {
 736                         if ($dxchan == $self) {
 737                                 $h = 1;
 738                         } else {
 739                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 740                                 next;
 741                         }
 742                 }
 743
 744                 # isolate now means only accept stuff from this call only
 745                 if ($self->{isolate} && $call ne $self->{call}) {
 746                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 747                         next;
 748                 }
 749
 750                 my $user = check_add_node($call);
 751
 752 #               if (eph_dup($genline)) {
 753 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 754 #                       next;
 755 #               }
 756
 757
 758                 unless ($h) {
 759                         if ($parent->via_pc92) {
 760                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 761                                 next;
 762                         }
 763                 }
 764
 765                 my $r = Route::Node::get($call);
 766                 my $flags = Route::here($here)|Route::conf($conf);
 767
 768                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 769                 if ($r) {
 770                         my $ar;
 771                         if ($call ne $parent->call) {
 772                                 if ($self->in_filter_route($r)) {
 773                                         $ar = $parent->add($call, $ver, $flags);
 774 #                                       push @rout, $ar if $ar;
 775                                 } else {
 776                                         next;
 777                                 }
 778                         }
 779                         if ($r->version ne $ver || $r->flags != $flags) {
 780                                 $r->version($ver);
 781                                 $r->flags($flags);
 782                         }
 783                         push @rout, $r;
 784                 } else {
 785                         if ($call eq $self->{call} || $user->wantroutepc19) {
 786                                 my $new = Route->new($call); # throw away
 787                                 if ($self->in_filter_route($new)) {
 788                                         my $ar = $parent->add($call, $ver, $flags);
 789                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 790                                         push @rout, $ar if $ar;
 791                                         push @pc92out, $r if $h;
 792                                 } else {
 793                                         next;
 794                                 }
 795                         }
 796                 }
 797
 798                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 799                 my $mref = DXMsg::get_busy($call);
 800                 $mref->stop_msg($call) if $mref;
 801
 802                 $user->lastin($main::systime) unless DXChannel::get($call);
 803                 $user->put;
 804         }
 805
 806         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 807         # but remember there will only be one (pair) these because any extras will be
 808         # thrown away.
 809         if (@rout) {
 810 #               $self->route_pc21($self->{call}, $line, @rout);
 811                 $self->route_pc19($self->{call}, $line, @rout);
 812         }
 813         if (@pc92out && !$pc92_slug_changes) {
 814                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 815         }
 816 }
 817
 818 # send local configuration
 819 sub handle_20
 820 {
 821         my $self = shift;
 822         my $pcno = shift;
 823         my $line = shift;
 824         my $origin = shift;
 825         my $pc = shift;
 826
 827         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 828                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 829                 $self->{do_pc9x} = 0;
 830         }
 831         $self->send_local_config;
 832         $self->send(pc22());
 833         $self->state('normal');
 834         $self->{lastping} = 0;
 835         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 836 }
 837
 838 # delete a cluster from the list
 839 #
 840 # This should never occur for directly connected nodes.
 841 #
 842 sub handle_21
 843 {
 844         my $self = shift;
 845         my $pcno = shift;
 846         my $line = shift;
 847         my $origin = shift;
 848         my $pc = shift;
 849
 850         my $call = uc $pc->[1];
 851
 852         eph_del_regex("^PC1[679].*$call");
 853
 854         # if I get a PC21 from the same callsign as self then ignore it
 855         if ($call eq $self->{call}) {
 856                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 857                 return;
 858         }
 859
 860         # for the above reason and also because of the check for PC21s coming
 861         # in for self->call from outside being ignored further down
 862         # we don't need any isolation code here, because we will never
 863         # act on a PC21 with self->call in it.
 864
 865         my $parent = Route::Node::get($self->{call});
 866         unless ($parent) {
 867                 dbg("PCPROT: my parent $self->{call} has disappeared");
 868                 $self->disconnect;
 869                 return;
 870         }
 871
 872         my @rout;
 873
 874         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
 875                 my $node = Route::Node::get($call);
 876                 if ($node) {
 877
 878                         if ($node->via_pc92) {
 879                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 880                                 return;
 881                         }
 882
 883                         my $dxchan = DXChannel::get($call);
 884                         if ($dxchan && $dxchan != $self) {
 885                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
 886                                 return;
 887                         }
 888
 889                         # input filter it
 890                         return unless $self->in_filter_route($node);
 891
 892                         # routing objects, force a PC21 if it is local
 893                         push @rout, $node->del($parent);
 894                         push @rout, $call if $dxchan && @rout == 0;
 895                 }
 896         } else {
 897                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
 898                 return;
 899         }
 900
 901         if (eph_dup($line)) {
 902                 return;
 903         }
 904
 905         if (@rout) {
 906                 $self->route_pc21($origin, $line, @rout);
 907 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 908         }
 909 }
 910
 911
 912 sub handle_22
 913 {
 914         my $self = shift;
 915         my $pcno = shift;
 916         my $line = shift;
 917         my $origin = shift;
 918         my $pc = shift;
 919
 920         if ($self->{do_pc9x}) {
 921                 if ($self->{state} ne 'init92') {
 922                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 923                         $self->{do_pc9x} = 0;
 924                 }
 925         }
 926         $self->{lastping} = 0;
 927         $self->state('normal');
 928         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 929 }
 930
 931 # WWV info
 932 sub handle_23
 933 {
 934         my $self = shift;
 935         my $pcno = shift;
 936         my $line = shift;
 937         my $origin = shift;
 938         my $pc = shift;
 939
 940         # route foreign' pc27s
 941         if ($pcno == 27) {
 942                 if ($pc->[8] ne $main::mycall) {
 943                         $self->route($pc->[8], $line);
 944                         return;
 945                 }
 946         }
 947
 948
 949         # do some de-duping
 950         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
 951         my $sfi = unpad($pc->[3]);
 952         my $k = unpad($pc->[4]);
 953         my $i = unpad($pc->[5]);
 954         my ($r) = $pc->[6] =~ /R=(\d+)/;
 955         $r = 0 unless $r;
 956         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
 957                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
 958                 return;
 959         }
 960
 961         # global wwv filtering on INPUT
 962         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
 963         if ($self->{inwwvfilter}) {
 964                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
 965                 unless ($filter) {
 966                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 967                         return;
 968                 }
 969         }
 970         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
 971         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
 972                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 973                 return;
 974         }
 975
 976         # note this only takes the first one it gets
 977         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 978         dbg("WWV: <$pc->[2]>, sfi=$sfi k=$k info=$i '$pc->[6]' $pc->[7]\@$pc->[8] $r route: $origin") if isdbg('progress');
 979
 980         if (defined &Local::wwv) {
 981                 my $rep;
 982                 eval {
 983                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 984                 };
 985                 return if $rep;
 986         }
 987
 988         # DON'T be silly and send on PC27s!
 989         return if $pcno == 27;
 990
 991         # broadcast to the eager world
 992         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
 993 }
 994
 995 # set here status
 996 sub handle_24
 997 {
 998         my $self = shift;
 999         my $pcno = shift;
1000         my $line = shift;
1001         my $origin = shift;
1002         my $pc = shift;
1003
1004         my $call = uc $pc->[1];
1005         my ($nref, $uref);
1006         $nref = Route::Node::get($call);
1007         $uref = Route::User::get($call);
1008         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1009
1010         if (eph_dup($line)) {
1011                 return;
1012         }
1013
1014         $nref->here($pc->[2]) if $nref;
1015         $uref->here($pc->[2]) if $uref;
1016         my $ref = $nref || $uref;
1017         return unless $self->in_filter_route($ref);
1018
1019         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1020 }
1021
1022 # merge request
1023 sub handle_25
1024 {
1025         my $self = shift;
1026         my $pcno = shift;
1027         my $line = shift;
1028         my $origin = shift;
1029         my $pc = shift;
1030
1031         if ($pc->[1] ne $main::mycall) {
1032                 $self->route($pc->[1], $line);
1033                 return;
1034         }
1035         if ($pc->[2] eq $main::mycall) {
1036                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1037                 return;
1038         }
1039
1040         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1041
1042         # spots
1043         if ($pc->[3] > 0) {
1044                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1045                 my $in;
1046                 foreach $in (@in) {
1047                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1048                 }
1049         }
1050
1051         # wwv
1052         if ($pc->[4] > 0) {
1053                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1054                 my $in;
1055                 foreach $in (@in) {
1056                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1057                 }
1058         }
1059 }
1060
1061 sub handle_26 {goto &handle_11}
1062 sub handle_27 {goto &handle_23}
1063
1064 # mail/file handling
1065 sub handle_28
1066 {
1067         my $self = shift;
1068         my $pcno = shift;
1069         my $line = shift;
1070         my $origin = shift;
1071         my $pc = shift;
1072
1073         if ($pc->[1] eq $main::mycall) {
1074                 no strict 'refs';
1075                 my $sub = "DXMsg::handle_$pcno";
1076                 &$sub($self, @$pc);
1077         } else {
1078                 $self->route($pc->[1], $line) unless $self->is_clx;
1079         }
1080 }
1081
1082 sub handle_29 {goto &handle_28}
1083 sub handle_30 {goto &handle_28}
1084 sub handle_31 {goto &handle_28}
1085 sub handle_32 {goto &handle_28}
1086 sub handle_33 {goto &handle_28}
1087
1088 sub handle_34
1089 {
1090         my $self = shift;
1091         my $pcno = shift;
1092         my $line = shift;
1093         my $origin = shift;
1094         my $pc = shift;
1095
1096         if (eph_dup($line, $eph_pc34_restime)) {
1097                 return;
1098         } else {
1099                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1100         }
1101 }
1102
1103 # remote command replies
1104 sub handle_35
1105 {
1106         my $self = shift;
1107         my $pcno = shift;
1108         my $line = shift;
1109         my $origin = shift;
1110         my $pc = shift;
1111
1112         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1113         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1114 }
1115
1116 sub handle_36 {goto &handle_34}
1117
1118 # database stuff
1119 sub handle_37
1120 {
1121         my $self = shift;
1122         my $pcno = shift;
1123         my $line = shift;
1124         my $origin = shift;
1125         my $pc = shift;
1126
1127         if ($pc->[1] eq $main::mycall) {
1128                 no strict 'refs';
1129                 my $sub = "DXDb::handle_$pcno";
1130                 &$sub($self, @$pc);
1131         } else {
1132                 $self->route($pc->[1], $line) unless $self->is_clx;
1133         }
1134 }
1135
1136 # node connected list from neighbour
1137 sub handle_38
1138 {
1139         my $self = shift;
1140         my $pcno = shift;
1141         my $line = shift;
1142         my $origin = shift;
1143         my $pc = shift;
1144 }
1145
1146 # incoming disconnect
1147 sub handle_39
1148 {
1149         my $self = shift;
1150         my $pcno = shift;
1151         my $line = shift;
1152         my $origin = shift;
1153         my $pc = shift;
1154
1155         if ($pc->[1] eq $self->{call}) {
1156                 $self->disconnect(1);
1157         } else {
1158                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1159         }
1160 }
1161
1162 sub handle_40 {goto &handle_28}
1163
1164 # user info
1165 sub handle_41
1166 {
1167         my $self = shift;
1168         my $pcno = shift;
1169         my $line = shift;
1170         my $origin = shift;
1171         my $pc = shift;
1172
1173         my $call = $pc->[1];
1174         my $sort = $pc->[2];
1175         my $val = $pc->[3];
1176
1177         my $l = "PC41^$call^$sort";
1178         if (eph_dup($l, $eph_info_restime)) {
1179                 return;
1180         }
1181
1182         # input filter if required
1183         #                       my $ref = Route::get($call) || Route->new($call);
1184         #                       return unless $self->in_filter_route($ref);
1185
1186         if ($val eq $sort || $val =~ /^\s*$/) {
1187                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1188                 return;
1189         }
1190
1191         if ($call eq $main::mycall || $call eq $main::myalias) {
1192                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1193                 return;
1194         }
1195         my $chan = DXChannel::get($call);
1196         if ($chan) {
1197                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1198                 return;
1199         }
1200
1201         # add this station to the user database, if required
1202         my $user = DXUser::get_current($call);
1203         $user = DXUser->new($call) unless $user;
1204
1205         if ($sort == 1) {
1206                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1207                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1208                         return;
1209                 }
1210                 $user->name($val);
1211         } elsif ($sort == 2) {
1212                 $user->qth($val);
1213         } elsif ($sort == 3) {
1214                 if (is_latlong($val)) {
1215                         my ($lat, $long) = DXBearing::stoll($val);
1216                         $user->lat($lat) if $lat;
1217                         $user->long($long) if $long;
1218                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1219                 } else {
1220                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1221                         return;
1222                 }
1223         } elsif ($sort == 4) {
1224                 $user->homenode($val);
1225         } elsif ($sort == 5) {
1226                 if (is_qra(uc $val)) {
1227                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1228                         $user->lat($lat) if $lat && !$user->lat;
1229                         $user->long($long) if $long && !$user->long;
1230                         $user->qra(uc $val);
1231                 } else {
1232                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1233                         return;
1234                 }
1235         }
1236         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1237         $user->put;
1238
1239         unless ($self->{isolate}) {
1240                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1241         }
1242
1243         #  perhaps this IS what we want after all
1244         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1245 }
1246
1247 sub handle_42 {goto &handle_28}
1248
1249
1250 # database
1251 sub handle_44 {goto &handle_37}
1252 sub handle_45 {goto &handle_37}
1253 sub handle_46 {goto &handle_37}
1254 sub handle_47 {goto &handle_37}
1255 sub handle_48 {goto &handle_37}
1256
1257 # message and database
1258 sub handle_49
1259 {
1260         my $self = shift;
1261         my $pcno = shift;
1262         my $line = shift;
1263         my $origin = shift;
1264         my $pc = shift;
1265
1266         if (eph_dup($line)) {
1267                 return;
1268         }
1269
1270         if ($pc->[1] eq $main::mycall) {
1271                 DXMsg::handle_49($self, @$pc);
1272         } else {
1273                 $self->route($pc->[1], $line) unless $self->is_clx;
1274         }
1275 }
1276
1277 # keep alive/user list
1278 sub handle_50
1279 {
1280         my $self = shift;
1281         my $pcno = shift;
1282         my $line = shift;
1283         my $origin = shift;
1284         my $pc = shift;
1285
1286         return if (eph_dup($line));
1287
1288         my $call = $pc->[1];
1289
1290         my $node = Route::Node::get($call);
1291         if ($node) {
1292                 return unless $node->call eq $self->{call};
1293                 $node->usercount($pc->[2]) unless $node->users;
1294                 $node->reset_obs;
1295                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1296
1297                 # input filter if required
1298 #               return unless $self->in_filter_route($node);
1299
1300                 unless ($self->{isolate}) {
1301                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1302                 }
1303 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1304         }
1305 }
1306
1307 # incoming ping requests/answers
1308 sub handle_51
1309 {
1310         my $self = shift;
1311         my $pcno = shift;
1312         my $line = shift;
1313         my $origin = shift;
1314         my $pc = shift;
1315
1316         my $to = $pc->[1];
1317         my $from = $pc->[2];
1318         my $flag = $pc->[3];
1319
1320         if ($to eq $main::myalias) {
1321                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1322                 return;
1323         }
1324
1325         # is it for us?
1326         if ($to eq $main::mycall) {
1327                 if ($flag == 1) {
1328                         $self->send(pc51($from, $to, '0'));
1329                 } else {
1330                         DXXml::Ping::handle_ping_reply($self, $from);
1331                 }
1332         } else {
1333                 if (eph_dup($line)) {
1334                         return;
1335                 }
1336                 # route down an appropriate thingy
1337                 $self->route($to, $line);
1338         }
1339 }
1340
1341 sub handle_61 { goto &handle_11; }
1342
1343 # dunno but route it
1344 sub handle_75
1345 {
1346         my $self = shift;
1347         my $pcno = shift;
1348         my $line = shift;
1349         my $origin = shift;
1350         my $pc = shift;
1351
1352         my $call = $pc->[1];
1353         if ($call ne $main::mycall) {
1354                 $self->route($call, $line);
1355         }
1356 }
1357
1358 # WCY broadcasts
1359 sub handle_73
1360 {
1361         my $self = shift;
1362         my $pcno = shift;
1363         my $line = shift;
1364         my $origin = shift;
1365         my $pc = shift;
1366
1367         my $call = $pc->[1];
1368
1369         # do some de-duping
1370         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1371         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1372                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1373                 return;
1374         }
1375         $pc = [ map { unpad($_) } @$pc ];
1376         if (WCY::dup($d)) {
1377                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1378                 return;
1379         }
1380
1381         my $wcy = WCY::update($d, @$pc[2..12]);
1382         dbg("WCY: <$pc->[2]> K=$pc->[5] expK=$pc->[6] A=$pc->[4] R=$pc->[7] SFI=$pc->[3] SA=$pc->[8] GMF=$pc->[9] Au=$pc->[10] $pc->[11]\@$pc->[12] route: $origin") if isdbg('progress');
1383
1384         if (defined &Local::wcy) {
1385                 my $rep;
1386                 eval {
1387                         $rep = Local::wcy($self, @$pc[1..12]);
1388                 };
1389                 return if $rep;
1390         }
1391
1392         # broadcast to the eager world
1393         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1394 }
1395
1396 # remote commands (incoming)
1397 sub handle_84
1398 {
1399         my $self = shift;
1400         my $pcno = shift;
1401         my $line = shift;
1402         my $origin = shift;
1403         my $pc = shift;
1404
1405         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1406 }
1407
1408 # remote command replies
1409 sub handle_85
1410 {
1411         my $self = shift;
1412         my $pcno = shift;
1413         my $line = shift;
1414         my $origin = shift;
1415         my $pc = shift;
1416
1417         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1418 }
1419
1420 # decode a pc92 call: flag call : version : build
1421 sub _decode_pc92_call
1422 {
1423         my $icall = shift;
1424         my @part = split /:/, $icall;
1425         my ($flag, $call) = unpack "A A*", $part[0];
1426         unless (defined $flag && $flag ge '0' && $flag le '7') {
1427                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1428                 return ();
1429         }
1430         unless ($call && is_callsign($call)) {
1431                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1432                 return ();
1433         }
1434         my $is_node = $flag & 4;
1435         my $is_extnode = $flag & 2;
1436         my $here = $flag & 1;
1437         my $ip  = $part[3];
1438         $ip ||= $part[1] if $part[1] && ($part[1] =~ /^(?:\d+\.)+/ || $part[1] =~ /^(?:(?:[abcdef\d]+)?,)+/);
1439         $ip =~ s/,/:/g if $ip;
1440         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2], $ip);
1441 }
1442
1443 # decode a pc92 call: flag call : version : build
1444 sub _encode_pc92_call
1445 {
1446         my $ref = shift;
1447
1448         # plain call or value
1449         return $ref unless ref $ref;
1450
1451         my $ext = shift || 0;
1452         my $flag = 0;
1453         my $call = $ref->call;
1454         my $extra = '';
1455         $flag |= $ref->here ? 1 : 0;
1456         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1457                 $flag |= 4;
1458                 my $dxchan = DXChannel::get($call);
1459                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1460                 if (($ext & 1) && $ref->version) {
1461                         my $version = $ref->version || 1.0;
1462                         $version =  $version * 100 + 5300 if $version < 50;
1463                         $extra .= ":" . $version;
1464                 }
1465         }
1466         if (($ext & 2) && $ref->ip) {
1467                 my $ip = $ref->ip;
1468                 $ip =~ s/:/,/g;
1469                 $extra .= ':' . $ip;
1470         }
1471         return "$flag$call$extra";
1472 }
1473
1474 my %things_add;
1475 my %things_del;
1476
1477 sub _add_thingy
1478 {
1479         my $parent = shift;
1480         my $s = shift;
1481         my $dxchan = shift;
1482         my $hops = shift;
1483
1484         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1485         my @rout;
1486
1487         # remove spurious IPV6 prefix on IPV4 addresses
1488         $ip =~ s/^::ffff:// if $ip;
1489
1490         if ($call) {
1491                 my $ncall = $parent->call;
1492                 if ($is_node) {
1493                         dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1494                         @rout = $parent->add($call, $version, Route::here($here), $ip);
1495                         my $r = Route::Node::get($call);
1496                         $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1497                         if ($ip) {
1498                                 $r->ip($ip);
1499                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1500                         }
1501                 } else {
1502                         dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1503                         @rout = $parent->add_user($call, Route::here($here), $ip);
1504                         $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1505                         my $r = Route::User::get($call);
1506                         if ($ip) {
1507                                 $r->ip($ip);
1508                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1509                         }
1510                 }
1511                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1512                         $things_add{$call} = Route::get($call);
1513                         delete $things_del{$call};
1514                 }
1515         }
1516         return @rout;
1517 }
1518
1519 sub _del_thingy
1520 {
1521         my $parent = shift;
1522         my $s = shift;
1523         my $dxchan = shift;
1524         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1525         my @rout;
1526         if ($call) {
1527                 my $ref;
1528                 if ($is_node) {
1529                         $ref = Route::Node::get($call);
1530                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1531                         @rout = $ref->del($parent) if $ref;
1532                 } else {
1533                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1534                         $ref = Route::User::get($call);
1535                         if ($ref) {
1536                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1537                                 @rout = $parent->del_user($ref);
1538                         }
1539                 }
1540                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1541                         $things_del{$call} = $ref unless exists $things_add{$call};
1542                         delete $things_add{$call};
1543                 }
1544         }
1545         return @rout;
1546 }
1547
1548 # this will only happen if we are slugging changes and
1549 # there are some changes to be sent, it will create an add or a delete
1550 # or both
1551 sub gen_pc92_changes
1552 {
1553         my @add = values %things_add;
1554         my @del = values %things_del;
1555         return (\@add, \@del);
1556 }
1557
1558 sub clear_pc92_changes
1559 {
1560         %things_add = %things_del = ();
1561         $last_pc92_slug = $main::systime;
1562 }
1563
1564 my $_last_time;
1565 my $_last_occurs;
1566 my $_last_pc9x_id;
1567
1568 sub last_pc9x_id
1569 {
1570         return $_last_pc9x_id;
1571 }
1572
1573 sub gen_pc9x_t
1574 {
1575         if (!$_last_time || $_last_time != $main::systime) {
1576                 $_last_time = $main::systime;
1577                 $_last_occurs = 0;
1578                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1579         } else {
1580                 $_last_occurs++;
1581                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1582         }
1583 }
1584
1585 sub check_pc9x_t
1586 {
1587         my $call = shift;
1588         my $t = shift;
1589         my $pc = shift;
1590         my $create = shift;
1591
1592         # check that the time is between 0 >= $t < 86400
1593         unless ($t >= 0 && $t < 86400) {
1594                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1595                 return undef;
1596         }
1597
1598         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1599         my $now = $main::systime - $main::systime_daystart ;
1600         my $diff = abs($now - $t);
1601         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1602                 my $c = ref $call ? $call->call : $call;
1603                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1604                 return undef;
1605         }
1606
1607         my $parent = ref $call ? $call : Route::Node::get($call);
1608         if ($parent) {
1609                 # we only do this for external calls whose routing table
1610                 # record come and go. The reference for mycall is permanent
1611                 # and not that frequently used, it also never times out, so
1612                 # the id on it is completely unreliable. Besides, only commands
1613                 # originating on this box will go through this code...
1614                 if ($parent->call ne $main::mycall) {
1615                         my $lastid = $parent->lastid;
1616                         if (defined $lastid) {
1617                                 if ($t < $lastid) {
1618                                         # note that this is where we determine whether this pc9x has come in yesterday
1619                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1620                                         # duplicate sentence. To determine this we need to do some module 86400
1621                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1622                                         # low numbers that it is a new sentence.
1623                                         #
1624                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1625                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1626                                         # 86378 respectively in the calculation below).
1627                                         #
1628                                         if ($t+86400-$lastid > $pc9x_past_age) {
1629                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1630                                                 return undef;
1631                                         }
1632                                 } elsif ($t == $lastid) {
1633                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1634                                         return undef;
1635                                 } else {
1636                                         # check that if we have a low number in lastid that yesterday's numbers
1637                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1638                                         if ($lastid+86400-$t < $pc9x_past_age) {
1639                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1640                                                 return undef;
1641                                         }
1642                                 }
1643                         }
1644                 }
1645         } elsif ($create) {
1646                 $parent = Route::Node->new($call);
1647         } else {
1648                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1649                 return undef;
1650         }
1651         if (isdbg('pc92dedupe')) {
1652                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1653                 my $val = $parent->{lastid};
1654                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1655                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1656         }
1657         $parent->lastid($t);
1658
1659         return $parent;
1660 }
1661
1662 sub pc92_handle_first_slot
1663 {
1664         my $self = shift;
1665         my $slot = shift;
1666         my $parent = shift;
1667         my $t = shift;
1668         my $hops = shift;
1669         my $oparent = $parent;
1670
1671         my @radd;
1672
1673         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1674         if ($call && $is_node) {
1675                 if ($call eq $main::mycall) {
1676                         dbg("PCPROT: $call looped back onto \$main::mycall ($main::mycall), ignored") if isdbg('chan');
1677                         return;
1678                 }
1679                 if ($call eq $main::myalias) {
1680                         dbg("PCPROT: $call looped back onto \$main::myalias ($main::myalias), ignored") if isdbg('chan');
1681                         return;
1682                 }
1683                 # this is only accepted from my "self".
1684                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1685                 # locally connected. Local nodes always take precedence. But we remember the lastid
1686                 # to try to reduce the number of dupe PC92s for this external node.
1687                 if (DXChannel::get($call) && $call ne $self->{call}) {
1688                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1689                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1690                         return;
1691                 }
1692                 if ($is_extnode) {
1693                         # reparent to external node (note that we must have received a 'C' or 'A' record
1694                         # from the true parent node for this external before we get one for the this node
1695                         unless ($parent = Route::Node::get($call)) {
1696                                 if ($is_extnode && $oparent) {
1697                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
1698                                         $parent = $radd[0];
1699                                 } else {
1700                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1701                                         return;
1702                                 }
1703                         }
1704                         $parent = check_pc9x_t($call, $t, 92) || return;
1705                         $parent->via_pc92(1);
1706                         $parent->PC92C_dxchan($self->{call}, $hops);
1707                 }
1708         } else {
1709                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1710                 return;
1711         }
1712         $parent->here(Route::here($here));
1713         $parent->version($version || $pc19_version) if $version;
1714         $parent->build($build) if $build;
1715         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1716         return ($parent, @radd);
1717 }
1718
1719 # DXSpider routing entries
1720 sub handle_92
1721 {
1722         my $self = shift;
1723         my $pcno = shift;
1724         my $line = shift;
1725         my $origin = shift;
1726         my $pc = shift;
1727
1728         my (@radd, @rdel);
1729
1730         my $pcall = $pc->[1];
1731         my $t = $pc->[2];
1732         my $sort = $pc->[3];
1733         my $hops = $pc->[-1];
1734
1735         # this catches loops of A/Ds
1736 #       if (eph_dup($line, $pc9x_dupe_age)) {
1737 #               return;
1738 #       }
1739
1740         if ($pcall eq $main::mycall) {
1741                 dbg("PCPROT: looped back, ignored") if isdbg('chan');
1742                 return;
1743         }
1744
1745         if ($pcall eq $main::myalias) {
1746                 dbg("PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored") if isdbg('chan');
1747                 return;
1748         }
1749
1750         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1751                 if ($self->{isolate}) {
1752                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
1753                         return;
1754                 } elsif (!$self->user->wantpc9x) {
1755                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
1756                         return;
1757                 } else {
1758                         $self->state('init92');
1759                         $self->{do_pc9x} = 1;
1760                         dbg("DXPROT: Do pc9x set on $pcall");
1761                 }
1762         }
1763         unless ($self->{do_pc9x}) {
1764                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1765                 return;
1766         }
1767
1768         # don't create routing entries for D records that don't already exist
1769         # this is what causes all those PC92 loops!
1770         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1771         my $oparent = $parent;
1772
1773         $parent->do_pc9x(1);
1774         $parent->via_pc92(1);
1775
1776         if ($sort eq 'F' || $sort eq 'R') {
1777
1778                 # this is the route finding section
1779                 # here is where the consequences of the 'find' command
1780                 # are dealt with
1781
1782                 my $from = $pc->[4];
1783                 my $target = $pc->[5];
1784
1785                 if ($sort eq 'F') {
1786                         my $flag;
1787                         my $ref;
1788                         my $dxchan;
1789                         if ($ref = DXChannel::get($target)) {
1790                                 $flag = 1;              # we are directly connected
1791                         } else {
1792                                 $ref = Route::get($target);
1793                                 $dxchan = $ref->dxchan;
1794                                 $flag = 2;
1795                         }
1796                         if ($ref && $flag && $dxchan) {
1797                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1798                                 return;
1799                         }
1800                 } elsif ($sort eq 'R') {
1801                         if (my $dxchan = DXChannel::get($from)) {
1802                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
1803                         } else {
1804                                 my $ref = Route::get($from);
1805                                 if ($ref) {
1806                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1807                                         if (@dxchan) {
1808                                                 $_->send($line) for @dxchan;
1809                                         } else {
1810                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1811                                         }
1812                                 } else {
1813                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1814                                 }
1815                         }
1816                         return;
1817                 }
1818
1819         } elsif ($sort eq 'K') {
1820                 $pc92Kin += length $line;
1821
1822                 # remember the last channel we arrived on
1823                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1824
1825                 my @ent = _decode_pc92_call($pc->[4]);
1826
1827                 if (@ent) {
1828                         my $add;
1829
1830                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
1831                         return unless $parent; # dupe
1832
1833                         push @radd, $add if $add;
1834                         $parent->reset_obs;
1835                         $parent->version($ent[4]) if $ent[4];
1836                         $parent->build($ent[5]) if $ent[5];
1837
1838                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1839                 }
1840         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1841
1842                 $pc92Ain += length $line if $sort eq 'A';
1843                 $pc92Cin += length $line if $sort eq 'C';
1844                 $pc92Din += length $line if $sort eq 'D';
1845
1846                 # remember the last channel we arrived on
1847                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1848
1849                 # this is the main route section
1850                 # here is where all the routes are created and destroyed
1851
1852                 # cope with missing duplicate node calls in the first slot
1853                 my $me = $pc->[4] || '';
1854                 $me ||= _encode_pc92_call($parent) unless $me ;
1855
1856                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
1857
1858                 if (@ent) {
1859
1860                         # look at the first one which will always be a node of some sort
1861                         # except in the case of 'A' or 'D' in which the $pcall is used
1862                         # otherwise use the node call and update any information
1863                         # that needs to be done.
1864                         my $add;
1865
1866                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
1867                         return unless $parent; # dupe
1868
1869                         shift @ent;
1870                         push @radd, $add if $add;
1871                 }
1872
1873                 # do a pass through removing any references to either mycall
1874                 my @nent;
1875                 for (@ent) {
1876                         my $dxc;
1877                         next unless $_ && @$_;
1878                         if ($_->[0] eq $main::mycall) {
1879                                 dbg("PCPROT: $_->[0] refers to me, ignored") if isdbg('chanerr');
1880                                 next;
1881                         }
1882                         push @nent, $_;
1883                 }
1884
1885                 if ($sort eq 'A') {
1886                         for (@nent) {
1887                                 push @radd, _add_thingy($parent, $_, $self, $hops);
1888                         }
1889                 } elsif ($sort eq 'D') {
1890                         for (@nent) {
1891                                 push @rdel, _del_thingy($parent, $_, $self);
1892                         }
1893                 } elsif ($sort eq 'C') {
1894                         my (@nodes, @users);
1895
1896                         # we reset obscounts on config records as well as K records
1897                         $parent->reset_obs;
1898                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1899
1900                         #
1901                         foreach my $r (@nent) {
1902                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1903                                 if ($r->[0]) {
1904                                         if ($r->[1]) {
1905                                                 push @nodes, $r->[0];
1906                                         } else {
1907                                                 push @users, $r->[0];
1908                                         }
1909                                 } else {
1910                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1911                                 }
1912                         }
1913
1914                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1915
1916                         # add users here
1917                         foreach my $r (@nent) {
1918                                 my $call = $r->[0];
1919                                 if ($call) {
1920                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
1921                                 }
1922                         }
1923                         # del users here
1924                         foreach my $r (@$dnodes) {
1925                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
1926                         }
1927                         foreach my $r (@$dusers) {
1928                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
1929                         }
1930
1931                         # remember this last PC92C for rebroadcast on demand
1932                         $parent->last_PC92C($line);
1933                 } else {
1934                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1935                         return;
1936                 }
1937
1938                 foreach my $r (@rdel) {
1939                         next unless $r;
1940
1941                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1942                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1943                 }
1944                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1945                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1946                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1947                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1948                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1949         }
1950
1951         # broadcast it if we get here
1952         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1953 }
1954
1955 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
1956 # might be on two or more nodes at the same time or that there may be more than
1957 # one equal distance neighbour to a node.
1958 #
1959 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
1960 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
1961 # each and then combined to give a set of dxchans to send the PC9x record down
1962 #
1963 sub find_pc9x_routes
1964 {
1965         my $to = shift;
1966         my $ref = Route::get($to);
1967         my @parent;
1968         my %cand;
1969
1970         if ($ref->isa('Route::User')) {
1971                 my $dxchan = DXChannel::get($to);
1972                 push @parent, $to if $dxchan;
1973                 push @parent, $ref->parents;
1974         } else {
1975                 @parent = $to;
1976         }
1977         foreach my $p (@parent) {
1978                 my $lasthops;
1979                 my @routes = Route::findroutes($p);
1980                 foreach my $r (@routes) {
1981                         $lasthops = $r->[0] unless defined $lasthops;
1982                         if ($r->[0] == $lasthops) {
1983                                 $cand{$r->[1]->call} = $r->[1];
1984                         } else {
1985                                 last;
1986                         }
1987                 }
1988         }
1989         return values %cand;
1990 }
1991
1992 sub handle_93
1993 {
1994         my $self = shift;
1995         my $pcno = shift;
1996         my $line = shift;
1997         my $origin = shift;
1998         my $pc = shift;
1999
2000 #       $self->{do_pc9x} ||= 1;
2001
2002         my $pcall = $pc->[1];                   # this is now checked earlier
2003
2004         # remember that we are converting PC10->PC93 and self will be $main::me if it
2005         # comes from us
2006         unless ($self->{do_pc9x}) {
2007                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2008                 return;
2009         }
2010
2011         my $t = $pc->[2];
2012         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2013
2014         my $to = uc $pc->[3];
2015         my $from = uc $pc->[4];
2016         my $via = uc $pc->[5];
2017         my $text = $pc->[6];
2018         my $onode = uc $pc->[7];
2019         $onode = $pcall if @$pc <= 8;
2020
2021         # this is catch loops caused by bad software ...
2022         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2023                 return;
2024         }
2025
2026         if (isdbg('progress')) {
2027                 my $vs = $via ne '*' ? " via $via" : '';
2028                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text' route: $origin";
2029                 dbg($s);
2030         }
2031
2032         # will we allow it at all?
2033         if ($censorpc) {
2034                 my @bad;
2035                 if (@bad = BadWords::check($text)) {
2036                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
2037                         return;
2038                 }
2039         }
2040
2041         # if this is a 'bad spotter' user then ignore it
2042         my $nossid = $from;
2043         $nossid =~ s/-\d+$//;
2044         if ($badspotter->in($nossid)) {
2045                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
2046                 return;
2047         }
2048
2049         # ignore PC93 coming in from outside this node with a target of local
2050         if ($to eq 'LOCAL' && $self != $main::me) {
2051                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2052                 return;
2053         }
2054
2055         # if it is routeable then then treat it like a talk
2056         my $ref = Route::get($to);
2057         if ($ref) {
2058                 my $dxchan;
2059
2060                 # convert to PC10 or local talks where appropriate
2061                 # PC93 capable nodes of the same hop count all get a copy
2062                 # if there is a PC10 node then it will get a copy and that
2063                 # will be it. Hopefully such a node will not figure highly
2064                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2065                 # note that both local and PC93s at the same time are possible if the
2066                 # user on more than one node.
2067                 my @routes = find_pc9x_routes($to);
2068                 my $lasthops;
2069                 foreach $dxchan (@routes) {
2070                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2071                                 if ($dxchan->{do_pc9x}) {
2072                                         $dxchan->send($line);
2073                                 } else {
2074                                         $dxchan->talk($from, $to, $via, $text, $onode);
2075                                 }
2076                         } else {
2077                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2078                         }
2079                 }
2080                 return;
2081
2082         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2083                 # announces
2084                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2085                 my $wx = $to eq 'WX' ? '1' : '0';
2086                 my $local = $via eq 'LOCAL' ? '*' : $via;
2087
2088                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2089                 return if $via eq 'LOCAL';
2090         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2091                 # chat messages really only locally connected users
2092                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2093         }
2094
2095         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2096         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2097 }
2098
2099 # if get here then rebroadcast the thing with its Hop count decremented (if
2100 # there is one). If it has a hop count and it decrements to zero then don't
2101 # rebroadcast it.
2102 #
2103 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2104 #        REBROADCAST!!!!
2105 #
2106
2107 sub handle_default
2108 {
2109         my $self = shift;
2110         my $pcno = shift;
2111         my $line = shift;
2112         my $origin = shift;
2113         my $pc = shift;
2114
2115         unless (eph_dup($line)) {
2116                 if ($pcno >= 90) {
2117                         my $pcall = $pc->[1];
2118                         unless (is_callsign($pcall)) {
2119                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2120                                 return;
2121                         }
2122                         my $t = $pc->[2];
2123                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2124                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2125                 } else {
2126                         unless ($self->{isolate}) {
2127                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2128                         }
2129                 }
2130         }
2131 }
2132
2133 1;