perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35
  36 use strict;
  37
  38 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  39                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  40                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  41                         $investigation_int $pc19_version $myprot_version
  42                         %nodehops $baddx $badspotter $badnode $censorpc
  43                         $allowzero $decode_dk0wcy $send_opernam @checklist
  44                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  45                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  46                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  47                         $pc92filterdef
  48                    );
  49
  50 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  51 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  52 $pc92_slug_changes = 60*5;              # slug any changes going outward for this long
  53 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  54 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  55 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  56         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  57                                 # this is actually the partition between "yesterday" and "today" but old.
  58
  59 $pc92filterdef = bless ([
  60                           # tag, sort, field, priv, special parser
  61                           ['call', 'c', 0],
  62                           ['by', 'c', 0],
  63                           ['dxcc', 'nc', 1],
  64                           ['itu', 'ni', 2],
  65                           ['zone', 'nz', 3],
  66                          ], 'Filter::Cmd');
  67
  68
  69 # incoming talk commands
  70 sub handle_10
  71 {
  72         my $self = shift;
  73         my $pcno = shift;
  74         my $line = shift;
  75         my $origin = shift;
  76         my $pc = shift;
  77
  78         # this is to catch loops caused by bad software ...
  79         if (eph_dup($line, $pc10_dupe_age)) {
  80                 return;
  81         }
  82
  83         # will we allow it at all?
  84         if ($censorpc) {
  85                 my @bad;
  86                 if (@bad = BadWords::check($pc->[3])) {
  87                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  88                         return;
  89                 }
  90         }
  91
  92         # is it for me or one of mine?
  93         my ($from, $to, $via, $call, $dxchan);
  94         $from = $pc->[1];
  95         if ($pc->[5] gt ' ') {
  96                 $via = $pc->[2];
  97                 $to = $pc->[5];
  98         } else {
  99                 $to = $pc->[2];
 100         }
 101
 102         # if this is a 'nodx' node then ignore it
 103         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 104                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 105                 return;
 106         }
 107
 108         # if this is a 'bad spotter' user then ignore it
 109         my $nossid = $from;
 110         $nossid =~ s/-\d+$//;
 111         if ($badspotter->in($nossid)) {
 112                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 113                 return;
 114         }
 115
 116         # if we are converting announces to talk is it a dup?
 117         if ($ann_to_talk) {
 118                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 119                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 120                         return;
 121                 }
 122         }
 123
 124         # convert this to a PC93, coming from mycall with origin set and process it as such
 125         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]));
 126 }
 127
 128 # DX Spot handling
 129 sub handle_11
 130 {
 131         my $self = shift;
 132         my $pcno = shift;
 133         my $line = shift;
 134         my $origin = shift;
 135         my $pc = shift;
 136
 137         # route 'foreign' pc26s
 138         if ($pcno == 26) {
 139                 if ($pc->[7] ne $main::mycall) {
 140                         $self->route($pc->[7], $line);
 141                         return;
 142                 }
 143         }
 144
 145 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 146
 147         # is the spotted callsign blank? This should really be trapped earlier but it
 148         # could break other protocol sentences. Also check for lower case characters.
 149         if ($pc->[2] =~ /^\s*$/) {
 150                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 151                 return;
 152         }
 153         if ($pc->[2] =~ /[a-z]/) {
 154                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 155                 return;
 156         }
 157
 158
 159         # if this is a 'nodx' node then ignore it
 160         if ($badnode->in($pc->[7])) {
 161                 dbg("PCPROT: Bad Node $pc->[7], dropped") if isdbg('chanerr');
 162                 return;
 163         }
 164
 165         # if this is a 'bad spotter' or an unknown user then ignore it. BUT if it's got an IP address then allow it through
 166         my $nossid = $pc->[6];
 167         $nossid =~ s/-\d+$//;
 168         if ($badspotter->in($nossid)) {
 169                 dbg("PCPROT: Bad Spotter $pc->[6], dropped") if isdbg('chanerr');
 170                 return;
 171         }
 172 #       unless (is_ipaddr($pc->[8]) || DXUser::get_current($pc->[6])) {
 173 #               dbg("PCPROT: Unknown Spotter $pc->[6], dropped") if isdbg('chanerr');
 174 #               return;
 175 #       }
 176
 177         # convert the date to a unix date
 178         my $d = cltounix($pc->[3], $pc->[4]);
 179         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 180         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 181                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n") if isdbg('chanerr');
 182                 return;
 183         }
 184
 185         # is it 'baddx'
 186         if ($baddx->in($pc->[2]) || BadWords::check($pc->[2])) {
 187                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 188                 return;
 189         }
 190
 191         # do some de-duping
 192         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 193         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 194         if ($pc->[2] =~ /BUST\w*$/) {
 195                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 196                 return;
 197         }
 198         if ($censorpc) {
 199                 my @bad;
 200                 if (@bad = BadWords::check($pc->[5])) {
 201                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 202                         return;
 203                 }
 204         }
 205
 206         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 207         # global spot filtering on INPUT
 208         if ($self->{inspotsfilter}) {
 209                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 210                 unless ($filter) {
 211                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 212                         return;
 213                 }
 214         }
 215
 216         # this goes after the input filtering, but before the add
 217         # so that if it is input filtered, it isn't added to the dup
 218         # list. This allows it to come in from a "legitimate" source
 219         if (Spot::dup(@spot[0..4,5])) {
 220                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         # add it
 225         Spot::add(@spot);
 226
 227         my $ip = $spot[14] if exists $spot[14];
 228         if (isdbg('progress')) {
 229                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 230                 my $d = ztime($spot[2]);
 231                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 232                 $s .= " '$spot[3]'" if $spot[3];
 233                 dbg($s);
 234         }
 235
 236         #
 237         # @spot at this point contains:-
 238         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 239         # then  spotted itu, spotted cq, spotters itu, spotters cq
 240         # you should be able to route on any of these
 241         #
 242
 243         # fix up qra locators of known users
 244         my $user = DXUser::get_current($spot[4]);
 245         if ($user) {
 246                 my $qra = $user->qra;
 247                 unless ($qra && is_qra($qra)) {
 248                         my $lat = $user->lat;
 249                         my $long = $user->long;
 250                         if (defined $lat && defined $long) {
 251                                 $user->qra(DXBearing::lltoqra($lat, $long));
 252                                 $user->put;
 253                         }
 254                 }
 255
 256                 # send a remote command to a distant cluster if it is visible and there is no
 257                 # qra locator and we havn't done it for a month.
 258
 259                 unless ($user->qra) {
 260                         my $node;
 261                         my $to = $user->homenode;
 262                         my $last = $user->lastoper || 0;
 263                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 264                                 my $cmd = "forward/opernam $spot[4]";
 265                                 # send the rcmd but we aren't interested in the replies...
 266                                 my $dxchan = $node->dxchan;
 267                                 if ($dxchan && $dxchan->is_clx) {
 268                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 269                                 } else {
 270                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 271                                 }
 272                                 if ($to ne $pc->[7]) {
 273                                         $to = $pc->[7];
 274                                         $node = Route::Node::get($to);
 275                                         if ($node) {
 276                                                 $dxchan = $node->dxchan;
 277                                                 if ($dxchan && $dxchan->is_clx) {
 278                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 279                                                 } else {
 280                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 281                                                 }
 282                                         }
 283                                 }
 284                                 $user->lastoper($main::systime);
 285                                 $user->put;
 286                         }
 287                 }
 288         }
 289
 290         # local processing
 291         if (defined &Local::spot) {
 292                 my $r;
 293                 eval {
 294                         $r = Local::spot($self, @spot);
 295                 };
 296                 return if $r;
 297         }
 298
 299         # DON'T be silly and send on PC26s!
 300         return if $pcno == 26;
 301
 302         # send out the filtered spots
 303         send_dx_spot($self, $line, @spot) if @spot;
 304 }
 305
 306 # announces
 307 sub handle_12
 308 {
 309         my $self = shift;
 310         my $pcno = shift;
 311         my $line = shift;
 312         my $origin = shift;
 313         my $pc = shift;
 314
 315         # announce duplicate checking
 316         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 317
 318         if ($censorpc) {
 319                 my @bad;
 320                 if (@bad = BadWords::check($pc->[3])) {
 321                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 322                         return;
 323                 }
 324         }
 325
 326         # if this is a 'nodx' node then ignore it
 327         if ($badnode->in($pc->[5])) {
 328                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 329                 return;
 330         }
 331
 332         # if this is a 'bad spotter' user then ignore it
 333         my $nossid = $pc->[1];
 334         $nossid =~ s/-\d+$//;
 335         if ($badspotter->in($nossid)) {
 336                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 337                 return;
 338         }
 339
 340         # ignore PC12s from origins that use PCxx protocol
 341         my $oref = Route::get($origin);
 342         if ($oref->do_pc9x) {
 343                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 344                 return;
 345         }
 346
 347         my $dxchan;
 348
 349         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 350                 $self->send_chat(0, $line, @$pc[1..6]);
 351         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 352
 353                 # ignore something that looks like a chat line coming in with sysop
 354                 # flag - this is a kludge...
 355                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 356                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 357                         return;
 358                 }
 359
 360                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 361                 # or one saying 'to <call>' to a talk if we can route to the recipient
 362                 if ($ann_to_talk) {
 363                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 364                         if ($call) {
 365                                 my $ref = Route::get($call);
 366                                 if ($ref) {
 367                                         $dxchan = $ref->dxchan;
 368                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 369                                         return;
 370                                 }
 371                         }
 372                 }
 373
 374                 # send it
 375                 $self->send_announce(0, $line, @$pc[1..6]);
 376         } else {
 377                 $self->route($pc->[2], $line);
 378         }
 379
 380         # local processing
 381         if (defined &Local::ann) {
 382                 my $r;
 383                 eval {
 384                         $r = Local::ann($self, $line, @$pc[1..6]);
 385                 };
 386                 return if $r;
 387         }
 388 }
 389
 390 sub handle_15
 391 {
 392         my $self = shift;
 393         my $pcno = shift;
 394         my $line = shift;
 395         my $origin = shift;
 396         my $pc = shift;
 397
 398         if (eph_dup($line, $eph_pc15_restime)) {
 399                 return;
 400         } else {
 401                 unless ($self->{isolate}) {
 402                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 403                 }
 404         }
 405 }
 406
 407 # incoming user
 408 sub handle_16
 409 {
 410         my $self = shift;
 411         my $pcno = shift;
 412         my $line = shift;
 413         my $origin = shift;
 414         my $pc = shift;
 415
 416         # general checks
 417         my $dxchan;
 418         my $ncall = $pc->[1];
 419         my $newline = "PC16^";
 420
 421         # dos I want users from this channel?
 422         unless ($self->user->wantpc16) {
 423                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 424                 return;
 425         }
 426
 427         # is it me?
 428         if ($ncall eq $main::mycall) {
 429                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 430                 return;
 431         }
 432
 433         my $h;
 434         $h = 1 if DXChannel::get($ncall);
 435         if ($h && $self->{call} ne $ncall) {
 436                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 437                 return;
 438         }
 439
 440         if (eph_dup($line)) {
 441                 return;
 442         }
 443
 444         # isolate now means only accept stuff from this call only
 445         if ($self->{isolate} && $ncall ne $self->{call}) {
 446                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 447                 return;
 448         }
 449
 450         my $parent = Route::Node::get($ncall);
 451
 452         if ($parent) {
 453                 $dxchan = $parent->dxchan;
 454                 if ($dxchan && $dxchan ne $self) {
 455                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 456                         return;
 457                 }
 458
 459                 # input filter if required
 460                 return unless $self->in_filter_route($parent);
 461         } else {
 462                 $parent = Route::Node->new($ncall);
 463         }
 464
 465         unless ($h) {
 466                 if ($parent->via_pc92) {
 467                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 468                         return;
 469                 }
 470         }
 471
 472         my $i;
 473         my @rout;
 474         for ($i = 2; $i < $#$pc; $i++) {
 475                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 476                 next unless $call && $conf && defined $here && is_callsign($call);
 477                 next if $call eq $main::mycall;
 478
 479                 eph_del_regex("^PC17\\^$call\\^$ncall");
 480
 481                 $conf = $conf eq '*';
 482
 483                 # reject this if we think it is a node already
 484                 my $r = Route::Node::get($call);
 485                 my $u = DXUser::get_current($call) unless $r;
 486                 if ($r || ($u && $u->is_node)) {
 487                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 488                         next;
 489                 }
 490
 491                 $r = Route::User::get($call);
 492                 my $flags = Route::here($here)|Route::conf($conf);
 493
 494                 if ($r) {
 495                         my $au = $r->addparent($parent);
 496                         if ($r->flags != $flags) {
 497                                 $r->flags($flags);
 498                                 $au = $r;
 499                         }
 500                         push @rout, $r if $h && $au;
 501                 } else {
 502                         my @ans = $parent->add_user($call, $flags);
 503                         push @rout, @ans if $h && @ans;
 504                 }
 505
 506                 # add this station to the user database, if required
 507                 my $user = DXUser::get_current($ncall);
 508                 $user = DXUser->new($call) unless $user;
 509                 $user->homenode($parent->call) if !$user->homenode;
 510                 $user->node($parent->call);
 511                 $user->lastin($main::systime) unless DXChannel::get($call);
 512                 $user->put;
 513
 514                 # send info to all logged in thingies
 515                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 516                 $self->tell_buddies('loginb', $call, $ncall);
 517         }
 518         if (@rout) {
 519                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 520 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 521         }
 522 }
 523
 524 # remove a user
 525 sub handle_17
 526 {
 527         my $self = shift;
 528         my $pcno = shift;
 529         my $line = shift;
 530         my $origin = shift;
 531         my $pc = shift;
 532
 533         my $dxchan;
 534         my $ncall = $pc->[2];
 535         my $ucall = $pc->[1];
 536
 537         eph_del_regex("^PC16\\^$ncall.*$ucall");
 538
 539         # do I want users from this channel?
 540         unless ($self->user->wantpc16) {
 541                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 542                 return;
 543         }
 544
 545         if ($ncall eq $main::mycall) {
 546                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 547                 return;
 548         }
 549
 550         # isolate now means only accept stuff from this call only
 551         if ($self->{isolate} && $ncall ne $self->{call}) {
 552                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 553                 return;
 554         }
 555
 556         my $uref = Route::User::get($ucall);
 557         unless ($uref) {
 558                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 559                 return;
 560         }
 561         my $parent = Route::Node::get($ncall);
 562         unless ($parent) {
 563                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 564                 return;
 565         }
 566
 567         $dxchan = DXChannel::get($ncall);
 568         if ($dxchan && $dxchan ne $self) {
 569                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 570                 return;
 571         }
 572
 573         unless ($dxchan) {
 574                 if ($parent->via_pc92) {
 575                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 576                         return;
 577                 }
 578         }
 579
 580         if (DXChannel::get($ucall)) {
 581                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 582                 return;
 583         }
 584
 585         # input filter if required and then remove user if present
 586 #               return unless $self->in_filter_route($parent);
 587         $parent->del_user($uref);
 588
 589         # send info to all logged in thingies
 590         my $user = DXUser::get_current($ncall);
 591         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 592         $self->tell_buddies('logoutb', $ucall, $ncall);
 593
 594         if (eph_dup($line)) {
 595                 return;
 596         }
 597
 598         $self->route_pc17($origin, $line, $parent, $uref);
 599 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 600 }
 601
 602 # link request
 603 sub handle_18
 604 {
 605         my $self = shift;
 606         my $pcno = shift;
 607         my $line = shift;
 608         my $origin = shift;
 609         my $pc = shift;
 610
 611         $self->state('init');
 612
 613         my $parent = Route::Node::get($self->{call});
 614
 615         # record the type and version offered
 616         if (my ($version) = $pc->[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 617                 $self->{version} = 53 + $version;
 618                 $self->user->version(53 + $version);
 619                 $parent->version(0 + $version);
 620                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 621                 $self->{build} = 0 + $build;
 622                 $self->user->build(0 + $build);
 623                 $parent->build(0 + $build);
 624                 dbg("DXSpider version $version build $build");
 625                 unless ($self->is_spider) {
 626                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 627                         $self->user->sort('S');
 628                         $self->user->put;
 629                         $self->sort('S');
 630                 }
 631 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 632         } else {
 633                 dbg("Unknown software");
 634                 $self->version(50.0);
 635                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 636                 $self->user->version($self->version);
 637         }
 638
 639         if ($pc->[1] =~ /\bpc9x/) {
 640                 if ($self->{isolate}) {
 641                         dbg("pc9x recognised, but $self->{call} is isolated, using old protocol");
 642                 } elsif (!$self->user->wantpc9x) {
 643                         dbg("pc9x explicitly switched off on $self->{call}, using old protocol");
 644                 } else {
 645                         $self->{do_pc9x} = 1;
 646                         dbg("Do px9x set on $self->{call}");
 647                 }
 648         }
 649
 650         # first clear out any nodes on this dxchannel
 651         my @rout = $parent->del_nodes;
 652         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 653         $self->send_local_config();
 654         $self->send(pc20());
 655 }
 656
 657 sub check_add_node
 658 {
 659         my $call = shift;
 660
 661         # add this station to the user database, if required (don't remove SSID from nodes)
 662         my $user = DXUser::get_current($call);
 663         if (!$user) {
 664                 $user = DXUser->new($call);
 665                 $user->priv(1);         # I have relented and defaulted nodes
 666                 $user->lockout(1);
 667                 $user->homenode($call);
 668                 $user->node($call);
 669                 $user->sort('A');
 670         }
 671         return $user;
 672 }
 673
 674 # incoming cluster list
 675 sub handle_19
 676 {
 677         my $self = shift;
 678         my $pcno = shift;
 679         my $line = shift;
 680         my $origin = shift;
 681         my $pc = shift;
 682
 683         my $i;
 684         my $newline = "PC19^";
 685
 686         # new routing list
 687         my (@rout, @pc92out);
 688
 689         # first get the INTERFACE node
 690         my $parent = Route::Node::get($self->{call});
 691         unless ($parent) {
 692                 dbg("PCPROT: my parent $self->{call} has disappeared");
 693                 $self->disconnect;
 694                 return;
 695         }
 696
 697         my $h;
 698
 699         # parse the PC19
 700         #
 701         # We are making a major change from now on. We are only going to accept
 702         # PC19s from directly connected nodes.  This means that we are probably
 703         # going to throw away most of the data that we are being sent.
 704         #
 705         # The justification for this is that most of it is wrong or out of date
 706         # anyway.
 707         #
 708         # From now on we are only going to believe PC92 data and locally connected
 709         # non-pc92 nodes.
 710         #
 711         for ($i = 1; $i < $#$pc-1; $i += 4) {
 712                 my $here = $pc->[$i];
 713                 my $call = uc $pc->[$i+1];
 714                 my $conf = $pc->[$i+2];
 715                 my $ver = $pc->[$i+3];
 716                 next unless defined $here && defined $conf && is_callsign($call);
 717
 718                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 719
 720                 # check for sane parameters
 721                 #                               $ver = 5000 if $ver eq '0000';
 722                 next unless $ver && $ver =~ /^\d+$/;
 723                 next if $ver < 5000;    # only works with version 5 software
 724                 next if length $call < 3; # min 3 letter callsigns
 725                 next if $call eq $main::mycall || $call eq $main::myalias;
 726
 727                 # check that this PC19 isn't trying to alter the wrong dxchan
 728                 $h = 0;
 729                 my $dxchan = DXChannel::get($call);
 730                 if ($dxchan) {
 731                         if ($dxchan == $self) {
 732                                 $h = 1;
 733                         } else {
 734                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 735                                 next;
 736                         }
 737                 }
 738
 739                 # isolate now means only accept stuff from this call only
 740                 if ($self->{isolate} && $call ne $self->{call}) {
 741                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 742                         next;
 743                 }
 744
 745                 my $user = check_add_node($call);
 746
 747 #               if (eph_dup($genline)) {
 748 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 749 #                       next;
 750 #               }
 751
 752
 753                 unless ($h) {
 754                         if ($parent->via_pc92) {
 755                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 756                                 next;
 757                         }
 758                 }
 759
 760                 my $r = Route::Node::get($call);
 761                 my $flags = Route::here($here)|Route::conf($conf);
 762
 763                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 764                 if ($r) {
 765                         my $ar;
 766                         if ($call ne $parent->call) {
 767                                 if ($self->in_filter_route($r)) {
 768                                         $ar = $parent->add($call, $ver, $flags);
 769 #                                       push @rout, $ar if $ar;
 770                                 } else {
 771                                         next;
 772                                 }
 773                         }
 774                         if ($r->version ne $ver || $r->flags != $flags) {
 775                                 $r->version($ver);
 776                                 $r->flags($flags);
 777                         }
 778                         push @rout, $r;
 779                 } else {
 780                         if ($call eq $self->{call} || $user->wantroutepc19) {
 781                                 my $new = Route->new($call); # throw away
 782                                 if ($self->in_filter_route($new)) {
 783                                         my $ar = $parent->add($call, $ver, $flags);
 784                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 785                                         push @rout, $ar if $ar;
 786                                         push @pc92out, $r if $h;
 787                                 } else {
 788                                         next;
 789                                 }
 790                         }
 791                 }
 792
 793                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 794                 my $mref = DXMsg::get_busy($call);
 795                 $mref->stop_msg($call) if $mref;
 796
 797                 $user->lastin($main::systime) unless DXChannel::get($call);
 798                 $user->put;
 799         }
 800
 801         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 802         # but remember there will only be one (pair) these because any extras will be
 803         # thrown away.
 804         if (@rout) {
 805 #               $self->route_pc21($self->{call}, $line, @rout);
 806                 $self->route_pc19($self->{call}, $line, @rout);
 807         }
 808         if (@pc92out && !$pc92_slug_changes) {
 809                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 810         }
 811 }
 812
 813 # send local configuration
 814 sub handle_20
 815 {
 816         my $self = shift;
 817         my $pcno = shift;
 818         my $line = shift;
 819         my $origin = shift;
 820         my $pc = shift;
 821
 822         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 823                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 824                 $self->{do_pc9x} = 0;
 825         }
 826         $self->send_local_config;
 827         $self->send(pc22());
 828         $self->state('normal');
 829         $self->{lastping} = 0;
 830         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 831 }
 832
 833 # delete a cluster from the list
 834 #
 835 # This should never occur for directly connected nodes.
 836 #
 837 sub handle_21
 838 {
 839         my $self = shift;
 840         my $pcno = shift;
 841         my $line = shift;
 842         my $origin = shift;
 843         my $pc = shift;
 844
 845         my $call = uc $pc->[1];
 846
 847         eph_del_regex("^PC1[679].*$call");
 848
 849         # if I get a PC21 from the same callsign as self then ignore it
 850         if ($call eq $self->{call}) {
 851                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 852                 return;
 853         }
 854
 855         # for the above reason and also because of the check for PC21s coming
 856         # in for self->call from outside being ignored further down
 857         # we don't need any isolation code here, because we will never
 858         # act on a PC21 with self->call in it.
 859
 860         my $parent = Route::Node::get($self->{call});
 861         unless ($parent) {
 862                 dbg("PCPROT: my parent $self->{call} has disappeared");
 863                 $self->disconnect;
 864                 return;
 865         }
 866
 867         my @rout;
 868
 869         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
 870                 my $node = Route::Node::get($call);
 871                 if ($node) {
 872
 873                         if ($node->via_pc92) {
 874                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 875                                 return;
 876                         }
 877
 878                         my $dxchan = DXChannel::get($call);
 879                         if ($dxchan && $dxchan != $self) {
 880                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
 881                                 return;
 882                         }
 883
 884                         # input filter it
 885                         return unless $self->in_filter_route($node);
 886
 887                         # routing objects, force a PC21 if it is local
 888                         push @rout, $node->del($parent);
 889                         push @rout, $call if $dxchan && @rout == 0;
 890                 }
 891         } else {
 892                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
 893                 return;
 894         }
 895
 896         if (eph_dup($line)) {
 897                 return;
 898         }
 899
 900         if (@rout) {
 901                 $self->route_pc21($origin, $line, @rout);
 902 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 903         }
 904 }
 905
 906
 907 sub handle_22
 908 {
 909         my $self = shift;
 910         my $pcno = shift;
 911         my $line = shift;
 912         my $origin = shift;
 913         my $pc = shift;
 914
 915         if ($self->{do_pc9x}) {
 916                 if ($self->{state} ne 'init92') {
 917                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 918                         $self->{do_pc9x} = 0;
 919                 }
 920         }
 921         $self->{lastping} = 0;
 922         $self->state('normal');
 923         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 924 }
 925
 926 # WWV info
 927 sub handle_23
 928 {
 929         my $self = shift;
 930         my $pcno = shift;
 931         my $line = shift;
 932         my $origin = shift;
 933         my $pc = shift;
 934
 935         # route foreign' pc27s
 936         if ($pcno == 27) {
 937                 if ($pc->[8] ne $main::mycall) {
 938                         $self->route($pc->[8], $line);
 939                         return;
 940                 }
 941         }
 942
 943
 944         # do some de-duping
 945         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
 946         my $sfi = unpad($pc->[3]);
 947         my $k = unpad($pc->[4]);
 948         my $i = unpad($pc->[5]);
 949         my ($r) = $pc->[6] =~ /R=(\d+)/;
 950         $r = 0 unless $r;
 951         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
 952                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
 953                 return;
 954         }
 955
 956         # global wwv filtering on INPUT
 957         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
 958         if ($self->{inwwvfilter}) {
 959                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
 960                 unless ($filter) {
 961                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 962                         return;
 963                 }
 964         }
 965         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
 966         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
 967                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 968                 return;
 969         }
 970
 971         # note this only takes the first one it gets
 972         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 973         dbg("WWV: $d $pc->[2], sfi:$sfi k:$k info:$i $pc->[6] $pc->[7] $pc->[8] $r") if isdbg('progress');
 974
 975         if (defined &Local::wwv) {
 976                 my $rep;
 977                 eval {
 978                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 979                 };
 980                 return if $rep;
 981         }
 982
 983         # DON'T be silly and send on PC27s!
 984         return if $pcno == 27;
 985
 986         # broadcast to the eager world
 987         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
 988 }
 989
 990 # set here status
 991 sub handle_24
 992 {
 993         my $self = shift;
 994         my $pcno = shift;
 995         my $line = shift;
 996         my $origin = shift;
 997         my $pc = shift;
 998
 999         my $call = uc $pc->[1];
1000         my ($nref, $uref);
1001         $nref = Route::Node::get($call);
1002         $uref = Route::User::get($call);
1003         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1004
1005         if (eph_dup($line)) {
1006                 return;
1007         }
1008
1009         $nref->here($pc->[2]) if $nref;
1010         $uref->here($pc->[2]) if $uref;
1011         my $ref = $nref || $uref;
1012         return unless $self->in_filter_route($ref);
1013
1014         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1015 }
1016
1017 # merge request
1018 sub handle_25
1019 {
1020         my $self = shift;
1021         my $pcno = shift;
1022         my $line = shift;
1023         my $origin = shift;
1024         my $pc = shift;
1025
1026         if ($pc->[1] ne $main::mycall) {
1027                 $self->route($pc->[1], $line);
1028                 return;
1029         }
1030         if ($pc->[2] eq $main::mycall) {
1031                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1032                 return;
1033         }
1034
1035         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1036
1037         # spots
1038         if ($pc->[3] > 0) {
1039                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1040                 my $in;
1041                 foreach $in (@in) {
1042                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1043                 }
1044         }
1045
1046         # wwv
1047         if ($pc->[4] > 0) {
1048                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1049                 my $in;
1050                 foreach $in (@in) {
1051                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1052                 }
1053         }
1054 }
1055
1056 sub handle_26 {goto &handle_11}
1057 sub handle_27 {goto &handle_23}
1058
1059 # mail/file handling
1060 sub handle_28
1061 {
1062         my $self = shift;
1063         my $pcno = shift;
1064         my $line = shift;
1065         my $origin = shift;
1066         my $pc = shift;
1067
1068         if ($pc->[1] eq $main::mycall) {
1069                 no strict 'refs';
1070                 my $sub = "DXMsg::handle_$pcno";
1071                 &$sub($self, @$pc);
1072         } else {
1073                 $self->route($pc->[1], $line) unless $self->is_clx;
1074         }
1075 }
1076
1077 sub handle_29 {goto &handle_28}
1078 sub handle_30 {goto &handle_28}
1079 sub handle_31 {goto &handle_28}
1080 sub handle_32 {goto &handle_28}
1081 sub handle_33 {goto &handle_28}
1082
1083 sub handle_34
1084 {
1085         my $self = shift;
1086         my $pcno = shift;
1087         my $line = shift;
1088         my $origin = shift;
1089         my $pc = shift;
1090
1091         if (eph_dup($line, $eph_pc34_restime)) {
1092                 return;
1093         } else {
1094                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1095         }
1096 }
1097
1098 # remote command replies
1099 sub handle_35
1100 {
1101         my $self = shift;
1102         my $pcno = shift;
1103         my $line = shift;
1104         my $origin = shift;
1105         my $pc = shift;
1106
1107         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1108         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1109 }
1110
1111 sub handle_36 {goto &handle_34}
1112
1113 # database stuff
1114 sub handle_37
1115 {
1116         my $self = shift;
1117         my $pcno = shift;
1118         my $line = shift;
1119         my $origin = shift;
1120         my $pc = shift;
1121
1122         if ($pc->[1] eq $main::mycall) {
1123                 no strict 'refs';
1124                 my $sub = "DXDb::handle_$pcno";
1125                 &$sub($self, @$pc);
1126         } else {
1127                 $self->route($pc->[1], $line) unless $self->is_clx;
1128         }
1129 }
1130
1131 # node connected list from neighbour
1132 sub handle_38
1133 {
1134         my $self = shift;
1135         my $pcno = shift;
1136         my $line = shift;
1137         my $origin = shift;
1138         my $pc = shift;
1139 }
1140
1141 # incoming disconnect
1142 sub handle_39
1143 {
1144         my $self = shift;
1145         my $pcno = shift;
1146         my $line = shift;
1147         my $origin = shift;
1148         my $pc = shift;
1149
1150         if ($pc->[1] eq $self->{call}) {
1151                 $self->disconnect(1);
1152         } else {
1153                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1154         }
1155 }
1156
1157 sub handle_40 {goto &handle_28}
1158
1159 # user info
1160 sub handle_41
1161 {
1162         my $self = shift;
1163         my $pcno = shift;
1164         my $line = shift;
1165         my $origin = shift;
1166         my $pc = shift;
1167
1168         my $call = $pc->[1];
1169         my $sort = $pc->[2];
1170         my $val = $pc->[3];
1171
1172         my $l = "PC41^$call^$sort";
1173         if (eph_dup($l, $eph_info_restime)) {
1174                 return;
1175         }
1176
1177         # input filter if required
1178         #                       my $ref = Route::get($call) || Route->new($call);
1179         #                       return unless $self->in_filter_route($ref);
1180
1181         if ($val eq $sort || $val =~ /^\s*$/) {
1182                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1183                 return;
1184         }
1185
1186         if ($call eq $main::mycall || $call eq $main::myalias) {
1187                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1188                 return;
1189         }
1190         my $chan = DXChannel::get($call);
1191         if ($chan) {
1192                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1193                 return;
1194         }
1195
1196         # add this station to the user database, if required
1197         my $user = DXUser::get_current($call);
1198         $user = DXUser->new($call) unless $user;
1199
1200         if ($sort == 1) {
1201                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1202                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1203                         return;
1204                 }
1205                 $user->name($val);
1206         } elsif ($sort == 2) {
1207                 $user->qth($val);
1208         } elsif ($sort == 3) {
1209                 if (is_latlong($val)) {
1210                         my ($lat, $long) = DXBearing::stoll($val);
1211                         $user->lat($lat) if $lat;
1212                         $user->long($long) if $long;
1213                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1214                 } else {
1215                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1216                         return;
1217                 }
1218         } elsif ($sort == 4) {
1219                 $user->homenode($val);
1220         } elsif ($sort == 5) {
1221                 if (is_qra(uc $val)) {
1222                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1223                         $user->lat($lat) if $lat && !$user->lat;
1224                         $user->long($long) if $long && !$user->long;
1225                         $user->qra(uc $val);
1226                 } else {
1227                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1228                         return;
1229                 }
1230         }
1231         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1232         $user->put;
1233
1234         unless ($self->{isolate}) {
1235                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1236         }
1237
1238         #  perhaps this IS what we want after all
1239         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1240 }
1241
1242 sub handle_42 {goto &handle_28}
1243
1244
1245 # database
1246 sub handle_44 {goto &handle_37}
1247 sub handle_45 {goto &handle_37}
1248 sub handle_46 {goto &handle_37}
1249 sub handle_47 {goto &handle_37}
1250 sub handle_48 {goto &handle_37}
1251
1252 # message and database
1253 sub handle_49
1254 {
1255         my $self = shift;
1256         my $pcno = shift;
1257         my $line = shift;
1258         my $origin = shift;
1259         my $pc = shift;
1260
1261         if (eph_dup($line)) {
1262                 return;
1263         }
1264
1265         if ($pc->[1] eq $main::mycall) {
1266                 DXMsg::handle_49($self, @$pc);
1267         } else {
1268                 $self->route($pc->[1], $line) unless $self->is_clx;
1269         }
1270 }
1271
1272 # keep alive/user list
1273 sub handle_50
1274 {
1275         my $self = shift;
1276         my $pcno = shift;
1277         my $line = shift;
1278         my $origin = shift;
1279         my $pc = shift;
1280
1281         return if (eph_dup($line));
1282
1283         my $call = $pc->[1];
1284
1285         my $node = Route::Node::get($call);
1286         if ($node) {
1287                 return unless $node->call eq $self->{call};
1288                 $node->usercount($pc->[2]) unless $node->users;
1289                 $node->reset_obs;
1290                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1291
1292                 # input filter if required
1293 #               return unless $self->in_filter_route($node);
1294
1295                 unless ($self->{isolate}) {
1296                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1297                 }
1298 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1299         }
1300 }
1301
1302 # incoming ping requests/answers
1303 sub handle_51
1304 {
1305         my $self = shift;
1306         my $pcno = shift;
1307         my $line = shift;
1308         my $origin = shift;
1309         my $pc = shift;
1310
1311         my $to = $pc->[1];
1312         my $from = $pc->[2];
1313         my $flag = $pc->[3];
1314
1315         if ($to eq $main::myalias) {
1316                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1317                 return;
1318         }
1319
1320         # is it for us?
1321         if ($to eq $main::mycall) {
1322                 if ($flag == 1) {
1323                         $self->send(pc51($from, $to, '0'));
1324                 } else {
1325                         DXXml::Ping::handle_ping_reply($self, $from);
1326                 }
1327         } else {
1328                 if (eph_dup($line)) {
1329                         return;
1330                 }
1331                 # route down an appropriate thingy
1332                 $self->route($to, $line);
1333         }
1334 }
1335
1336 sub handle_61 { goto &handle_11; }
1337
1338 # dunno but route it
1339 sub handle_75
1340 {
1341         my $self = shift;
1342         my $pcno = shift;
1343         my $line = shift;
1344         my $origin = shift;
1345         my $pc = shift;
1346
1347         my $call = $pc->[1];
1348         if ($call ne $main::mycall) {
1349                 $self->route($call, $line);
1350         }
1351 }
1352
1353 # WCY broadcasts
1354 sub handle_73
1355 {
1356         my $self = shift;
1357         my $pcno = shift;
1358         my $line = shift;
1359         my $origin = shift;
1360         my $pc = shift;
1361
1362         my $call = $pc->[1];
1363
1364         # do some de-duping
1365         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1366         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1367                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1368                 return;
1369         }
1370         $pc = [ map { unpad($_) } @$pc ];
1371         if (WCY::dup($d)) {
1372                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1373                 return;
1374         }
1375
1376         my $wcy = WCY::update($d, @$pc[2..12]);
1377         dbg("WCY: " . join ', ', @$pc[2..12]) if isdbg('progress');
1378
1379         if (defined &Local::wcy) {
1380                 my $rep;
1381                 eval {
1382                         $rep = Local::wcy($self, @$pc[1..12]);
1383                 };
1384                 return if $rep;
1385         }
1386
1387         # broadcast to the eager world
1388         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1389 }
1390
1391 # remote commands (incoming)
1392 sub handle_84
1393 {
1394         my $self = shift;
1395         my $pcno = shift;
1396         my $line = shift;
1397         my $origin = shift;
1398         my $pc = shift;
1399
1400         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1401 }
1402
1403 # remote command replies
1404 sub handle_85
1405 {
1406         my $self = shift;
1407         my $pcno = shift;
1408         my $line = shift;
1409         my $origin = shift;
1410         my $pc = shift;
1411
1412         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1413 }
1414
1415 # decode a pc92 call: flag call : version : build
1416 sub _decode_pc92_call
1417 {
1418         my $icall = shift;
1419         my @part = split /:/, $icall;
1420         my ($flag, $call) = unpack "A A*", $part[0];
1421         unless (defined $flag && $flag ge '0' && $flag le '7') {
1422                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1423                 return ();
1424         }
1425         unless ($call && is_callsign($call)) {
1426                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1427                 return ();
1428         }
1429         my $is_node = $flag & 4;
1430         my $is_extnode = $flag & 2;
1431         my $here = $flag & 1;
1432         my $ip  = $part[3];
1433         $ip ||= $part[1] if $part[1] && ($part[1] =~ /^(?:\d+\.)+/ || $part[1] =~ /^(?:(?:[abcdef\d]+)?,)+/);
1434         $ip =~ s/,/:/g if $ip;
1435         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2], $ip);
1436 }
1437
1438 # decode a pc92 call: flag call : version : build
1439 sub _encode_pc92_call
1440 {
1441         my $ref = shift;
1442
1443         # plain call or value
1444         return $ref unless ref $ref;
1445
1446         my $ext = shift || 0;
1447         my $flag = 0;
1448         my $call = $ref->call;
1449         my $extra = '';
1450         $flag |= $ref->here ? 1 : 0;
1451         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1452                 $flag |= 4;
1453                 my $dxchan = DXChannel::get($call);
1454                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1455                 if (($ext & 1) && $ref->version) {
1456                         my $version = $ref->version || 1.0;
1457                         $version =  $version * 100 + 5300 if $version < 50;
1458                         $extra .= ":" . $version;
1459                 }
1460         }
1461         if (($ext & 2) && $ref->ip) {
1462                 my $ip = $ref->ip;
1463                 $ip =~ s/:/,/g;
1464                 $extra .= ':' . $ip;
1465         }
1466         return "$flag$call$extra";
1467 }
1468
1469 my %things_add;
1470 my %things_del;
1471
1472 sub _add_thingy
1473 {
1474         my $parent = shift;
1475         my $s = shift;
1476         my $dxchan = shift;
1477         my $hops = shift;
1478
1479         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1480         my @rout;
1481
1482         # remove spurious IPV6 prefix on IPV4 addresses
1483         $ip =~ s/^::ffff:// if $ip;
1484
1485         if ($call) {
1486                 my $ncall = $parent->call;
1487                 if ($is_node) {
1488                         dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1489                         @rout = $parent->add($call, $version, Route::here($here), $ip);
1490                         my $r = Route::Node::get($call);
1491                         $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1492                         if ($ip) {
1493                                 $r->ip($ip);
1494                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1495                         }
1496                 } else {
1497                         dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1498                         @rout = $parent->add_user($call, Route::here($here), $ip);
1499                         $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1500                         my $r = Route::User::get($call);
1501                         if ($ip) {
1502                                 $r->ip($ip);
1503                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1504                         }
1505                 }
1506                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1507                         $things_add{$call} = Route::get($call);
1508                         delete $things_del{$call};
1509                 }
1510         }
1511         return @rout;
1512 }
1513
1514 sub _del_thingy
1515 {
1516         my $parent = shift;
1517         my $s = shift;
1518         my $dxchan = shift;
1519         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1520         my @rout;
1521         if ($call) {
1522                 my $ref;
1523                 if ($is_node) {
1524                         $ref = Route::Node::get($call);
1525                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1526                         @rout = $ref->del($parent) if $ref;
1527                 } else {
1528                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1529                         $ref = Route::User::get($call);
1530                         if ($ref) {
1531                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1532                                 @rout = $parent->del_user($ref);
1533                         }
1534                 }
1535                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1536                         $things_del{$call} = $ref unless exists $things_add{$call};
1537                         delete $things_add{$call};
1538                 }
1539         }
1540         return @rout;
1541 }
1542
1543 # this will only happen if we are slugging changes and
1544 # there are some changes to be sent, it will create an add or a delete
1545 # or both
1546 sub gen_pc92_changes
1547 {
1548         my @add = values %things_add;
1549         my @del = values %things_del;
1550         return (\@add, \@del);
1551 }
1552
1553 sub clear_pc92_changes
1554 {
1555         %things_add = %things_del = ();
1556         $last_pc92_slug = $main::systime;
1557 }
1558
1559 my $_last_time;
1560 my $_last_occurs;
1561 my $_last_pc9x_id;
1562
1563 sub last_pc9x_id
1564 {
1565         return $_last_pc9x_id;
1566 }
1567
1568 sub gen_pc9x_t
1569 {
1570         if (!$_last_time || $_last_time != $main::systime) {
1571                 $_last_time = $main::systime;
1572                 $_last_occurs = 0;
1573                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1574         } else {
1575                 $_last_occurs++;
1576                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1577         }
1578 }
1579
1580 sub check_pc9x_t
1581 {
1582         my $call = shift;
1583         my $t = shift;
1584         my $pc = shift;
1585         my $create = shift;
1586
1587         # check that the time is between 0 >= $t < 86400
1588         unless ($t >= 0 && $t < 86400) {
1589                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1590                 return undef;
1591         }
1592
1593         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1594         my $now = $main::systime - $main::systime_daystart ;
1595         my $diff = abs($now - $t);
1596         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1597                 my $c = ref $call ? $call->call : $call;
1598                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1599                 return undef;
1600         }
1601
1602         my $parent = ref $call ? $call : Route::Node::get($call);
1603         if ($parent) {
1604                 # we only do this for external calls whose routing table
1605                 # record come and go. The reference for mycall is permanent
1606                 # and not that frequently used, it also never times out, so
1607                 # the id on it is completely unreliable. Besides, only commands
1608                 # originating on this box will go through this code...
1609                 if ($parent->call ne $main::mycall) {
1610                         my $lastid = $parent->lastid;
1611                         if (defined $lastid) {
1612                                 if ($t < $lastid) {
1613                                         # note that this is where we determine whether this pc9x has come in yesterday
1614                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1615                                         # duplicate sentence. To determine this we need to do some module 86400
1616                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1617                                         # low numbers that it is a new sentence.
1618                                         #
1619                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1620                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1621                                         # 86378 respectively in the calculation below).
1622                                         #
1623                                         if ($t+86400-$lastid > $pc9x_past_age) {
1624                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1625                                                 return undef;
1626                                         }
1627                                 } elsif ($t == $lastid) {
1628                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1629                                         return undef;
1630                                 } else {
1631                                         # check that if we have a low number in lastid that yesterday's numbers
1632                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1633                                         if ($lastid+86400-$t < $pc9x_past_age) {
1634                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1635                                                 return undef;
1636                                         }
1637                                 }
1638                         }
1639                 }
1640         } elsif ($create) {
1641                 $parent = Route::Node->new($call);
1642         } else {
1643                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1644                 return undef;
1645         }
1646         if (isdbg('pc92dedupe')) {
1647                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1648                 my $val = $parent->{lastid};
1649                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1650                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1651         }
1652         $parent->lastid($t);
1653
1654         return $parent;
1655 }
1656
1657 sub pc92_handle_first_slot
1658 {
1659         my $self = shift;
1660         my $slot = shift;
1661         my $parent = shift;
1662         my $t = shift;
1663         my $hops = shift;
1664         my $oparent = $parent;
1665
1666         my @radd;
1667
1668         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1669         if ($call && $is_node) {
1670                 if ($call eq $main::mycall) {
1671                         dbg("PCPROT: $call looped back onto \$main::mycall ($main::mycall), ignored") if isdbg('chan');
1672                         return;
1673                 }
1674                 if ($call eq $main::myalias) {
1675                         dbg("PCPROT: $call looped back onto \$main::myalias ($main::myalias), ignored") if isdbg('chan');
1676                         return;
1677                 }
1678                 # this is only accepted from my "self".
1679                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1680                 # locally connected. Local nodes always take precedence. But we remember the lastid
1681                 # to try to reduce the number of dupe PC92s for this external node.
1682                 if (DXChannel::get($call) && $call ne $self->{call}) {
1683                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1684                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1685                         return;
1686                 }
1687                 if ($is_extnode) {
1688                         # reparent to external node (note that we must have received a 'C' or 'A' record
1689                         # from the true parent node for this external before we get one for the this node
1690                         unless ($parent = Route::Node::get($call)) {
1691                                 if ($is_extnode && $oparent) {
1692                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
1693                                         $parent = $radd[0];
1694                                 } else {
1695                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1696                                         return;
1697                                 }
1698                         }
1699                         $parent = check_pc9x_t($call, $t, 92) || return;
1700                         $parent->via_pc92(1);
1701                         $parent->PC92C_dxchan($self->{call}, $hops);
1702                 }
1703         } else {
1704                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1705                 return;
1706         }
1707         $parent->here(Route::here($here));
1708         $parent->version($version || $pc19_version) if $version;
1709         $parent->build($build) if $build;
1710         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1711         return ($parent, @radd);
1712 }
1713
1714 # DXSpider routing entries
1715 sub handle_92
1716 {
1717         my $self = shift;
1718         my $pcno = shift;
1719         my $line = shift;
1720         my $origin = shift;
1721         my $pc = shift;
1722
1723         my (@radd, @rdel);
1724
1725         my $pcall = $pc->[1];
1726         my $t = $pc->[2];
1727         my $sort = $pc->[3];
1728         my $hops = $pc->[-1];
1729
1730         # this catches loops of A/Ds
1731 #       if (eph_dup($line, $pc9x_dupe_age)) {
1732 #               return;
1733 #       }
1734
1735         if ($pcall eq $main::mycall) {
1736                 dbg("PCPROT: looped back, ignored") if isdbg('chan');
1737                 return;
1738         }
1739
1740         if ($pcall eq $main::myalias) {
1741                 dbg("PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored") if isdbg('chan');
1742                 return;
1743         }
1744
1745         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1746                 if ($self->{isolate}) {
1747                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
1748                         return;
1749                 } elsif (!$self->user->wantpc9x) {
1750                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
1751                         return;
1752                 } else {
1753                         $self->state('init92');
1754                         $self->{do_pc9x} = 1;
1755                         dbg("DXPROT: Do pc9x set on $pcall");
1756                 }
1757         }
1758         unless ($self->{do_pc9x}) {
1759                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1760                 return;
1761         }
1762
1763         # don't create routing entries for D records that don't already exist
1764         # this is what causes all those PC92 loops!
1765         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1766         my $oparent = $parent;
1767
1768         $parent->do_pc9x(1);
1769         $parent->via_pc92(1);
1770
1771         if ($sort eq 'F' || $sort eq 'R') {
1772
1773                 # this is the route finding section
1774                 # here is where the consequences of the 'find' command
1775                 # are dealt with
1776
1777                 my $from = $pc->[4];
1778                 my $target = $pc->[5];
1779
1780                 if ($sort eq 'F') {
1781                         my $flag;
1782                         my $ref;
1783                         my $dxchan;
1784                         if ($ref = DXChannel::get($target)) {
1785                                 $flag = 1;              # we are directly connected
1786                         } else {
1787                                 $ref = Route::get($target);
1788                                 $dxchan = $ref->dxchan;
1789                                 $flag = 2;
1790                         }
1791                         if ($ref && $flag && $dxchan) {
1792                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1793                                 return;
1794                         }
1795                 } elsif ($sort eq 'R') {
1796                         if (my $dxchan = DXChannel::get($from)) {
1797                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
1798                         } else {
1799                                 my $ref = Route::get($from);
1800                                 if ($ref) {
1801                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1802                                         if (@dxchan) {
1803                                                 $_->send($line) for @dxchan;
1804                                         } else {
1805                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1806                                         }
1807                                 } else {
1808                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1809                                 }
1810                         }
1811                         return;
1812                 }
1813
1814         } elsif ($sort eq 'K') {
1815                 $pc92Kin += length $line;
1816
1817                 # remember the last channel we arrived on
1818                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1819
1820                 my @ent = _decode_pc92_call($pc->[4]);
1821
1822                 if (@ent) {
1823                         my $add;
1824
1825                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
1826                         return unless $parent; # dupe
1827
1828                         push @radd, $add if $add;
1829                         $parent->reset_obs;
1830                         $parent->version($ent[4]) if $ent[4];
1831                         $parent->build($ent[5]) if $ent[5];
1832
1833                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1834                 }
1835         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1836
1837                 $pc92Ain += length $line if $sort eq 'A';
1838                 $pc92Cin += length $line if $sort eq 'C';
1839                 $pc92Din += length $line if $sort eq 'D';
1840
1841                 # remember the last channel we arrived on
1842                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1843
1844                 # this is the main route section
1845                 # here is where all the routes are created and destroyed
1846
1847                 # cope with missing duplicate node calls in the first slot
1848                 my $me = $pc->[4] || '';
1849                 $me ||= _encode_pc92_call($parent) unless $me ;
1850
1851                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
1852
1853                 if (@ent) {
1854
1855                         # look at the first one which will always be a node of some sort
1856                         # except in the case of 'A' or 'D' in which the $pcall is used
1857                         # otherwise use the node call and update any information
1858                         # that needs to be done.
1859                         my $add;
1860
1861                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
1862                         return unless $parent; # dupe
1863
1864                         shift @ent;
1865                         push @radd, $add if $add;
1866                 }
1867
1868                 # do a pass through removing any references to either mycall
1869                 my @nent;
1870                 for (@ent) {
1871                         my $dxc;
1872                         next unless $_ && @$_;
1873                         if ($_->[0] eq $main::mycall) {
1874                                 dbg("PCPROT: $_->[0] refers to me, ignored") if isdbg('chanerr');
1875                                 next;
1876                         }
1877                         push @nent, $_;
1878                 }
1879
1880                 if ($sort eq 'A') {
1881                         for (@nent) {
1882                                 push @radd, _add_thingy($parent, $_, $self, $hops);
1883                         }
1884                 } elsif ($sort eq 'D') {
1885                         for (@nent) {
1886                                 push @rdel, _del_thingy($parent, $_, $self);
1887                         }
1888                 } elsif ($sort eq 'C') {
1889                         my (@nodes, @users);
1890
1891                         # we reset obscounts on config records as well as K records
1892                         $parent->reset_obs;
1893                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1894
1895                         #
1896                         foreach my $r (@nent) {
1897                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1898                                 if ($r->[0]) {
1899                                         if ($r->[1]) {
1900                                                 push @nodes, $r->[0];
1901                                         } else {
1902                                                 push @users, $r->[0];
1903                                         }
1904                                 } else {
1905                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1906                                 }
1907                         }
1908
1909                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1910
1911                         # add users here
1912                         foreach my $r (@nent) {
1913                                 my $call = $r->[0];
1914                                 if ($call) {
1915                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
1916                                 }
1917                         }
1918                         # del users here
1919                         foreach my $r (@$dnodes) {
1920                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
1921                         }
1922                         foreach my $r (@$dusers) {
1923                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
1924                         }
1925
1926                         # remember this last PC92C for rebroadcast on demand
1927                         $parent->last_PC92C($line);
1928                 } else {
1929                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1930                         return;
1931                 }
1932
1933                 foreach my $r (@rdel) {
1934                         next unless $r;
1935
1936                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1937                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1938                 }
1939                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1940                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1941                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1942                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1943                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1944         }
1945
1946         # broadcast it if we get here
1947         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1948 }
1949
1950 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
1951 # might be on two or more nodes at the same time or that there may be more than
1952 # one equal distance neighbour to a node.
1953 #
1954 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
1955 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
1956 # each and then combined to give a set of dxchans to send the PC9x record down
1957 #
1958 sub find_pc9x_routes
1959 {
1960         my $to = shift;
1961         my $ref = Route::get($to);
1962         my @parent;
1963         my %cand;
1964
1965         if ($ref->isa('Route::User')) {
1966                 my $dxchan = DXChannel::get($to);
1967                 push @parent, $to if $dxchan;
1968                 push @parent, $ref->parents;
1969         } else {
1970                 @parent = $to;
1971         }
1972         foreach my $p (@parent) {
1973                 my $lasthops;
1974                 my @routes = Route::findroutes($p);
1975                 foreach my $r (@routes) {
1976                         $lasthops = $r->[0] unless defined $lasthops;
1977                         if ($r->[0] == $lasthops) {
1978                                 $cand{$r->[1]->call} = $r->[1];
1979                         } else {
1980                                 last;
1981                         }
1982                 }
1983         }
1984         return values %cand;
1985 }
1986
1987 sub handle_93
1988 {
1989         my $self = shift;
1990         my $pcno = shift;
1991         my $line = shift;
1992         my $origin = shift;
1993         my $pc = shift;
1994
1995 #       $self->{do_pc9x} ||= 1;
1996
1997         my $pcall = $pc->[1];                   # this is now checked earlier
1998
1999         # remember that we are converting PC10->PC93 and self will be $main::me if it
2000         # comes from us
2001         unless ($self->{do_pc9x}) {
2002                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2003                 return;
2004         }
2005
2006         my $t = $pc->[2];
2007         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2008
2009         my $to = uc $pc->[3];
2010         my $from = uc $pc->[4];
2011         my $via = uc $pc->[5];
2012         my $text = $pc->[6];
2013         my $onode = uc $pc->[7];
2014         $onode = $pcall if @$pc <= 8;
2015
2016         # this is catch loops caused by bad software ...
2017         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2018                 return;
2019         }
2020
2021         if (isdbg('progress')) {
2022                 my $vs = $via ne '*' ? " via $via" : '';
2023                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text'";
2024                 dbg($s);
2025         }
2026
2027         # will we allow it at all?
2028         if ($censorpc) {
2029                 my @bad;
2030                 if (@bad = BadWords::check($text)) {
2031                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
2032                         return;
2033                 }
2034         }
2035
2036         # if this is a 'bad spotter' user then ignore it
2037         my $nossid = $from;
2038         $nossid =~ s/-\d+$//;
2039         if ($badspotter->in($nossid)) {
2040                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
2041                 return;
2042         }
2043
2044         # ignore PC93 coming in from outside this node with a target of local
2045         if ($to eq 'LOCAL' && $self != $main::me) {
2046                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2047                 return;
2048         }
2049
2050         # if it is routeable then then treat it like a talk
2051         my $ref = Route::get($to);
2052         if ($ref) {
2053                 my $dxchan;
2054
2055                 # convert to PC10 or local talks where appropriate
2056                 # PC93 capable nodes of the same hop count all get a copy
2057                 # if there is a PC10 node then it will get a copy and that
2058                 # will be it. Hopefully such a node will not figure highly
2059                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2060                 # note that both local and PC93s at the same time are possible if the
2061                 # user on more than one node.
2062                 my @routes = find_pc9x_routes($to);
2063                 my $lasthops;
2064                 foreach $dxchan (@routes) {
2065                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2066                                 if ($dxchan->{do_pc9x}) {
2067                                         $dxchan->send($line);
2068                                 } else {
2069                                         $dxchan->talk($from, $to, $via, $text, $onode);
2070                                 }
2071                         } else {
2072                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2073                         }
2074                 }
2075                 return;
2076
2077         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2078                 # announces
2079                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2080                 my $wx = $to eq 'WX' ? '1' : '0';
2081                 my $local = $via eq 'LOCAL' ? '*' : $via;
2082
2083                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2084                 return if $via eq 'LOCAL';
2085         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2086                 # chat messages really only locally connected users
2087                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2088         }
2089
2090         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2091         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2092 }
2093
2094 # if get here then rebroadcast the thing with its Hop count decremented (if
2095 # there is one). If it has a hop count and it decrements to zero then don't
2096 # rebroadcast it.
2097 #
2098 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2099 #        REBROADCAST!!!!
2100 #
2101
2102 sub handle_default
2103 {
2104         my $self = shift;
2105         my $pcno = shift;
2106         my $line = shift;
2107         my $origin = shift;
2108         my $pc = shift;
2109
2110         unless (eph_dup($line)) {
2111                 if ($pcno >= 90) {
2112                         my $pcall = $pc->[1];
2113                         unless (is_callsign($pcall)) {
2114                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2115                                 return;
2116                         }
2117                         my $t = $pc->[2];
2118                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2119                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2120                 } else {
2121                         unless ($self->{isolate}) {
2122                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2123                         }
2124                 }
2125         }
2126 }
2127
2128 1;