perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35
  36 use strict;
  37
  38 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  39                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  40                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  41                         $investigation_int $pc19_version $myprot_version
  42                         %nodehops $baddx $badspotter $badnode $censorpc
  43                         $allowzero $decode_dk0wcy $send_opernam @checklist
  44                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  45                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  46                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  47                         $pc92filterdef
  48                    );
  49
  50 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  51 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  52 $pc92_slug_changes = 60*5;              # slug any changes going outward for this long
  53 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  54 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  55 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  56         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  57                                 # this is actually the partition between "yesterday" and "today" but old.
  58
  59 $pc92filterdef = bless ([
  60                           # tag, sort, field, priv, special parser
  61                           ['call', 'c', 0],
  62                           ['by', 'c', 0],
  63                           ['dxcc', 'nc', 1],
  64                           ['itu', 'ni', 2],
  65                           ['zone', 'nz', 3],
  66                          ], 'Filter::Cmd');
  67
  68
  69 # incoming talk commands
  70 sub handle_10
  71 {
  72         my $self = shift;
  73         my $pcno = shift;
  74         my $line = shift;
  75         my $origin = shift;
  76         my $pc = shift;
  77
  78         # this is to catch loops caused by bad software ...
  79         if (eph_dup($line, $pc10_dupe_age)) {
  80                 return;
  81         }
  82
  83         # will we allow it at all?
  84         if ($censorpc) {
  85                 my @bad;
  86                 if (@bad = BadWords::check($pc->[3])) {
  87                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  88                         return;
  89                 }
  90         }
  91
  92         # is it for me or one of mine?
  93         my ($from, $to, $via, $call, $dxchan);
  94         $from = $pc->[1];
  95         if ($pc->[5] gt ' ') {
  96                 $via = $pc->[2];
  97                 $to = $pc->[5];
  98         } else {
  99                 $to = $pc->[2];
 100         }
 101
 102         # if this is a 'nodx' node then ignore it
 103         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 104                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 105                 return;
 106         }
 107
 108         # if this is a 'bad spotter' user then ignore it
 109         my $nossid = $from;
 110         $nossid =~ s/-\d+$//;
 111         if ($badspotter->in($nossid)) {
 112                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 113                 return;
 114         }
 115
 116         # if we are converting announces to talk is it a dup?
 117         if ($ann_to_talk) {
 118                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 119                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 120                         return;
 121                 }
 122         }
 123
 124         # convert this to a PC93, coming from mycall with origin set and process it as such
 125         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]));
 126 }
 127
 128 # DX Spot handling
 129 sub handle_11
 130 {
 131         my $self = shift;
 132         my $pcno = shift;
 133         my $line = shift;
 134         my $origin = shift;
 135         my $pc = shift;
 136
 137         # route 'foreign' pc26s
 138         if ($pcno == 26) {
 139                 if ($pc->[7] ne $main::mycall) {
 140                         $self->route($pc->[7], $line);
 141                         return;
 142                 }
 143         }
 144
 145 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 146
 147         # is the spotted callsign blank? This should really be trapped earlier but it
 148         # could break other protocol sentences. Also check for lower case characters.
 149         if ($pc->[2] =~ /^\s*$/) {
 150                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 151                 return;
 152         }
 153         if ($pc->[2] =~ /[a-z]/) {
 154                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 155                 return;
 156         }
 157
 158
 159         # if this is a 'nodx' node then ignore it
 160         if ($badnode->in($pc->[7])) {
 161                 dbg("PCPROT: Bad Node $pc->[7], dropped") if isdbg('chanerr');
 162                 return;
 163         }
 164
 165         # if this is a 'bad spotter' or an unknown user then ignore it. BUT if it's got an IP address then allow it through
 166         my $nossid = $pc->[6];
 167         $nossid =~ s/-\d+$//;
 168         if ($badspotter->in($nossid)) {
 169                 dbg("PCPROT: Bad Spotter $pc->[6], dropped") if isdbg('chanerr');
 170                 return;
 171         }
 172 #       unless (is_ipaddr($pc->[8]) || DXUser::get_current($pc->[6])) {
 173 #               dbg("PCPROT: Unknown Spotter $pc->[6], dropped") if isdbg('chanerr');
 174 #               return;
 175 #       }
 176
 177         # convert the date to a unix date
 178         my $d = cltounix($pc->[3], $pc->[4]);
 179         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 180         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 181                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n") if isdbg('chanerr');
 182                 return;
 183         }
 184
 185         # is it 'baddx'
 186         if ($baddx->in($pc->[2]) || BadWords::check($pc->[2])) {
 187                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 188                 return;
 189         }
 190
 191         # do some de-duping
 192         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 193         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 194         if ($pc->[2] =~ /BUST\w*$/) {
 195                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 196                 return;
 197         }
 198         if ($censorpc) {
 199                 my @bad;
 200                 if (@bad = BadWords::check($pc->[5])) {
 201                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 202                         return;
 203                 }
 204         }
 205
 206         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 207         # global spot filtering on INPUT
 208         if ($self->{inspotsfilter}) {
 209                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 210                 unless ($filter) {
 211                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 212                         return;
 213                 }
 214         }
 215
 216         # this goes after the input filtering, but before the add
 217         # so that if it is input filtered, it isn't added to the dup
 218         # list. This allows it to come in from a "legitimate" source
 219         if (Spot::dup(@spot[0..4,5])) {
 220                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         # add it
 225         Spot::add(@spot);
 226
 227         my $ip = $spot[14] if exists $spot[14];
 228         if (isdbg('progress')) {
 229                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 230                 my $d = cldatetime($spot[2]);
 231                 $d =~ /^s+//;
 232                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 233                 $s .= " '$spot[3]'" if $spot[3];
 234                 dbg($s);
 235         }
 236
 237         #
 238         # @spot at this point contains:-
 239         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 240         # then  spotted itu, spotted cq, spotters itu, spotters cq
 241         # you should be able to route on any of these
 242         #
 243
 244         # fix up qra locators of known users
 245         my $user = DXUser::get_current($spot[4]);
 246         if ($user) {
 247                 my $qra = $user->qra;
 248                 unless ($qra && is_qra($qra)) {
 249                         my $lat = $user->lat;
 250                         my $long = $user->long;
 251                         if (defined $lat && defined $long) {
 252                                 $user->qra(DXBearing::lltoqra($lat, $long));
 253                                 $user->put;
 254                         }
 255                 }
 256
 257                 # send a remote command to a distant cluster if it is visible and there is no
 258                 # qra locator and we havn't done it for a month.
 259
 260                 unless ($user->qra) {
 261                         my $node;
 262                         my $to = $user->homenode;
 263                         my $last = $user->lastoper || 0;
 264                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 265                                 my $cmd = "forward/opernam $spot[4]";
 266                                 # send the rcmd but we aren't interested in the replies...
 267                                 my $dxchan = $node->dxchan;
 268                                 if ($dxchan && $dxchan->is_clx) {
 269                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 270                                 } else {
 271                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 272                                 }
 273                                 if ($to ne $pc->[7]) {
 274                                         $to = $pc->[7];
 275                                         $node = Route::Node::get($to);
 276                                         if ($node) {
 277                                                 $dxchan = $node->dxchan;
 278                                                 if ($dxchan && $dxchan->is_clx) {
 279                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 280                                                 } else {
 281                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 282                                                 }
 283                                         }
 284                                 }
 285                                 $user->lastoper($main::systime);
 286                                 $user->put;
 287                         }
 288                 }
 289         }
 290
 291         # local processing
 292         if (defined &Local::spot) {
 293                 my $r;
 294                 eval {
 295                         $r = Local::spot($self, @spot);
 296                 };
 297                 return if $r;
 298         }
 299
 300         # DON'T be silly and send on PC26s!
 301         return if $pcno == 26;
 302
 303         # send out the filtered spots
 304         send_dx_spot($self, $line, @spot) if @spot;
 305 }
 306
 307 # announces
 308 sub handle_12
 309 {
 310         my $self = shift;
 311         my $pcno = shift;
 312         my $line = shift;
 313         my $origin = shift;
 314         my $pc = shift;
 315
 316         # announce duplicate checking
 317         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 318
 319         if ($censorpc) {
 320                 my @bad;
 321                 if (@bad = BadWords::check($pc->[3])) {
 322                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 323                         return;
 324                 }
 325         }
 326
 327         # if this is a 'nodx' node then ignore it
 328         if ($badnode->in($pc->[5])) {
 329                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 330                 return;
 331         }
 332
 333         # if this is a 'bad spotter' user then ignore it
 334         my $nossid = $pc->[1];
 335         $nossid =~ s/-\d+$//;
 336         if ($badspotter->in($nossid)) {
 337                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 338                 return;
 339         }
 340
 341         # ignore PC12s from origins that use PCxx protocol
 342         my $oref = Route::get($origin);
 343         if ($oref->do_pc9x) {
 344                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 345                 return;
 346         }
 347
 348         my $dxchan;
 349
 350         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 351                 $self->send_chat(0, $line, @$pc[1..6]);
 352         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 353
 354                 # ignore something that looks like a chat line coming in with sysop
 355                 # flag - this is a kludge...
 356                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 357                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 358                         return;
 359                 }
 360
 361                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 362                 # or one saying 'to <call>' to a talk if we can route to the recipient
 363                 if ($ann_to_talk) {
 364                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 365                         if ($call) {
 366                                 my $ref = Route::get($call);
 367                                 if ($ref) {
 368                                         $dxchan = $ref->dxchan;
 369                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 370                                         return;
 371                                 }
 372                         }
 373                 }
 374
 375                 # send it
 376                 $self->send_announce(0, $line, @$pc[1..6]);
 377         } else {
 378                 $self->route($pc->[2], $line);
 379         }
 380
 381         # local processing
 382         if (defined &Local::ann) {
 383                 my $r;
 384                 eval {
 385                         $r = Local::ann($self, $line, @$pc[1..6]);
 386                 };
 387                 return if $r;
 388         }
 389 }
 390
 391 sub handle_15
 392 {
 393         my $self = shift;
 394         my $pcno = shift;
 395         my $line = shift;
 396         my $origin = shift;
 397         my $pc = shift;
 398
 399         if (eph_dup($line, $eph_pc15_restime)) {
 400                 return;
 401         } else {
 402                 unless ($self->{isolate}) {
 403                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 404                 }
 405         }
 406 }
 407
 408 # incoming user
 409 sub handle_16
 410 {
 411         my $self = shift;
 412         my $pcno = shift;
 413         my $line = shift;
 414         my $origin = shift;
 415         my $pc = shift;
 416
 417         # general checks
 418         my $dxchan;
 419         my $ncall = $pc->[1];
 420         my $newline = "PC16^";
 421
 422         # dos I want users from this channel?
 423         unless ($self->user->wantpc16) {
 424                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 425                 return;
 426         }
 427
 428         # is it me?
 429         if ($ncall eq $main::mycall) {
 430                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 431                 return;
 432         }
 433
 434         my $h;
 435         $h = 1 if DXChannel::get($ncall);
 436         if ($h && $self->{call} ne $ncall) {
 437                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 438                 return;
 439         }
 440
 441         if (eph_dup($line)) {
 442                 return;
 443         }
 444
 445         # isolate now means only accept stuff from this call only
 446         if ($self->{isolate} && $ncall ne $self->{call}) {
 447                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 448                 return;
 449         }
 450
 451         my $parent = Route::Node::get($ncall);
 452
 453         if ($parent) {
 454                 $dxchan = $parent->dxchan;
 455                 if ($dxchan && $dxchan ne $self) {
 456                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 457                         return;
 458                 }
 459
 460                 # input filter if required
 461                 return unless $self->in_filter_route($parent);
 462         } else {
 463                 $parent = Route::Node->new($ncall);
 464         }
 465
 466         unless ($h) {
 467                 if ($parent->via_pc92) {
 468                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 469                         return;
 470                 }
 471         }
 472
 473         my $i;
 474         my @rout;
 475         for ($i = 2; $i < $#$pc; $i++) {
 476                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 477                 next unless $call && $conf && defined $here && is_callsign($call);
 478                 next if $call eq $main::mycall;
 479
 480                 eph_del_regex("^PC17\\^$call\\^$ncall");
 481
 482                 $conf = $conf eq '*';
 483
 484                 # reject this if we think it is a node already
 485                 my $r = Route::Node::get($call);
 486                 my $u = DXUser::get_current($call) unless $r;
 487                 if ($r || ($u && $u->is_node)) {
 488                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 489                         next;
 490                 }
 491
 492                 $r = Route::User::get($call);
 493                 my $flags = Route::here($here)|Route::conf($conf);
 494
 495                 if ($r) {
 496                         my $au = $r->addparent($parent);
 497                         if ($r->flags != $flags) {
 498                                 $r->flags($flags);
 499                                 $au = $r;
 500                         }
 501                         push @rout, $r if $h && $au;
 502                 } else {
 503                         my @ans = $parent->add_user($call, $flags);
 504                         push @rout, @ans if $h && @ans;
 505                 }
 506
 507                 # add this station to the user database, if required
 508                 my $user = DXUser::get_current($ncall);
 509                 $user = DXUser->new($call) unless $user;
 510                 $user->homenode($parent->call) if !$user->homenode;
 511                 $user->node($parent->call);
 512                 $user->lastin($main::systime) unless DXChannel::get($call);
 513                 $user->put;
 514
 515                 # send info to all logged in thingies
 516                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 517                 $self->tell_buddies('loginb', $call, $ncall);
 518         }
 519         if (@rout) {
 520                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 521 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 522         }
 523 }
 524
 525 # remove a user
 526 sub handle_17
 527 {
 528         my $self = shift;
 529         my $pcno = shift;
 530         my $line = shift;
 531         my $origin = shift;
 532         my $pc = shift;
 533
 534         my $dxchan;
 535         my $ncall = $pc->[2];
 536         my $ucall = $pc->[1];
 537
 538         eph_del_regex("^PC16\\^$ncall.*$ucall");
 539
 540         # do I want users from this channel?
 541         unless ($self->user->wantpc16) {
 542                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 543                 return;
 544         }
 545
 546         if ($ncall eq $main::mycall) {
 547                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 548                 return;
 549         }
 550
 551         # isolate now means only accept stuff from this call only
 552         if ($self->{isolate} && $ncall ne $self->{call}) {
 553                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 554                 return;
 555         }
 556
 557         my $uref = Route::User::get($ucall);
 558         unless ($uref) {
 559                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 560                 return;
 561         }
 562         my $parent = Route::Node::get($ncall);
 563         unless ($parent) {
 564                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 565                 return;
 566         }
 567
 568         $dxchan = DXChannel::get($ncall);
 569         if ($dxchan && $dxchan ne $self) {
 570                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 571                 return;
 572         }
 573
 574         unless ($dxchan) {
 575                 if ($parent->via_pc92) {
 576                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 577                         return;
 578                 }
 579         }
 580
 581         if (DXChannel::get($ucall)) {
 582                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 583                 return;
 584         }
 585
 586         # input filter if required and then remove user if present
 587 #               return unless $self->in_filter_route($parent);
 588         $parent->del_user($uref);
 589
 590         # send info to all logged in thingies
 591         my $user = DXUser::get_current($ncall);
 592         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 593         $self->tell_buddies('logoutb', $ucall, $ncall);
 594
 595         if (eph_dup($line)) {
 596                 return;
 597         }
 598
 599         $self->route_pc17($origin, $line, $parent, $uref);
 600 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 601 }
 602
 603 # link request
 604 sub handle_18
 605 {
 606         my $self = shift;
 607         my $pcno = shift;
 608         my $line = shift;
 609         my $origin = shift;
 610         my $pc = shift;
 611
 612         $self->state('init');
 613
 614         my $parent = Route::Node::get($self->{call});
 615
 616         # record the type and version offered
 617         if (my ($version) = $pc->[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 618                 $self->{version} = 53 + $version;
 619                 $self->user->version(53 + $version);
 620                 $parent->version(0 + $version);
 621                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 622                 $self->{build} = 0 + $build;
 623                 $self->user->build(0 + $build);
 624                 $parent->build(0 + $build);
 625                 dbg("DXSpider version $version build $build");
 626                 unless ($self->is_spider) {
 627                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 628                         $self->user->sort('S');
 629                         $self->user->put;
 630                         $self->sort('S');
 631                 }
 632 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 633         } else {
 634                 dbg("Unknown software");
 635                 $self->version(50.0);
 636                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 637                 $self->user->version($self->version);
 638         }
 639
 640         if ($pc->[1] =~ /\bpc9x/) {
 641                 if ($self->{isolate}) {
 642                         dbg("pc9x recognised, but $self->{call} is isolated, using old protocol");
 643                 } elsif (!$self->user->wantpc9x) {
 644                         dbg("pc9x explicitly switched off on $self->{call}, using old protocol");
 645                 } else {
 646                         $self->{do_pc9x} = 1;
 647                         dbg("Do px9x set on $self->{call}");
 648                 }
 649         }
 650
 651         # first clear out any nodes on this dxchannel
 652         my @rout = $parent->del_nodes;
 653         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 654         $self->send_local_config();
 655         $self->send(pc20());
 656 }
 657
 658 sub check_add_node
 659 {
 660         my $call = shift;
 661
 662         # add this station to the user database, if required (don't remove SSID from nodes)
 663         my $user = DXUser::get_current($call);
 664         if (!$user) {
 665                 $user = DXUser->new($call);
 666                 $user->priv(1);         # I have relented and defaulted nodes
 667                 $user->lockout(1);
 668                 $user->homenode($call);
 669                 $user->node($call);
 670                 $user->sort('A');
 671         }
 672         return $user;
 673 }
 674
 675 # incoming cluster list
 676 sub handle_19
 677 {
 678         my $self = shift;
 679         my $pcno = shift;
 680         my $line = shift;
 681         my $origin = shift;
 682         my $pc = shift;
 683
 684         my $i;
 685         my $newline = "PC19^";
 686
 687         # new routing list
 688         my (@rout, @pc92out);
 689
 690         # first get the INTERFACE node
 691         my $parent = Route::Node::get($self->{call});
 692         unless ($parent) {
 693                 dbg("PCPROT: my parent $self->{call} has disappeared");
 694                 $self->disconnect;
 695                 return;
 696         }
 697
 698         my $h;
 699
 700         # parse the PC19
 701         #
 702         # We are making a major change from now on. We are only going to accept
 703         # PC19s from directly connected nodes.  This means that we are probably
 704         # going to throw away most of the data that we are being sent.
 705         #
 706         # The justification for this is that most of it is wrong or out of date
 707         # anyway.
 708         #
 709         # From now on we are only going to believe PC92 data and locally connected
 710         # non-pc92 nodes.
 711         #
 712         for ($i = 1; $i < $#$pc-1; $i += 4) {
 713                 my $here = $pc->[$i];
 714                 my $call = uc $pc->[$i+1];
 715                 my $conf = $pc->[$i+2];
 716                 my $ver = $pc->[$i+3];
 717                 next unless defined $here && defined $conf && is_callsign($call);
 718
 719                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 720
 721                 # check for sane parameters
 722                 #                               $ver = 5000 if $ver eq '0000';
 723                 next unless $ver && $ver =~ /^\d+$/;
 724                 next if $ver < 5000;    # only works with version 5 software
 725                 next if length $call < 3; # min 3 letter callsigns
 726                 next if $call eq $main::mycall || $call eq $main::myalias;
 727
 728                 # check that this PC19 isn't trying to alter the wrong dxchan
 729                 $h = 0;
 730                 my $dxchan = DXChannel::get($call);
 731                 if ($dxchan) {
 732                         if ($dxchan == $self) {
 733                                 $h = 1;
 734                         } else {
 735                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 736                                 next;
 737                         }
 738                 }
 739
 740                 # isolate now means only accept stuff from this call only
 741                 if ($self->{isolate} && $call ne $self->{call}) {
 742                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 743                         next;
 744                 }
 745
 746                 my $user = check_add_node($call);
 747
 748 #               if (eph_dup($genline)) {
 749 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 750 #                       next;
 751 #               }
 752
 753
 754                 unless ($h) {
 755                         if ($parent->via_pc92) {
 756                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 757                                 next;
 758                         }
 759                 }
 760
 761                 my $r = Route::Node::get($call);
 762                 my $flags = Route::here($here)|Route::conf($conf);
 763
 764                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 765                 if ($r) {
 766                         my $ar;
 767                         if ($call ne $parent->call) {
 768                                 if ($self->in_filter_route($r)) {
 769                                         $ar = $parent->add($call, $ver, $flags);
 770 #                                       push @rout, $ar if $ar;
 771                                 } else {
 772                                         next;
 773                                 }
 774                         }
 775                         if ($r->version ne $ver || $r->flags != $flags) {
 776                                 $r->version($ver);
 777                                 $r->flags($flags);
 778                         }
 779                         push @rout, $r;
 780                 } else {
 781                         if ($call eq $self->{call} || $user->wantroutepc19) {
 782                                 my $new = Route->new($call); # throw away
 783                                 if ($self->in_filter_route($new)) {
 784                                         my $ar = $parent->add($call, $ver, $flags);
 785                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 786                                         push @rout, $ar if $ar;
 787                                         push @pc92out, $r if $h;
 788                                 } else {
 789                                         next;
 790                                 }
 791                         }
 792                 }
 793
 794                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 795                 my $mref = DXMsg::get_busy($call);
 796                 $mref->stop_msg($call) if $mref;
 797
 798                 $user->lastin($main::systime) unless DXChannel::get($call);
 799                 $user->put;
 800         }
 801
 802         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 803         # but remember there will only be one (pair) these because any extras will be
 804         # thrown away.
 805         if (@rout) {
 806 #               $self->route_pc21($self->{call}, $line, @rout);
 807                 $self->route_pc19($self->{call}, $line, @rout);
 808         }
 809         if (@pc92out && !$pc92_slug_changes) {
 810                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 811         }
 812 }
 813
 814 # send local configuration
 815 sub handle_20
 816 {
 817         my $self = shift;
 818         my $pcno = shift;
 819         my $line = shift;
 820         my $origin = shift;
 821         my $pc = shift;
 822
 823         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 824                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 825                 $self->{do_pc9x} = 0;
 826         }
 827         $self->send_local_config;
 828         $self->send(pc22());
 829         $self->state('normal');
 830         $self->{lastping} = 0;
 831         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 832 }
 833
 834 # delete a cluster from the list
 835 #
 836 # This should never occur for directly connected nodes.
 837 #
 838 sub handle_21
 839 {
 840         my $self = shift;
 841         my $pcno = shift;
 842         my $line = shift;
 843         my $origin = shift;
 844         my $pc = shift;
 845
 846         my $call = uc $pc->[1];
 847
 848         eph_del_regex("^PC1[679].*$call");
 849
 850         # if I get a PC21 from the same callsign as self then ignore it
 851         if ($call eq $self->{call}) {
 852                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 853                 return;
 854         }
 855
 856         # for the above reason and also because of the check for PC21s coming
 857         # in for self->call from outside being ignored further down
 858         # we don't need any isolation code here, because we will never
 859         # act on a PC21 with self->call in it.
 860
 861         my $parent = Route::Node::get($self->{call});
 862         unless ($parent) {
 863                 dbg("PCPROT: my parent $self->{call} has disappeared");
 864                 $self->disconnect;
 865                 return;
 866         }
 867
 868         my @rout;
 869
 870         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
 871                 my $node = Route::Node::get($call);
 872                 if ($node) {
 873
 874                         if ($node->via_pc92) {
 875                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 876                                 return;
 877                         }
 878
 879                         my $dxchan = DXChannel::get($call);
 880                         if ($dxchan && $dxchan != $self) {
 881                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
 882                                 return;
 883                         }
 884
 885                         # input filter it
 886                         return unless $self->in_filter_route($node);
 887
 888                         # routing objects, force a PC21 if it is local
 889                         push @rout, $node->del($parent);
 890                         push @rout, $call if $dxchan && @rout == 0;
 891                 }
 892         } else {
 893                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
 894                 return;
 895         }
 896
 897         if (eph_dup($line)) {
 898                 return;
 899         }
 900
 901         if (@rout) {
 902                 $self->route_pc21($origin, $line, @rout);
 903 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 904         }
 905 }
 906
 907
 908 sub handle_22
 909 {
 910         my $self = shift;
 911         my $pcno = shift;
 912         my $line = shift;
 913         my $origin = shift;
 914         my $pc = shift;
 915
 916         if ($self->{do_pc9x}) {
 917                 if ($self->{state} ne 'init92') {
 918                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 919                         $self->{do_pc9x} = 0;
 920                 }
 921         }
 922         $self->{lastping} = 0;
 923         $self->state('normal');
 924         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 925 }
 926
 927 # WWV info
 928 sub handle_23
 929 {
 930         my $self = shift;
 931         my $pcno = shift;
 932         my $line = shift;
 933         my $origin = shift;
 934         my $pc = shift;
 935
 936         # route foreign' pc27s
 937         if ($pcno == 27) {
 938                 if ($pc->[8] ne $main::mycall) {
 939                         $self->route($pc->[8], $line);
 940                         return;
 941                 }
 942         }
 943
 944
 945         # do some de-duping
 946         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
 947         my $sfi = unpad($pc->[3]);
 948         my $k = unpad($pc->[4]);
 949         my $i = unpad($pc->[5]);
 950         my ($r) = $pc->[6] =~ /R=(\d+)/;
 951         $r = 0 unless $r;
 952         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
 953                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
 954                 return;
 955         }
 956
 957         # global wwv filtering on INPUT
 958         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
 959         if ($self->{inwwvfilter}) {
 960                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
 961                 unless ($filter) {
 962                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 963                         return;
 964                 }
 965         }
 966         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
 967         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
 968                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 969                 return;
 970         }
 971
 972         # note this only takes the first one it gets
 973         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 974         dbg("WWV: $d $pc->[2], sfi:$sfi k:$k info:$i $pc->[6] $pc->[7] $pc->[8] $r") if isdbg('progress');
 975
 976         if (defined &Local::wwv) {
 977                 my $rep;
 978                 eval {
 979                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 980                 };
 981                 return if $rep;
 982         }
 983
 984         # DON'T be silly and send on PC27s!
 985         return if $pcno == 27;
 986
 987         # broadcast to the eager world
 988         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
 989 }
 990
 991 # set here status
 992 sub handle_24
 993 {
 994         my $self = shift;
 995         my $pcno = shift;
 996         my $line = shift;
 997         my $origin = shift;
 998         my $pc = shift;
 999
1000         my $call = uc $pc->[1];
1001         my ($nref, $uref);
1002         $nref = Route::Node::get($call);
1003         $uref = Route::User::get($call);
1004         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1005
1006         if (eph_dup($line)) {
1007                 return;
1008         }
1009
1010         $nref->here($pc->[2]) if $nref;
1011         $uref->here($pc->[2]) if $uref;
1012         my $ref = $nref || $uref;
1013         return unless $self->in_filter_route($ref);
1014
1015         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1016 }
1017
1018 # merge request
1019 sub handle_25
1020 {
1021         my $self = shift;
1022         my $pcno = shift;
1023         my $line = shift;
1024         my $origin = shift;
1025         my $pc = shift;
1026
1027         if ($pc->[1] ne $main::mycall) {
1028                 $self->route($pc->[1], $line);
1029                 return;
1030         }
1031         if ($pc->[2] eq $main::mycall) {
1032                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1033                 return;
1034         }
1035
1036         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1037
1038         # spots
1039         if ($pc->[3] > 0) {
1040                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1041                 my $in;
1042                 foreach $in (@in) {
1043                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1044                 }
1045         }
1046
1047         # wwv
1048         if ($pc->[4] > 0) {
1049                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1050                 my $in;
1051                 foreach $in (@in) {
1052                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1053                 }
1054         }
1055 }
1056
1057 sub handle_26 {goto &handle_11}
1058 sub handle_27 {goto &handle_23}
1059
1060 # mail/file handling
1061 sub handle_28
1062 {
1063         my $self = shift;
1064         my $pcno = shift;
1065         my $line = shift;
1066         my $origin = shift;
1067         my $pc = shift;
1068
1069         if ($pc->[1] eq $main::mycall) {
1070                 no strict 'refs';
1071                 my $sub = "DXMsg::handle_$pcno";
1072                 &$sub($self, @$pc);
1073         } else {
1074                 $self->route($pc->[1], $line) unless $self->is_clx;
1075         }
1076 }
1077
1078 sub handle_29 {goto &handle_28}
1079 sub handle_30 {goto &handle_28}
1080 sub handle_31 {goto &handle_28}
1081 sub handle_32 {goto &handle_28}
1082 sub handle_33 {goto &handle_28}
1083
1084 sub handle_34
1085 {
1086         my $self = shift;
1087         my $pcno = shift;
1088         my $line = shift;
1089         my $origin = shift;
1090         my $pc = shift;
1091
1092         if (eph_dup($line, $eph_pc34_restime)) {
1093                 return;
1094         } else {
1095                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1096         }
1097 }
1098
1099 # remote command replies
1100 sub handle_35
1101 {
1102         my $self = shift;
1103         my $pcno = shift;
1104         my $line = shift;
1105         my $origin = shift;
1106         my $pc = shift;
1107
1108         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1109         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1110 }
1111
1112 sub handle_36 {goto &handle_34}
1113
1114 # database stuff
1115 sub handle_37
1116 {
1117         my $self = shift;
1118         my $pcno = shift;
1119         my $line = shift;
1120         my $origin = shift;
1121         my $pc = shift;
1122
1123         if ($pc->[1] eq $main::mycall) {
1124                 no strict 'refs';
1125                 my $sub = "DXDb::handle_$pcno";
1126                 &$sub($self, @$pc);
1127         } else {
1128                 $self->route($pc->[1], $line) unless $self->is_clx;
1129         }
1130 }
1131
1132 # node connected list from neighbour
1133 sub handle_38
1134 {
1135         my $self = shift;
1136         my $pcno = shift;
1137         my $line = shift;
1138         my $origin = shift;
1139         my $pc = shift;
1140 }
1141
1142 # incoming disconnect
1143 sub handle_39
1144 {
1145         my $self = shift;
1146         my $pcno = shift;
1147         my $line = shift;
1148         my $origin = shift;
1149         my $pc = shift;
1150
1151         if ($pc->[1] eq $self->{call}) {
1152                 $self->disconnect(1);
1153         } else {
1154                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1155         }
1156 }
1157
1158 sub handle_40 {goto &handle_28}
1159
1160 # user info
1161 sub handle_41
1162 {
1163         my $self = shift;
1164         my $pcno = shift;
1165         my $line = shift;
1166         my $origin = shift;
1167         my $pc = shift;
1168
1169         my $call = $pc->[1];
1170         my $sort = $pc->[2];
1171         my $val = $pc->[3];
1172
1173         my $l = "PC41^$call^$sort";
1174         if (eph_dup($l, $eph_info_restime)) {
1175                 return;
1176         }
1177
1178         # input filter if required
1179         #                       my $ref = Route::get($call) || Route->new($call);
1180         #                       return unless $self->in_filter_route($ref);
1181
1182         if ($val eq $sort || $val =~ /^\s*$/) {
1183                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1184                 return;
1185         }
1186
1187         if ($call eq $main::mycall || $call eq $main::myalias) {
1188                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1189                 return;
1190         }
1191         my $chan = DXChannel::get($call);
1192         if ($chan) {
1193                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1194                 return;
1195         }
1196
1197         # add this station to the user database, if required
1198         my $user = DXUser::get_current($call);
1199         $user = DXUser->new($call) unless $user;
1200
1201         if ($sort == 1) {
1202                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1203                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1204                         return;
1205                 }
1206                 $user->name($val);
1207         } elsif ($sort == 2) {
1208                 $user->qth($val);
1209         } elsif ($sort == 3) {
1210                 if (is_latlong($val)) {
1211                         my ($lat, $long) = DXBearing::stoll($val);
1212                         $user->lat($lat) if $lat;
1213                         $user->long($long) if $long;
1214                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1215                 } else {
1216                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1217                         return;
1218                 }
1219         } elsif ($sort == 4) {
1220                 $user->homenode($val);
1221         } elsif ($sort == 5) {
1222                 if (is_qra(uc $val)) {
1223                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1224                         $user->lat($lat) if $lat && !$user->lat;
1225                         $user->long($long) if $long && !$user->long;
1226                         $user->qra(uc $val);
1227                 } else {
1228                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1229                         return;
1230                 }
1231         }
1232         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1233         $user->put;
1234
1235         unless ($self->{isolate}) {
1236                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1237         }
1238
1239         #  perhaps this IS what we want after all
1240         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1241 }
1242
1243 sub handle_42 {goto &handle_28}
1244
1245
1246 # database
1247 sub handle_44 {goto &handle_37}
1248 sub handle_45 {goto &handle_37}
1249 sub handle_46 {goto &handle_37}
1250 sub handle_47 {goto &handle_37}
1251 sub handle_48 {goto &handle_37}
1252
1253 # message and database
1254 sub handle_49
1255 {
1256         my $self = shift;
1257         my $pcno = shift;
1258         my $line = shift;
1259         my $origin = shift;
1260         my $pc = shift;
1261
1262         if (eph_dup($line)) {
1263                 return;
1264         }
1265
1266         if ($pc->[1] eq $main::mycall) {
1267                 DXMsg::handle_49($self, @$pc);
1268         } else {
1269                 $self->route($pc->[1], $line) unless $self->is_clx;
1270         }
1271 }
1272
1273 # keep alive/user list
1274 sub handle_50
1275 {
1276         my $self = shift;
1277         my $pcno = shift;
1278         my $line = shift;
1279         my $origin = shift;
1280         my $pc = shift;
1281
1282         return if (eph_dup($line));
1283
1284         my $call = $pc->[1];
1285
1286         my $node = Route::Node::get($call);
1287         if ($node) {
1288                 return unless $node->call eq $self->{call};
1289                 $node->usercount($pc->[2]) unless $node->users;
1290                 $node->reset_obs;
1291                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1292
1293                 # input filter if required
1294 #               return unless $self->in_filter_route($node);
1295
1296                 unless ($self->{isolate}) {
1297                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1298                 }
1299 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1300         }
1301 }
1302
1303 # incoming ping requests/answers
1304 sub handle_51
1305 {
1306         my $self = shift;
1307         my $pcno = shift;
1308         my $line = shift;
1309         my $origin = shift;
1310         my $pc = shift;
1311
1312         my $to = $pc->[1];
1313         my $from = $pc->[2];
1314         my $flag = $pc->[3];
1315
1316         if ($to eq $main::myalias) {
1317                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1318                 return;
1319         }
1320
1321         # is it for us?
1322         if ($to eq $main::mycall) {
1323                 if ($flag == 1) {
1324                         $self->send(pc51($from, $to, '0'));
1325                 } else {
1326                         DXXml::Ping::handle_ping_reply($self, $from);
1327                 }
1328         } else {
1329                 if (eph_dup($line)) {
1330                         return;
1331                 }
1332                 # route down an appropriate thingy
1333                 $self->route($to, $line);
1334         }
1335 }
1336
1337 sub handle_61 { goto &handle_11; }
1338
1339 # dunno but route it
1340 sub handle_75
1341 {
1342         my $self = shift;
1343         my $pcno = shift;
1344         my $line = shift;
1345         my $origin = shift;
1346         my $pc = shift;
1347
1348         my $call = $pc->[1];
1349         if ($call ne $main::mycall) {
1350                 $self->route($call, $line);
1351         }
1352 }
1353
1354 # WCY broadcasts
1355 sub handle_73
1356 {
1357         my $self = shift;
1358         my $pcno = shift;
1359         my $line = shift;
1360         my $origin = shift;
1361         my $pc = shift;
1362
1363         my $call = $pc->[1];
1364
1365         # do some de-duping
1366         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1367         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1368                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1369                 return;
1370         }
1371         $pc = [ map { unpad($_) } @$pc ];
1372         if (WCY::dup($d)) {
1373                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1374                 return;
1375         }
1376
1377         my $wcy = WCY::update($d, @$pc[2..12]);
1378         dbg("WCY: " . join ', ', @$pc[2..12]) if isdbg('progress');
1379
1380         if (defined &Local::wcy) {
1381                 my $rep;
1382                 eval {
1383                         $rep = Local::wcy($self, @$pc[1..12]);
1384                 };
1385                 return if $rep;
1386         }
1387
1388         # broadcast to the eager world
1389         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1390 }
1391
1392 # remote commands (incoming)
1393 sub handle_84
1394 {
1395         my $self = shift;
1396         my $pcno = shift;
1397         my $line = shift;
1398         my $origin = shift;
1399         my $pc = shift;
1400
1401         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1402 }
1403
1404 # remote command replies
1405 sub handle_85
1406 {
1407         my $self = shift;
1408         my $pcno = shift;
1409         my $line = shift;
1410         my $origin = shift;
1411         my $pc = shift;
1412
1413         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1414 }
1415
1416 # decode a pc92 call: flag call : version : build
1417 sub _decode_pc92_call
1418 {
1419         my $icall = shift;
1420         my @part = split /:/, $icall;
1421         my ($flag, $call) = unpack "A A*", $part[0];
1422         unless (defined $flag && $flag ge '0' && $flag le '7') {
1423                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1424                 return ();
1425         }
1426         unless ($call && is_callsign($call)) {
1427                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1428                 return ();
1429         }
1430         my $is_node = $flag & 4;
1431         my $is_extnode = $flag & 2;
1432         my $here = $flag & 1;
1433         my $ip  = $part[3];
1434         $ip ||= $part[1] if $part[1] && ($part[1] =~ /^(?:\d+\.)+/ || $part[1] =~ /^(?:(?:[abcdef\d]+)?,)+/);
1435         $ip =~ s/,/:/g if $ip;
1436         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2], $ip);
1437 }
1438
1439 # decode a pc92 call: flag call : version : build
1440 sub _encode_pc92_call
1441 {
1442         my $ref = shift;
1443
1444         # plain call or value
1445         return $ref unless ref $ref;
1446
1447         my $ext = shift || 0;
1448         my $flag = 0;
1449         my $call = $ref->call;
1450         my $extra = '';
1451         $flag |= $ref->here ? 1 : 0;
1452         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1453                 $flag |= 4;
1454                 my $dxchan = DXChannel::get($call);
1455                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1456                 if (($ext & 1) && $ref->version) {
1457                         my $version = $ref->version || 1.0;
1458                         $version =  $version * 100 + 5300 if $version < 50;
1459                         $extra .= ":" . $version;
1460                 }
1461         }
1462         if (($ext & 2) && $ref->ip) {
1463                 my $ip = $ref->ip;
1464                 $ip =~ s/:/,/g;
1465                 $extra .= ':' . $ip;
1466         }
1467         return "$flag$call$extra";
1468 }
1469
1470 my %things_add;
1471 my %things_del;
1472
1473 sub _add_thingy
1474 {
1475         my $parent = shift;
1476         my $s = shift;
1477         my $dxchan = shift;
1478         my $hops = shift;
1479
1480         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1481         my @rout;
1482
1483         if ($call) {
1484                 my $ncall = $parent->call;
1485                 if ($is_node) {
1486                         dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1487                         @rout = $parent->add($call, $version, Route::here($here), $ip);
1488                         my $r = Route::Node::get($call);
1489                         $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1490                         if ($ip) {
1491                                 $r->ip($ip);
1492                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1493                         }
1494                 } else {
1495                         dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1496                         @rout = $parent->add_user($call, Route::here($here), $ip);
1497                         $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1498                         my $r = Route::User::get($call);
1499                         if ($ip) {
1500                                 $r->ip($ip);
1501                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1502                         }
1503                 }
1504                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1505                         $things_add{$call} = Route::get($call);
1506                         delete $things_del{$call};
1507                 }
1508         }
1509         return @rout;
1510 }
1511
1512 sub _del_thingy
1513 {
1514         my $parent = shift;
1515         my $s = shift;
1516         my $dxchan = shift;
1517         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1518         my @rout;
1519         if ($call) {
1520                 my $ref;
1521                 if ($is_node) {
1522                         $ref = Route::Node::get($call);
1523                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1524                         @rout = $ref->del($parent) if $ref;
1525                 } else {
1526                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1527                         $ref = Route::User::get($call);
1528                         if ($ref) {
1529                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1530                                 @rout = $parent->del_user($ref);
1531                         }
1532                 }
1533                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1534                         $things_del{$call} = $ref unless exists $things_add{$call};
1535                         delete $things_add{$call};
1536                 }
1537         }
1538         return @rout;
1539 }
1540
1541 # this will only happen if we are slugging changes and
1542 # there are some changes to be sent, it will create an add or a delete
1543 # or both
1544 sub gen_pc92_changes
1545 {
1546         my @add = values %things_add;
1547         my @del = values %things_del;
1548         return (\@add, \@del);
1549 }
1550
1551 sub clear_pc92_changes
1552 {
1553         %things_add = %things_del = ();
1554         $last_pc92_slug = $main::systime;
1555 }
1556
1557 my $_last_time;
1558 my $_last_occurs;
1559 my $_last_pc9x_id;
1560
1561 sub last_pc9x_id
1562 {
1563         return $_last_pc9x_id;
1564 }
1565
1566 sub gen_pc9x_t
1567 {
1568         if (!$_last_time || $_last_time != $main::systime) {
1569                 $_last_time = $main::systime;
1570                 $_last_occurs = 0;
1571                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1572         } else {
1573                 $_last_occurs++;
1574                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1575         }
1576 }
1577
1578 sub check_pc9x_t
1579 {
1580         my $call = shift;
1581         my $t = shift;
1582         my $pc = shift;
1583         my $create = shift;
1584
1585         # check that the time is between 0 >= $t < 86400
1586         unless ($t >= 0 && $t < 86400) {
1587                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1588                 return undef;
1589         }
1590
1591         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1592         my $now = $main::systime - $main::systime_daystart ;
1593         my $diff = abs($now - $t);
1594         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1595                 my $c = ref $call ? $call->call : $call;
1596                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1597                 return undef;
1598         }
1599
1600         my $parent = ref $call ? $call : Route::Node::get($call);
1601         if ($parent) {
1602                 # we only do this for external calls whose routing table
1603                 # record come and go. The reference for mycall is permanent
1604                 # and not that frequently used, it also never times out, so
1605                 # the id on it is completely unreliable. Besides, only commands
1606                 # originating on this box will go through this code...
1607                 if ($parent->call ne $main::mycall) {
1608                         my $lastid = $parent->lastid;
1609                         if (defined $lastid) {
1610                                 if ($t < $lastid) {
1611                                         # note that this is where we determine whether this pc9x has come in yesterday
1612                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1613                                         # duplicate sentence. To determine this we need to do some module 86400
1614                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1615                                         # low numbers that it is a new sentence.
1616                                         #
1617                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1618                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1619                                         # 86378 respectively in the calculation below).
1620                                         #
1621                                         if ($t+86400-$lastid > $pc9x_past_age) {
1622                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1623                                                 return undef;
1624                                         }
1625                                 } elsif ($t == $lastid) {
1626                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1627                                         return undef;
1628                                 } else {
1629                                         # check that if we have a low number in lastid that yesterday's numbers
1630                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1631                                         if ($lastid+86400-$t < $pc9x_past_age) {
1632                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1633                                                 return undef;
1634                                         }
1635                                 }
1636                         }
1637                 }
1638         } elsif ($create) {
1639                 $parent = Route::Node->new($call);
1640         } else {
1641                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1642                 return undef;
1643         }
1644         if (isdbg('pc92dedupe')) {
1645                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1646                 my $val = $parent->{lastid};
1647                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1648                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1649         }
1650         $parent->lastid($t);
1651
1652         return $parent;
1653 }
1654
1655 sub pc92_handle_first_slot
1656 {
1657         my $self = shift;
1658         my $slot = shift;
1659         my $parent = shift;
1660         my $t = shift;
1661         my $hops = shift;
1662         my $oparent = $parent;
1663
1664         my @radd;
1665
1666         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1667         if ($call && $is_node) {
1668                 if ($call eq $main::mycall) {
1669                         dbg("PCPROT: $call looped back onto \$main::mycall ($main::mycall), ignored") if isdbg('chan');
1670                         return;
1671                 }
1672                 if ($call eq $main::myalias) {
1673                         dbg("PCPROT: $call looped back onto \$main::myalias ($main::myalias), ignored") if isdbg('chan');
1674                         return;
1675                 }
1676                 # this is only accepted from my "self".
1677                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1678                 # locally connected. Local nodes always take precedence. But we remember the lastid
1679                 # to try to reduce the number of dupe PC92s for this external node.
1680                 if (DXChannel::get($call) && $call ne $self->{call}) {
1681                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1682                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1683                         return;
1684                 }
1685                 if ($is_extnode) {
1686                         # reparent to external node (note that we must have received a 'C' or 'A' record
1687                         # from the true parent node for this external before we get one for the this node
1688                         unless ($parent = Route::Node::get($call)) {
1689                                 if ($is_extnode && $oparent) {
1690                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
1691                                         $parent = $radd[0];
1692                                 } else {
1693                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1694                                         return;
1695                                 }
1696                         }
1697                         $parent = check_pc9x_t($call, $t, 92) || return;
1698                         $parent->via_pc92(1);
1699                         $parent->PC92C_dxchan($self->{call}, $hops);
1700                 }
1701         } else {
1702                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1703                 return;
1704         }
1705         $parent->here(Route::here($here));
1706         $parent->version($version || $pc19_version) if $version;
1707         $parent->build($build) if $build;
1708         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1709         return ($parent, @radd);
1710 }
1711
1712 # DXSpider routing entries
1713 sub handle_92
1714 {
1715         my $self = shift;
1716         my $pcno = shift;
1717         my $line = shift;
1718         my $origin = shift;
1719         my $pc = shift;
1720
1721         my (@radd, @rdel);
1722
1723         my $pcall = $pc->[1];
1724         my $t = $pc->[2];
1725         my $sort = $pc->[3];
1726         my $hops = $pc->[-1];
1727
1728         # this catches loops of A/Ds
1729 #       if (eph_dup($line, $pc9x_dupe_age)) {
1730 #               return;
1731 #       }
1732
1733         if ($pcall eq $main::mycall) {
1734                 dbg("PCPROT: looped back, ignored") if isdbg('chan');
1735                 return;
1736         }
1737
1738         if ($pcall eq $main::myalias) {
1739                 dbg("PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored") if isdbg('chan');
1740                 return;
1741         }
1742
1743         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1744                 if ($self->{isolate}) {
1745                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
1746                         return;
1747                 } elsif (!$self->user->wantpc9x) {
1748                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
1749                         return;
1750                 } else {
1751                         $self->state('init92');
1752                         $self->{do_pc9x} = 1;
1753                         dbg("DXPROT: Do pc9x set on $pcall");
1754                 }
1755         }
1756         unless ($self->{do_pc9x}) {
1757                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1758                 return;
1759         }
1760
1761         # don't create routing entries for D records that don't already exist
1762         # this is what causes all those PC92 loops!
1763         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1764         my $oparent = $parent;
1765
1766         $parent->do_pc9x(1);
1767         $parent->via_pc92(1);
1768
1769         if ($sort eq 'F' || $sort eq 'R') {
1770
1771                 # this is the route finding section
1772                 # here is where the consequences of the 'find' command
1773                 # are dealt with
1774
1775                 my $from = $pc->[4];
1776                 my $target = $pc->[5];
1777
1778                 if ($sort eq 'F') {
1779                         my $flag;
1780                         my $ref;
1781                         my $dxchan;
1782                         if ($ref = DXChannel::get($target)) {
1783                                 $flag = 1;              # we are directly connected
1784                         } else {
1785                                 $ref = Route::get($target);
1786                                 $dxchan = $ref->dxchan;
1787                                 $flag = 2;
1788                         }
1789                         if ($ref && $flag && $dxchan) {
1790                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1791                                 return;
1792                         }
1793                 } elsif ($sort eq 'R') {
1794                         if (my $dxchan = DXChannel::get($from)) {
1795                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
1796                         } else {
1797                                 my $ref = Route::get($from);
1798                                 if ($ref) {
1799                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1800                                         if (@dxchan) {
1801                                                 $_->send($line) for @dxchan;
1802                                         } else {
1803                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1804                                         }
1805                                 } else {
1806                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1807                                 }
1808                         }
1809                         return;
1810                 }
1811
1812         } elsif ($sort eq 'K') {
1813                 $pc92Kin += length $line;
1814
1815                 # remember the last channel we arrived on
1816                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1817
1818                 my @ent = _decode_pc92_call($pc->[4]);
1819
1820                 if (@ent) {
1821                         my $add;
1822
1823                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
1824                         return unless $parent; # dupe
1825
1826                         push @radd, $add if $add;
1827                         $parent->reset_obs;
1828                         $parent->version($ent[4]) if $ent[4];
1829                         $parent->build($ent[5]) if $ent[5];
1830
1831                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1832                 }
1833         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1834
1835                 $pc92Ain += length $line if $sort eq 'A';
1836                 $pc92Cin += length $line if $sort eq 'C';
1837                 $pc92Din += length $line if $sort eq 'D';
1838
1839                 # remember the last channel we arrived on
1840                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1841
1842                 # this is the main route section
1843                 # here is where all the routes are created and destroyed
1844
1845                 # cope with missing duplicate node calls in the first slot
1846                 my $me = $pc->[4] || '';
1847                 $me ||= _encode_pc92_call($parent) unless $me ;
1848
1849                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
1850
1851                 if (@ent) {
1852
1853                         # look at the first one which will always be a node of some sort
1854                         # except in the case of 'A' or 'D' in which the $pcall is used
1855                         # otherwise use the node call and update any information
1856                         # that needs to be done.
1857                         my $add;
1858
1859                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
1860                         return unless $parent; # dupe
1861
1862                         shift @ent;
1863                         push @radd, $add if $add;
1864                 }
1865
1866                 # do a pass through removing any references to either mycall
1867                 my @nent;
1868                 for (@ent) {
1869                         my $dxc;
1870                         next unless $_ && @$_;
1871                         if ($_->[0] eq $main::mycall) {
1872                                 dbg("PCPROT: $_->[0] refers to me, ignored") if isdbg('chanerr');
1873                                 next;
1874                         }
1875                         push @nent, $_;
1876                 }
1877
1878                 if ($sort eq 'A') {
1879                         for (@nent) {
1880                                 push @radd, _add_thingy($parent, $_, $self, $hops);
1881                         }
1882                 } elsif ($sort eq 'D') {
1883                         for (@nent) {
1884                                 push @rdel, _del_thingy($parent, $_, $self);
1885                         }
1886                 } elsif ($sort eq 'C') {
1887                         my (@nodes, @users);
1888
1889                         # we reset obscounts on config records as well as K records
1890                         $parent->reset_obs;
1891                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1892
1893                         #
1894                         foreach my $r (@nent) {
1895                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1896                                 if ($r->[0]) {
1897                                         if ($r->[1]) {
1898                                                 push @nodes, $r->[0];
1899                                         } else {
1900                                                 push @users, $r->[0];
1901                                         }
1902                                 } else {
1903                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1904                                 }
1905                         }
1906
1907                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1908
1909                         # add users here
1910                         foreach my $r (@nent) {
1911                                 my $call = $r->[0];
1912                                 if ($call) {
1913                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
1914                                 }
1915                         }
1916                         # del users here
1917                         foreach my $r (@$dnodes) {
1918                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
1919                         }
1920                         foreach my $r (@$dusers) {
1921                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
1922                         }
1923
1924                         # remember this last PC92C for rebroadcast on demand
1925                         $parent->last_PC92C($line);
1926                 } else {
1927                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1928                         return;
1929                 }
1930
1931                 foreach my $r (@rdel) {
1932                         next unless $r;
1933
1934                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1935                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1936                 }
1937                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1938                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1939                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1940                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1941                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1942         }
1943
1944         # broadcast it if we get here
1945         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1946 }
1947
1948 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
1949 # might be on two or more nodes at the same time or that there may be more than
1950 # one equal distance neighbour to a node.
1951 #
1952 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
1953 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
1954 # each and then combined to give a set of dxchans to send the PC9x record down
1955 #
1956 sub find_pc9x_routes
1957 {
1958         my $to = shift;
1959         my $ref = Route::get($to);
1960         my @parent;
1961         my %cand;
1962
1963         if ($ref->isa('Route::User')) {
1964                 my $dxchan = DXChannel::get($to);
1965                 push @parent, $to if $dxchan;
1966                 push @parent, $ref->parents;
1967         } else {
1968                 @parent = $to;
1969         }
1970         foreach my $p (@parent) {
1971                 my $lasthops;
1972                 my @routes = Route::findroutes($p);
1973                 foreach my $r (@routes) {
1974                         $lasthops = $r->[0] unless defined $lasthops;
1975                         if ($r->[0] == $lasthops) {
1976                                 $cand{$r->[1]->call} = $r->[1];
1977                         } else {
1978                                 last;
1979                         }
1980                 }
1981         }
1982         return values %cand;
1983 }
1984
1985 sub handle_93
1986 {
1987         my $self = shift;
1988         my $pcno = shift;
1989         my $line = shift;
1990         my $origin = shift;
1991         my $pc = shift;
1992
1993 #       $self->{do_pc9x} ||= 1;
1994
1995         my $pcall = $pc->[1];                   # this is now checked earlier
1996
1997         # remember that we are converting PC10->PC93 and self will be $main::me if it
1998         # comes from us
1999         unless ($self->{do_pc9x}) {
2000                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2001                 return;
2002         }
2003
2004         my $t = $pc->[2];
2005         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2006
2007         my $to = uc $pc->[3];
2008         my $from = uc $pc->[4];
2009         my $via = uc $pc->[5];
2010         my $text = $pc->[6];
2011         my $onode = uc $pc->[7];
2012         $onode = $pcall if @$pc <= 8;
2013
2014         # this is catch loops caused by bad software ...
2015         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2016                 return;
2017         }
2018
2019         if (isdbg('progress')) {
2020                 my $vs = $via ne '*' ? " via $via" : '';
2021                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text'";
2022                 dbg($s);
2023         }
2024
2025         # will we allow it at all?
2026         if ($censorpc) {
2027                 my @bad;
2028                 if (@bad = BadWords::check($text)) {
2029                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
2030                         return;
2031                 }
2032         }
2033
2034         # if this is a 'bad spotter' user then ignore it
2035         my $nossid = $from;
2036         $nossid =~ s/-\d+$//;
2037         if ($badspotter->in($nossid)) {
2038                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
2039                 return;
2040         }
2041
2042         # ignore PC93 coming in from outside this node with a target of local
2043         if ($to eq 'LOCAL' && $self != $main::me) {
2044                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2045                 return;
2046         }
2047
2048         # if it is routeable then then treat it like a talk
2049         my $ref = Route::get($to);
2050         if ($ref) {
2051                 my $dxchan;
2052
2053                 # convert to PC10 or local talks where appropriate
2054                 # PC93 capable nodes of the same hop count all get a copy
2055                 # if there is a PC10 node then it will get a copy and that
2056                 # will be it. Hopefully such a node will not figure highly
2057                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2058                 # note that both local and PC93s at the same time are possible if the
2059                 # user on more than one node.
2060                 my @routes = find_pc9x_routes($to);
2061                 my $lasthops;
2062                 foreach $dxchan (@routes) {
2063                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2064                                 if ($dxchan->{do_pc9x}) {
2065                                         $dxchan->send($line);
2066                                 } else {
2067                                         $dxchan->talk($from, $to, $via, $text, $onode);
2068                                 }
2069                         } else {
2070                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2071                         }
2072                 }
2073                 return;
2074
2075         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2076                 # announces
2077                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2078                 my $wx = $to eq 'WX' ? '1' : '0';
2079                 my $local = $via eq 'LOCAL' ? '*' : $via;
2080
2081                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2082                 return if $via eq 'LOCAL';
2083         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2084                 # chat messages really only locally connected users
2085                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2086         }
2087
2088         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2089         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2090 }
2091
2092 # if get here then rebroadcast the thing with its Hop count decremented (if
2093 # there is one). If it has a hop count and it decrements to zero then don't
2094 # rebroadcast it.
2095 #
2096 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2097 #        REBROADCAST!!!!
2098 #
2099
2100 sub handle_default
2101 {
2102         my $self = shift;
2103         my $pcno = shift;
2104         my $line = shift;
2105         my $origin = shift;
2106         my $pc = shift;
2107
2108         unless (eph_dup($line)) {
2109                 if ($pcno >= 90) {
2110                         my $pcall = $pc->[1];
2111                         unless (is_callsign($pcall)) {
2112                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2113                                 return;
2114                         }
2115                         my $t = $pc->[2];
2116                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2117                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2118                 } else {
2119                         unless ($self->{isolate}) {
2120                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2121                         }
2122                 }
2123         }
2124 }
2125
2126 1;