perl/DXProt.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 # $Id$
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use Time::HiRes qw(gettimeofday tv_interval);
  31 use BadWords;
  32 use DXHash;
  33 use Route;
  34 use Route::Node;
  35 use Script;
  36
  37 use strict;
  38
  39 use vars qw($VERSION $BRANCH);
  40 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  41 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/ ) || 0;
  42 $main::build += $VERSION;
  43 $main::branch += $BRANCH;
  44
  45 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  46                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  47                         %nodehops $baddx $badspotter $badnode $censorpc $rspfcheck
  48                         $allowzero $decode_dk0wcy $send_opernam @checklist);
  49
  50 $pc11_max_age = 1*3600;                 # the maximum age for an incoming 'real-time' pc11
  51 $pc23_max_age = 1*3600;                 # the maximum age for an incoming 'real-time' pc23
  52
  53 $last_hour = time;                              # last time I did an hourly periodic update
  54 %pings = ();                    # outstanding ping requests outbound
  55 %rcmds = ();                    # outstanding rcmd requests outbound
  56 %nodehops = ();                 # node specific hop control
  57 $censorpc = 1;                                  # Do a BadWords::check on text fields and reject things
  58                                                                 # loads of 'bad things'
  59 $baddx = new DXHash "baddx";
  60 $badspotter = new DXHash "badspotter";
  61 $badnode = new DXHash "badnode";
  62 $last10 = $last_pc50 = time;
  63 $ann_to_talk = 1;
  64 $rspfcheck = 1;
  65 $eph_restime = 180;
  66 $eph_info_restime = 60*60;
  67 $eph_pc34_restime = 30;
  68
  69 @checklist =
  70 (
  71  [ qw(c c m bp bc c) ],                 # pc10
  72  [ qw(f m d t m c c h) ],               # pc11
  73  [ qw(c bc m bp bm p h) ],              # pc12
  74  [ qw(c h) ],                                   #
  75  [ qw(c h) ],                                   #
  76  [ qw(c m h) ],                                 #
  77  undef ,                                                # pc16 has to be validated manually
  78  [ qw(c c h) ],                                 # pc17
  79  [ qw(m n) ],                                   # pc18
  80  undef ,                                                # pc19 has to be validated manually
  81  undef ,                                                # pc20 no validation
  82  [ qw(c m h) ],                                 # pc21
  83  undef ,                                                # pc22 no validation
  84  [ qw(d n n n n m c c h) ],             # pc23
  85  [ qw(c p h) ],                                 # pc24
  86  [ qw(c c n n) ],                               # pc25
  87  [ qw(f m d t m c c bc) ],              # pc26
  88  [ qw(d n n n n m c c bc) ],    # pc27
  89  [ qw(c c m c d t p m bp n p bp bc) ], # pc28
  90  [ qw(c c n m) ],                               # pc29
  91  [ qw(c c n) ],                                 # pc30
  92  [ qw(c c n) ],                                 # pc31
  93  [ qw(c c n) ],                                 # pc32
  94  [ qw(c c n) ],                                 # pc33
  95  [ qw(c c m) ],                                 # pc34
  96  [ qw(c c m) ],                                 # pc35
  97  [ qw(c c m) ],                                 # pc36
  98  [ qw(c c n m) ],                               # pc37
  99  undef,                                                 # pc38 not interested
 100  [ qw(c m) ],                                   # pc39
 101  [ qw(c c m p n) ],                             # pc40
 102  [ qw(c n m h) ],                               # pc41
 103  [ qw(c c n) ],                                 # pc42
 104  undef,                                                 # pc43 don't handle it
 105  [ qw(c c n m m c) ],                   # pc44
 106  [ qw(c c n m) ],                               # pc45
 107  [ qw(c c n) ],                                 # pc46
 108  undef,                                                 # pc47
 109  undef,                                                 # pc48
 110  [ qw(c m h) ],                                 # pc49
 111  [ qw(c n h) ],                                 # pc50
 112  [ qw(c c n) ],                                 # pc51
 113  undef,
 114  undef,
 115  undef,
 116  undef,
 117  undef,
 118  undef,
 119  undef,
 120  undef,
 121  undef,                                                 # pc60
 122  undef,
 123  undef,
 124  undef,
 125  undef,
 126  undef,
 127  undef,
 128  undef,
 129  undef,
 130  undef,
 131  undef,                                                 # pc70
 132  undef,
 133  undef,
 134  [ qw(d n n n n n n m m m c c h) ],     # pc73
 135  undef,
 136  undef,
 137  undef,
 138  undef,
 139  undef,
 140  undef,
 141  undef,                                                 # pc80
 142  undef,
 143  undef,
 144  undef,
 145  [ qw(c c c m) ],                               # pc84
 146  [ qw(c c c m) ],                               # pc85
 147 );
 148
 149 # use the entry in the check list to check the field list presented
 150 # return OK if line NOT in check list (for now)
 151 sub check
 152 {
 153         my $n = shift;
 154         $n -= 10;
 155         return 0 if $n < 0 || $n > @checklist;
 156         my $ref = $checklist[$n];
 157         return 0 unless ref $ref;
 158
 159         my $i;
 160         shift;    # not interested in the first field
 161         for ($i = 0; $i < @$ref; $i++) {
 162                 my ($blank, $act) = $$ref[$i] =~ /^(b?)(\w)$/;
 163                 return 0 unless $act;
 164                 next if $blank && $_[$i] =~ /^[ \*]$/;
 165                 if ($act eq 'c') {
 166                         return $i+1 unless is_callsign($_[$i]);
 167                 } elsif ($act eq 'm') {
 168                         return $i+1 unless is_pctext($_[$i]);
 169                 } elsif ($act eq 'p') {
 170                         return $i+1 unless is_pcflag($_[$i]);
 171                 } elsif ($act eq 'f') {
 172                         return $i+1 unless is_freq($_[$i]);
 173                 } elsif ($act eq 'n') {
 174                         return $i+1 unless $_[$i] =~ /^[\d ]+$/;
 175                 } elsif ($act eq 'h') {
 176                         return $i+1 unless $_[$i] =~ /^H\d\d?$/;
 177                 } elsif ($act eq 'd') {
 178                         return $i+1 unless $_[$i] =~ /^\s*\d+-\w\w\w-[12][90]\d\d$/;
 179                 } elsif ($act eq 't') {
 180                         return $i+1 unless $_[$i] =~ /^[012]\d[012345]\dZ$/;
 181                 }
 182         }
 183         return 0;
 184 }
 185
 186 sub init
 187 {
 188         my $user = DXUser->get($main::mycall);
 189         $DXProt::myprot_version += $main::version*100;
 190         $main::me = DXProt->new($main::mycall, 0, $user);
 191         $main::me->{here} = 1;
 192         $main::me->{state} = "indifferent";
 193         do "$main::data/hop_table.pl" if -e "$main::data/hop_table.pl";
 194         confess $@ if $@;
 195         $main::me->{sort} = 'S';    # S for spider
 196         $main::me->{priv} = 9;
 197         $main::me->{metric} = 0;
 198         $main::me->{pingave} = 0;
 199
 200 #       $Route::Node::me->adddxchan($main::me);
 201 }
 202
 203 #
 204 # obtain a new connection this is derived from dxchannel
 205 #
 206
 207 sub new
 208 {
 209         my $self = DXChannel::alloc(@_);
 210
 211         # add this node to the table, the values get filled in later
 212         my $pkg = shift;
 213         my $call = shift;
 214         $main::routeroot->add($call, '5000', Route::here(1)) if $call ne $main::mycall;
 215
 216         return $self;
 217 }
 218
 219 # this is how a pc connection starts (for an incoming connection)
 220 # issue a PC38 followed by a PC18, then wait for a PC20 (remembering
 221 # all the crap that comes between).
 222 sub start
 223 {
 224         my ($self, $line, $sort) = @_;
 225         my $call = $self->{call};
 226         my $user = $self->{user};
 227
 228         # log it
 229         my $host = $self->{conn}->{peerhost} || "unknown";
 230         Log('DXProt', "$call connected from $host");
 231
 232         # remember type of connection
 233         $self->{consort} = $line;
 234         $self->{outbound} = $sort eq 'O';
 235         my $priv = $user->priv;
 236         $priv = $user->priv(1) unless $priv;
 237         $self->{priv} = $priv;     # other clusters can always be 'normal' users
 238         $self->{lang} = $user->lang || 'en';
 239         $self->{isolate} = $user->{isolate};
 240         $self->{consort} = $line;       # save the connection type
 241         $self->{here} = 1;
 242         $self->{width} = 80;
 243
 244         # sort out registration
 245         $self->{registered} = 1;
 246
 247         # get the output filters
 248         $self->{spotsfilter} = Filter::read_in('spots', $call, 0) || Filter::read_in('spots', 'node_default', 0);
 249         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0) || Filter::read_in('wwv', 'node_default', 0);
 250         $self->{wcyfilter} = Filter::read_in('wcy', $call, 0) || Filter::read_in('wcy', 'node_default', 0);
 251         $self->{annfilter} = Filter::read_in('ann', $call, 0) || Filter::read_in('ann', 'node_default', 0) ;
 252         $self->{routefilter} = Filter::read_in('route', $call, 0) || Filter::read_in('route', 'node_default', 0) unless $self->{isolate} ;
 253
 254
 255         # get the INPUT filters (these only pertain to Clusters)
 256         $self->{inspotsfilter} = Filter::read_in('spots', $call, 1) || Filter::read_in('spots', 'node_default', 1);
 257         $self->{inwwvfilter} = Filter::read_in('wwv', $call, 1) || Filter::read_in('wwv', 'node_default', 1);
 258         $self->{inwcyfilter} = Filter::read_in('wcy', $call, 1) || Filter::read_in('wcy', 'node_default', 1);
 259         $self->{inannfilter} = Filter::read_in('ann', $call, 1) || Filter::read_in('ann', 'node_default', 1);
 260         $self->{inroutefilter} = Filter::read_in('route', $call, 1) || Filter::read_in('route', 'node_default', 1) unless $self->{isolate};
 261
 262         # set unbuffered and no echo
 263         $self->send_now('B',"0");
 264         $self->send_now('E',"0");
 265         $self->conn->echo(0) if $self->conn->can('echo');
 266
 267         # ping neighbour node stuff
 268         my $ping = $user->pingint;
 269         $ping = 5*60 unless defined $ping;
 270         $self->{pingint} = $ping;
 271         $self->{nopings} = $user->nopings || 2;
 272         $self->{pingtime} = [ ];
 273         $self->{pingave} = 999;
 274         $self->{metric} ||= 100;
 275         $self->{lastping} = $main::systime;
 276
 277         # send initialisation string
 278         unless ($self->{outbound}) {
 279                 $self->send(pc18());
 280         }
 281
 282         $self->state('init');
 283         $self->{pc50_t} = $main::systime;
 284
 285         # send info to all logged in thingies
 286         $self->tell_login('loginn');
 287
 288         # run a script send the output to the debug file
 289         my $script = new Script(lc $call) || new Script('node_default');
 290         $script->run($self) if $script;
 291 }
 292
 293 #
 294 # This is the normal pcxx despatcher
 295 #
 296 sub normal
 297 {
 298         my ($self, $line) = @_;
 299         my @field = split /\^/, $line;
 300         return unless @field;
 301
 302         pop @field if $field[-1] eq '~';
 303
 304 #       print join(',', @field), "\n";
 305
 306
 307         # process PC frames, this will fail unless the frame starts PCnn
 308         my ($pcno) = $field[0] =~ /^PC(\d\d)/; # just get the number
 309         return unless $pcno;
 310         return if $pcno < 10 || $pcno > 99;
 311
 312         # check for and dump bad protocol messages
 313         my $n = check($pcno, @field);
 314         if ($n) {
 315                 dbg("PCPROT: bad field $n, dumped (" . parray($checklist[$pcno-10]) . ")") if isdbg('chanerr');
 316                 return;
 317         }
 318
 319         # local processing 1
 320         my $pcr;
 321         eval {
 322                 $pcr = Local::pcprot($self, $pcno, @field);
 323         };
 324 #       dbg("Local::pcprot error $@") if isdbg('local') if $@;
 325         return if $pcr;
 326
 327  SWITCH: {
 328                 if ($pcno == 10) {              # incoming talk
 329
 330                         # rsfp check
 331                         return if $rspfcheck and !$self->rspfcheck(0, $field[6], $field[1]);
 332
 333                         # will we allow it at all?
 334                         if ($censorpc) {
 335                                 my @bad;
 336                                 if (@bad = BadWords::check($field[3])) {
 337                                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 338                                         return;
 339                                 }
 340                         }
 341
 342                         # is it for me or one of mine?
 343                         my ($from, $to, $via, $call, $dxchan);
 344                         $from = $field[1];
 345                         if ($field[5] gt ' ') {
 346                                 $via = $field[2];
 347                                 $to = $field[5];
 348                         } else {
 349                                 $to = $field[2];
 350                         }
 351
 352                         # if we are converting announces to talk is it a dup?
 353                         if ($ann_to_talk) {
 354                                 if (AnnTalk::is_talk_candidate($from, $field[3]) && AnnTalk::dup($from, $to, $field[3])) {
 355                                         dbg("DXPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 356                                         return;
 357                                 }
 358                         }
 359
 360                         # it is here and logged on
 361                         $dxchan = DXChannel->get($main::myalias) if $to eq $main::mycall;
 362                         $dxchan = DXChannel->get($to) unless $dxchan;
 363                         if ($dxchan && $dxchan->is_user) {
 364                                 $field[3] =~ s/\%5E/^/g;
 365                                 $dxchan->talk($from, $to, $via, $field[3]);
 366                                 return;
 367                         }
 368
 369                         # is it elsewhere, visible on the cluster via the to address?
 370                         # note: this discards the via unless the to address is on
 371                         # the via address
 372                         my ($ref, $vref);
 373                         if ($ref = Route::get($to)) {
 374                                 $vref = Route::Node::get($via) if $via;
 375                                 $vref = undef unless $vref && grep $to eq $_, $vref->users;
 376                                 $ref->dxchan->talk($from, $to, $vref ? $via : undef, $field[3], $field[6]);
 377                                 return;
 378                         }
 379
 380                         # not visible here, send a message of condolence
 381                         $vref = undef;
 382                         $ref = Route::get($from);
 383                         $vref = $ref = Route::Node::get($field[6]) unless $ref;
 384                         if ($ref) {
 385                                 $dxchan = $ref->dxchan;
 386                                 $dxchan->talk($main::mycall, $from, $vref ? $vref->call : undef, $dxchan->msg('talknh', $to) );
 387                         }
 388                         return;
 389                 }
 390
 391                 if ($pcno == 11 || $pcno == 26) { # dx spot
 392
 393                         # route 'foreign' pc26s
 394                         if ($pcno == 26) {
 395                                 if ($field[7] ne $main::mycall) {
 396                                         $self->route($field[7], $line);
 397                                         return;
 398                                 }
 399                         }
 400
 401                         # rsfp check
 402 #                       return if $rspfcheck and !$self->rspfcheck(1, $field[7], $field[6]);
 403
 404                         # if this is a 'nodx' node then ignore it
 405                         if ($badnode->in($field[7])) {
 406                                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 407                                 return;
 408                         }
 409
 410                         # if this is a 'bad spotter' user then ignore it
 411                         if ($badspotter->in($field[6])) {
 412                                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 413                                 return;
 414                         }
 415
 416                         # convert the date to a unix date
 417                         my $d = cltounix($field[3], $field[4]);
 418                         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 419                         if (!$d || ($pcno == 11 && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 420                                 dbg("PCPROT: Spot ignored, invalid date or out of range ($field[3] $field[4])\n") if isdbg('chanerr');
 421                                 return;
 422                         }
 423
 424                         # is it 'baddx'
 425                         if ($baddx->in($field[2]) || BadWords::check($field[2]) || $field[2] =~ /COCK/) {
 426                                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 427                                 return;
 428                         }
 429
 430                         # do some de-duping
 431                         $field[5] =~ s/^\s+//;      # take any leading blanks off
 432                         $field[2] = unpad($field[2]);   # take off leading and trailing blanks from spotted callsign
 433                         if ($field[2] =~ /BUST\w*$/) {
 434                                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 435                                 return;
 436                         }
 437                         if ($censorpc) {
 438                                 my @bad;
 439                                 if (@bad = BadWords::check($field[5])) {
 440                                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 441                                         return;
 442                                 }
 443                         }
 444
 445
 446                         my @spot = Spot::prepare($field[1], $field[2], $d, $field[5], $field[6], $field[7]);
 447                         # global spot filtering on INPUT
 448                         if ($self->{inspotsfilter}) {
 449                                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 450                                 unless ($filter) {
 451                                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 452                                         return;
 453                                 }
 454                         }
 455
 456                         # this goes after the input filtering, but before the add
 457                         # so that if it is input filtered, it isn't added to the dup
 458                         # list. This allows it to come in from a "legitimate" source
 459                         if (Spot::dup($field[1], $field[2], $d, $field[5])) {
 460                                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 461                                 return;
 462                         }
 463
 464                         # add it
 465                         Spot::add(@spot);
 466
 467             #
 468                         # @spot at this point contains:-
 469             # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 470                         # then  spotted itu, spotted cq, spotters itu, spotters cq
 471                         # you should be able to route on any of these
 472             #
 473
 474                         # fix up qra locators of known users
 475                         my $user = DXUser->get_current($spot[4]);
 476                         if ($user) {
 477                                 my $qra = $user->qra;
 478                                 unless ($qra && is_qra($qra)) {
 479                                         my $lat = $user->lat;
 480                                         my $long = $user->long;
 481                                         if (defined $lat && defined $long) {
 482                                                 $user->qra(DXBearing::lltoqra($lat, $long));
 483                                                 $user->put;
 484                                         }
 485                                 }
 486
 487                                 # send a remote command to a distant cluster if it is visible and there is no
 488                                 # qra locator and we havn't done it for a month.
 489
 490                                 unless ($user->qra) {
 491                                         my $node;
 492                                         my $to = $user->homenode;
 493                                         my $last = $user->lastoper || 0;
 494                                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 495                                                 my $cmd = "forward/opernam $spot[4]";
 496                                                 # send the rcmd but we aren't interested in the replies...
 497                                                 my $dxchan = $node->dxchan;
 498                                                 if ($dxchan && $dxchan->is_clx) {
 499                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 500                                                 } else {
 501                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 502                                                 }
 503                                                 if ($to ne $field[7]) {
 504                                                         $to = $field[7];
 505                                                         $node = Route::Node::get($to);
 506                                                         if ($node) {
 507                                                                 $dxchan = $node->dxchan;
 508                                                                 if ($dxchan && $dxchan->is_clx) {
 509                                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 510                                                                 } else {
 511                                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 512                                                                 }
 513                                                         }
 514                                                 }
 515                                                 $user->lastoper($main::systime);
 516                                                 $user->put;
 517                                         }
 518                                 }
 519                         }
 520
 521                         # local processing
 522                         my $r;
 523                         eval {
 524                                 $r = Local::spot($self, @spot);
 525                         };
 526 #                       dbg("Local::spot1 error $@") if isdbg('local') if $@;
 527                         return if $r;
 528
 529                         # DON'T be silly and send on PC26s!
 530                         return if $pcno == 26;
 531
 532                         # send out the filtered spots
 533                         send_dx_spot($self, $line, @spot) if @spot;
 534                         return;
 535                 }
 536
 537                 if ($pcno == 12) {              # announces
 538
 539 #                       return if $rspfcheck and !$self->rspfcheck(1, $field[5], $field[1]);
 540
 541                         # announce duplicate checking
 542                         $field[3] =~ s/^\s+//;  # remove leading blanks
 543
 544                         if ($censorpc) {
 545                                 my @bad;
 546                                 if (@bad = BadWords::check($field[3])) {
 547                                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 548                                         return;
 549                                 }
 550                         }
 551
 552                         if ($field[2] eq '*' || $field[2] eq $main::mycall) {
 553
 554
 555                                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 556                                 # or one saying 'to <call>' to a talk if we can route to the recipient
 557                                 if ($ann_to_talk) {
 558                                         my $call = AnnTalk::is_talk_candidate($field[1], $field[3]);
 559                                         if ($call) {
 560                                                 my $ref = Route::get($call);
 561                                                 if ($ref) {
 562                                                         my $dxchan = $ref->dxchan;
 563                                                         $dxchan->talk($field[1], $call, undef, $field[3], $field[5]) if $dxchan != $self;
 564                                                         return;
 565                                                 }
 566                                         }
 567                                 }
 568
 569                                 # send it
 570                                 $self->send_announce($line, @field[1..6]);
 571                         } else {
 572                                 $self->route($field[2], $line);
 573                         }
 574                         return;
 575                 }
 576
 577                 if ($pcno == 13) {
 578                         last SWITCH;
 579                 }
 580                 if ($pcno == 14) {
 581                         last SWITCH;
 582                 }
 583                 if ($pcno == 15) {
 584                         last SWITCH;
 585                 }
 586
 587                 if ($pcno == 16) {              # add a user
 588
 589                         if (eph_dup($line)) {
 590                                 dbg("PCPROT: dup PC16 detected") if isdbg('chanerr');
 591                                 return;
 592                         }
 593
 594                         # general checks
 595                         my $dxchan;
 596                         my $ncall = $field[1];
 597                         my $newline = "PC16^";
 598
 599                         if ($ncall eq $main::mycall) {
 600                                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 601                                 return;
 602                         }
 603                         my $parent = Route::Node::get($ncall);
 604                         unless ($parent) {
 605                                 dbg("PCPROT: Node $ncall not in config") if isdbg('chanerr');
 606                                 return;
 607                         }
 608                         $dxchan = $parent->dxchan;
 609                         if ($dxchan && $dxchan ne $self) {
 610                                 dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 611                                 return;
 612                         }
 613
 614                         # input filter if required
 615                         return unless $self->in_filter_route($parent);
 616
 617                         my $i;
 618                         my @rout;
 619                         for ($i = 2; $i < $#field; $i++) {
 620                                 my ($call, $conf, $here) = $field[$i] =~ /^(\S+) (\S) (\d)/o;
 621                                 next unless $call && $conf && defined $here && is_callsign($call);
 622                                 next if $call eq $main::mycall;
 623
 624                                 eph_del_regex("^PC17\^$call\^$ncall");
 625
 626                                 $conf = $conf eq '*';
 627
 628                                 # reject this if we think it is a node already
 629                                 my $r = Route::Node::get($call);
 630                                 my $u = DXUser->get_current($call) unless $r;
 631                                 if ($r || ($u && $u->is_node)) {
 632                                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 633                                         next;
 634                                 }
 635
 636                                 $r = Route::User::get($call);
 637                                 my $flags = Route::here($here)|Route::conf($conf);
 638
 639                                 if ($r) {
 640                                         if ($r->flags != $flags) {
 641                                                 $r->flags($flags);
 642                                                 push @rout, $r;
 643                                         }
 644                                         $r->addparent($parent);
 645                                 } else {
 646                                         push @rout, $parent->add_user($call, $flags);
 647                                 }
 648
 649                                 # add this station to the user database, if required
 650                                 $call =~ s/-\d+$//o;        # remove ssid for users
 651                                 my $user = DXUser->get_current($call);
 652                                 $user = DXUser->new($call) if !$user;
 653                                 $user->homenode($parent->call) if !$user->homenode;
 654                                 $user->node($parent->call);
 655                                 $user->lastin($main::systime) unless DXChannel->get($call);
 656                                 $user->put;
 657                         }
 658
 659                         # queue up any messages (look for privates only)
 660                         DXMsg::queue_msg(1) if $self->state eq 'normal';
 661
 662                         $self->route_pc16($parent, @rout) if @rout;
 663                         return;
 664                 }
 665
 666                 if ($pcno == 17) {              # remove a user
 667                         my $dxchan;
 668                         my $ncall = $field[2];
 669                         my $ucall = $field[1];
 670
 671                         if (eph_dup($line)) {
 672                                 dbg("PCPROT: dup PC17 detected") if isdbg('chanerr');
 673                                 return;
 674                         }
 675
 676                         eph_del_regex("^PC16.*$ncall.*$ucall");
 677
 678                         if ($ncall eq $main::mycall) {
 679                                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 680                                 return;
 681                         }
 682
 683                         my $uref = Route::User::get($ucall);
 684                         unless ($uref) {
 685                                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 686                                 return;
 687                         }
 688                         my $parent = Route::Node::get($ncall);
 689                         unless ($parent) {
 690                                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 691                                 return;
 692                         }
 693
 694                         $dxchan = $parent->dxchan;
 695                         if ($dxchan && $dxchan ne $self) {
 696                                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 697                                 return;
 698                         }
 699
 700                         # input filter if required
 701                         return unless $self->in_filter_route($parent);
 702
 703                         $parent->del_user($uref);
 704                         $self->route_pc17($parent, $uref);
 705                         return;
 706                 }
 707
 708                 if ($pcno == 18) {              # link request
 709                         $self->state('init');
 710
 711                         # first clear out any nodes on this dxchannel
 712                         my $parent = Route::Node::get($self->{call});
 713                         my @rout = $parent->del_nodes;
 714                         $self->route_pc21(@rout, $parent) if @rout;
 715                         $self->send_local_config();
 716                         $self->send(pc20());
 717                         return;             # we don't pass these on
 718                 }
 719
 720                 if ($pcno == 19) {              # incoming cluster list
 721                         my $i;
 722                         my $newline = "PC19^";
 723
 724                         if (eph_dup($line)) {
 725                                 dbg("PCPROT: dup PC19 detected") if isdbg('chanerr');
 726                                 return;
 727                         }
 728
 729                         # new routing list
 730                         my @rout;
 731                         my $parent = Route::Node::get($self->{call});
 732                         unless ($parent) {
 733                                 dbg("DXPROT: my parent $self->{call} has disappeared");
 734                                 $self->disconnect;
 735                                 return;
 736                         }
 737
 738                         # parse the PC19
 739                         for ($i = 1; $i < $#field-1; $i += 4) {
 740                                 my $here = $field[$i];
 741                                 my $call = uc $field[$i+1];
 742                                 my $conf = $field[$i+2];
 743                                 my $ver = $field[$i+3];
 744                                 next unless defined $here && defined $conf && is_callsign($call);
 745
 746                                 eph_del_regex("^PC(?:21\^$call|17\^[^\^]+\^$call)");
 747
 748                                 # check for sane parameters
 749 #                               $ver = 5000 if $ver eq '0000';
 750                                 next if $ver < 5000; # only works with version 5 software
 751                                 next if length $call < 3; # min 3 letter callsigns
 752                                 next if $call eq $main::mycall;
 753
 754                                 # check that this PC19 isn't trying to alter the wrong dxchan
 755                                 my $dxchan = DXChannel->get($call);
 756                                 if ($dxchan && $dxchan != $self) {
 757                                         dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 758                                         return;
 759                                 }
 760
 761                                 # update it if required
 762                                 my $r = Route::Node::get($call);
 763                                 my $flags = Route::here($here)|Route::conf($conf);
 764                                 if ($r) {
 765                                         my $ar;
 766                                         if ($call ne $parent->call) {
 767                                                 if ($self->in_filter_route($r)) {
 768                                                         $ar = $parent->add($call, $ver, $flags);
 769                                                         push @rout, $ar if $ar;
 770                                                 } else {
 771                                                         next;
 772                                                 }
 773                                         }
 774                                         if ($r->version ne $ver || $r->flags != $flags) {
 775                                                 $r->version($ver);
 776                                                 $r->flags($flags);
 777                                                 push @rout, $r unless $ar;
 778                                         }
 779                                 } else {
 780                                         if ($call eq $self->{call}) {
 781                                                 dbg("DXPROT: my channel route for $call has disappeared");
 782                                                 next;
 783                                         };
 784
 785                                         my $new = Route->new($call);          # throw away
 786                                     if ($self->in_filter_route($new)) {
 787                                                 my $r = $parent->add($call, $ver, $flags);
 788                                                 push @rout, $r;
 789                                         } else {
 790                                                 next;
 791                                         }
 792                                 }
 793
 794                                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 795                                 my $mref = DXMsg::get_busy($call);
 796                                 $mref->stop_msg($call) if $mref;
 797
 798                                 # add this station to the user database, if required (don't remove SSID from nodes)
 799                                 my $user = DXUser->get_current($call);
 800                                 if (!$user) {
 801                                         $user = DXUser->new($call);
 802                                         $user->sort('A');
 803                                         $user->priv(1);                   # I have relented and defaulted nodes
 804                                         $user->lockout(1);
 805                                         $user->homenode($call);
 806                                         $user->node($call);
 807                                 }
 808                                 $user->lastin($main::systime) unless DXChannel->get($call);
 809                                 $user->put;
 810                         }
 811
 812
 813                         $self->route_pc19(@rout) if @rout;
 814                         return;
 815                 }
 816
 817                 if ($pcno == 20) {              # send local configuration
 818                         $self->send_local_config();
 819                         $self->send(pc22());
 820                         $self->state('normal');
 821                         $self->{lastping} = 0;
 822                         return;
 823                 }
 824
 825                 if ($pcno == 21) {              # delete a cluster from the list
 826                         my $call = uc $field[1];
 827
 828                         if (eph_dup($line)) {
 829                                 dbg("PCPROT: dup PC21 detected") if isdbg('chanerr');
 830                                 return;
 831                         }
 832
 833                         # if I get a PC21 from the same callsign as self then treat it
 834                         # as a PC39: I have gone away
 835                         if ($call eq $self->call) {
 836                                 $self->disconnect(1);
 837                                 eph_del_regex("^PC(?:1[679]|21).*$field[1]");
 838                                 return;
 839                         }
 840
 841                         eph_del_regex("^PC1[79].*$call");
 842
 843                         my @rout;
 844                         my $parent = Route::Node::get($self->{call});
 845                         unless ($parent) {
 846                                 dbg("DXPROT: my parent $self->{call} has disappeared");
 847                                 $self->disconnect;
 848                                 return;
 849                         }
 850                         if ($call ne $main::mycall) { # don't allow malicious buggers to disconnect me!
 851                                 my $node = Route::Node::get($call);
 852                                 if ($node) {
 853
 854                                         my $dxchan = DXChannel->get($call);
 855                                         if ($dxchan && $dxchan != $self) {
 856                                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chanerr');
 857                                                 return;
 858                                         }
 859
 860                                         # input filter it
 861                                         return unless $self->in_filter_route($node);
 862
 863                                         # routing objects
 864                                         push @rout, $node->del($parent);
 865                                 }
 866                         } else {
 867                                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chanerr');
 868                                 return;
 869                         }
 870
 871                         $self->route_pc21(@rout) if @rout;
 872                         return;
 873                 }
 874
 875                 if ($pcno == 22) {
 876                         $self->state('normal');
 877                         $self->{lastping} = 0;
 878                         return;
 879                 }
 880
 881                 if ($pcno == 23 || $pcno == 27) { # WWV info
 882
 883                         # route 'foreign' pc27s
 884                         if ($pcno == 27) {
 885                                 if ($field[8] ne $main::mycall) {
 886                                         $self->route($field[8], $line);
 887                                         return;
 888                                 }
 889                         }
 890
 891                         return if $rspfcheck and !$self->rspfcheck(1, $field[8], $field[7]);
 892
 893                         # do some de-duping
 894                         my $d = cltounix($field[1], sprintf("%02d18Z", $field[2]));
 895                         my $sfi = unpad($field[3]);
 896                         my $k = unpad($field[4]);
 897                         my $i = unpad($field[5]);
 898                         my ($r) = $field[6] =~ /R=(\d+)/;
 899                         $r = 0 unless $r;
 900                         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $field[2] < 0 || $field[2] > 23) {
 901                                 dbg("PCPROT: WWV Date ($field[1] $field[2]) out of range") if isdbg('chanerr');
 902                                 return;
 903                         }
 904                         if (Geomag::dup($d,$sfi,$k,$i,$field[6])) {
 905                                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 906                                 return;
 907                         }
 908                         $field[7] =~ s/-\d+$//o;            # remove spotter's ssid
 909
 910                         my $wwv = Geomag::update($d, $field[2], $sfi, $k, $i, @field[6..8], $r);
 911
 912                         my $rep;
 913                         eval {
 914                                 $rep = Local::wwv($self, $field[1], $field[2], $sfi, $k, $i, @field[6..8], $r);
 915                         };
 916 #                       dbg("Local::wwv2 error $@") if isdbg('local') if $@;
 917                         return if $rep;
 918
 919                         # DON'T be silly and send on PC27s!
 920                         return if $pcno == 27;
 921
 922                         # broadcast to the eager world
 923                         send_wwv_spot($self, $line, $d, $field[2], $sfi, $k, $i, @field[6..8]);
 924                         return;
 925                 }
 926
 927                 if ($pcno == 24) {              # set here status
 928                         my $call = uc $field[1];
 929                         my ($nref, $uref);
 930                         $nref = Route::Node::get($call);
 931                         $uref = Route::User::get($call);
 932                         return unless $nref || $uref;   # if we don't know where they are, it's pointless sending it on
 933
 934                         unless (eph_dup($line)) {
 935                                 $nref->here($field[2]) if $nref;
 936                                 $uref->here($field[2]) if $uref;
 937                                 my $ref = $nref || $uref;
 938                                 return unless $self->in_filter_route($ref);
 939                                 $self->route_pc24($ref, $field[3]);
 940                         }
 941                         return;
 942                 }
 943
 944                 if ($pcno == 25) {      # merge request
 945                         if ($field[1] ne $main::mycall) {
 946                                 $self->route($field[1], $line);
 947                                 return;
 948                         }
 949                         if ($field[2] eq $main::mycall) {
 950                                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chanerr');
 951                                 return;
 952                         }
 953
 954                         Log('DXProt', "Merge request for $field[3] spots and $field[4] WWV from $field[2]");
 955
 956                         # spots
 957                         if ($field[3] > 0) {
 958                                 my @in = reverse Spot::search(1, undef, undef, 0, $field[3]);
 959                                 my $in;
 960                                 foreach $in (@in) {
 961                                         $self->send(pc26(@{$in}[0..4], $field[2]));
 962                                 }
 963                         }
 964
 965                         # wwv
 966                         if ($field[4] > 0) {
 967                                 my @in = reverse Geomag::search(0, $field[4], time, 1);
 968                                 my $in;
 969                                 foreach $in (@in) {
 970                                         $self->send(pc27(@{$in}[0..5], $field[2]));
 971                                 }
 972                         }
 973                         return;
 974                 }
 975
 976                 if (($pcno >= 28 && $pcno <= 33) || $pcno == 40 || $pcno == 42 || $pcno == 49) { # mail/file handling
 977                         return if $pcno == 49 && eph_dup($line);
 978                         if ($pcno == 49 || $field[1] eq $main::mycall) {
 979                                 DXMsg::process($self, $line);
 980                         } else {
 981                                 $self->route($field[1], $line) unless $self->is_clx;
 982                         }
 983                         return;
 984                 }
 985
 986                 if ($pcno == 34 || $pcno == 36) { # remote commands (incoming)
 987                         if (eph_dup($line, $eph_pc34_restime)) {
 988                                 dbg("PCPROT: dupe") if isdbg('chanerr');
 989                         } else {
 990                                 $self->process_rcmd($field[1], $field[2], $field[2], $field[3]);
 991                         }
 992                         return;
 993                 }
 994
 995                 if ($pcno == 35) {              # remote command replies
 996                         eph_del_regex("^PC35\^$field[2]\^$field[1]\^");
 997                         $self->process_rcmd_reply($field[1], $field[2], $field[1], $field[3]);
 998                         return;
 999                 }
1000
1001                 # for pc 37 see 44 onwards
1002
1003                 if ($pcno == 38) {              # node connected list from neighbour
1004                         return;
1005                 }
1006
1007                 if ($pcno == 39) {              # incoming disconnect
1008                         if ($field[1] eq $self->{call}) {
1009                                 $self->disconnect(1);
1010                                 eph_del_regex("^PC(?:1[679]|21).*$field[1]");
1011                         } else {
1012                                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1013                         }
1014                         return;
1015                 }
1016
1017                 if ($pcno == 41) {              # user info
1018                         my $call = $field[1];
1019
1020                         if (eph_dup($line, $eph_info_restime)) {
1021                                 dbg("PCPROT: dupe") if isdbg('chanerr');
1022                                 return;
1023                         }
1024
1025                         # input filter if required
1026 #                       my $ref = Route::get($call) || Route->new($call);
1027 #                       return unless $self->in_filter_route($ref);
1028
1029                         if ($field[3] eq $field[2] || $field[3] =~ /^\s*$/) {
1030                                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1031                                 return;
1032                         }
1033
1034                         # add this station to the user database, if required
1035                         my $user = DXUser->get_current($call);
1036                         $user = DXUser->new($call) if !$user;
1037
1038                         if ($field[2] == 1) {
1039                                 $user->name($field[3]);
1040                         } elsif ($field[2] == 2) {
1041                                 $user->qth($field[3]);
1042                         } elsif ($field[2] == 3) {
1043                                 if (is_latlong($field[3])) {
1044                                         my ($lat, $long) = DXBearing::stoll($field[3]);
1045                                         $user->lat($lat);
1046                                         $user->long($long);
1047                                         $user->qra(DXBearing::lltoqra($lat, $long));
1048                                 } else {
1049                                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1050                                         return;
1051                                 }
1052                         } elsif ($field[2] == 4) {
1053                                 $user->homenode($field[3]);
1054                         } elsif ($field[2] == 5) {
1055                                 if (is_qra(uc $field[3])) {
1056                                         my ($lat, $long) = DXBearing::qratoll(uc $field[3]);
1057                                         $user->lat($lat);
1058                                         $user->long($long);
1059                                         $user->qra(uc $field[3]);
1060                                 } else {
1061                                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1062                                         return;
1063                                 }
1064                         }
1065                         $user->lastoper($main::systime);   # to cut down on excessive for/opers being generated
1066                         $user->put;
1067
1068                         unless ($self->{isolate}) {
1069                                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1070                         }
1071
1072 #  perhaps this IS what we want after all
1073 #                       $self->route_pc41($ref, $call, $field[2], $field[3], $field[4]);
1074                         return;
1075                 }
1076
1077                 if ($pcno == 43) {
1078                         last SWITCH;
1079                 }
1080
1081                 if ($pcno == 37 || $pcno == 44 || $pcno == 45 || $pcno == 46 || $pcno == 47 || $pcno == 48) {
1082                         DXDb::process($self, $line);
1083                         return;
1084                 }
1085
1086                 if ($pcno == 50) {              # keep alive/user list
1087                         my $call = $field[1];
1088                         my $node = Route::Node::get($call);
1089                         if ($node) {
1090                                 return unless $node->call eq $self->{call};
1091                                 $node->usercount($field[2]);
1092
1093                                 # input filter if required
1094                                 return unless $self->in_filter_route($node);
1095
1096                                 $self->route_pc50($node, $field[2], $field[3]) unless eph_dup($line);
1097                         }
1098                         return;
1099                 }
1100
1101                 if ($pcno == 51) {              # incoming ping requests/answers
1102                         my $to = $field[1];
1103                         my $from = $field[2];
1104                         my $flag = $field[3];
1105
1106
1107                         # is it for us?
1108                         if ($to eq $main::mycall) {
1109                                 if ($flag == 1) {
1110                                         $self->send(pc51($from, $to, '0'));
1111                                 } else {
1112                                         # it's a reply, look in the ping list for this one
1113                                         my $ref = $pings{$from};
1114                                         if ($ref) {
1115                                                 my $tochan =  DXChannel->get($from);
1116                                                 while (@$ref) {
1117                                                         my $r = shift @$ref;
1118                                                         my $dxchan = DXChannel->get($r->{call});
1119                                                         next unless $dxchan;
1120                                                         my $t = tv_interval($r->{t}, [ gettimeofday ]);
1121                                                         if ($dxchan->is_user) {
1122                                                                 my $s = sprintf "%.2f", $t;
1123                                                                 my $ave = sprintf "%.2f", $tochan ? ($tochan->{pingave} || $t) : $t;
1124                                                                 $dxchan->send($dxchan->msg('pingi', $from, $s, $ave))
1125                                                         } elsif ($dxchan->is_node) {
1126                                                                 if ($tochan) {
1127                                                                         my $nopings = $tochan->user->nopings || 2;
1128                                                                         push @{$tochan->{pingtime}}, $t;
1129                                                                         shift @{$tochan->{pingtime}} if @{$tochan->{pingtime}} > 6;
1130
1131                                                                         # cope with a missed ping, this means you must set the pingint large enough
1132                                                                         if ($t > $tochan->{pingint}  && $t < 2 * $tochan->{pingint} ) {
1133                                                                                 $t -= $tochan->{pingint};
1134                                                                         }
1135
1136                                                                         # calc smoothed RTT a la TCP
1137                                                                         if (@{$tochan->{pingtime}} == 1) {
1138                                                                                 $tochan->{pingave} = $t;
1139                                                                         } else {
1140                                                                                 $tochan->{pingave} = $tochan->{pingave} + (($t - $tochan->{pingave}) / 6);
1141                                                                         }
1142 #                                                                       my $st;
1143 #                                                                       for (@{$tochan->{pingtime}}) {
1144 #                                                                               $st += $_;
1145 #                                                                       }
1146 #                                                                       $tochan->{pingave} = $st / @{$tochan->{pingtime}};
1147                                                                         $tochan->{nopings} = $nopings; # pump up the timer
1148                                                                 }
1149                                                         }
1150                                                 }
1151                                         }
1152                                 }
1153                         } else {
1154                                 if (eph_dup($line)) {
1155                                         dbg("PCPROT: dup PC51 detected") if isdbg('chanerr');
1156                                         return;
1157                                 }
1158                                 # route down an appropriate thingy
1159                                 $self->route($to, $line);
1160                         }
1161                         return;
1162                 }
1163
1164                 if ($pcno == 75) {              # dunno but route it
1165                         my $call = $field[1];
1166                         if ($call ne $main::mycall) {
1167                                 $self->route($call, $line);
1168                         }
1169                         return;
1170                 }
1171
1172                 if ($pcno == 73) {  # WCY broadcasts
1173                         my $call = $field[1];
1174
1175                         # do some de-duping
1176                         my $d = cltounix($call, sprintf("%02d18Z", $field[2]));
1177                         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $field[2] < 0 || $field[2] > 23) {
1178                                 dbg("PCPROT: WCY Date ($call $field[2]) out of range") if isdbg('chanerr');
1179                                 return;
1180                         }
1181                         @field = map { unpad($_) } @field;
1182                         if (WCY::dup($d)) {
1183                                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1184                                 return;
1185                         }
1186
1187                         my $wcy = WCY::update($d, @field[2..12]);
1188
1189                         my $rep;
1190                         eval {
1191                                 $rep = Local::wcy($self, @field[1..12]);
1192                         };
1193                         # dbg("Local::wcy error $@") if isdbg('local') if $@;
1194                         return if $rep;
1195
1196                         # broadcast to the eager world
1197                         send_wcy_spot($self, $line, $d, @field[2..12]);
1198                         return;
1199                 }
1200
1201                 if ($pcno == 84) { # remote commands (incoming)
1202                         $self->process_rcmd($field[1], $field[2], $field[3], $field[4]);
1203                         return;
1204                 }
1205
1206                 if ($pcno == 85) {              # remote command replies
1207                         $self->process_rcmd_reply($field[1], $field[2], $field[3], $field[4]);
1208
1209                         return;
1210                 }
1211         }
1212
1213         # if get here then rebroadcast the thing with its Hop count decremented (if
1214         # there is one). If it has a hop count and it decrements to zero then don't
1215         # rebroadcast it.
1216         #
1217         # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
1218         #        REBROADCAST!!!!
1219         #
1220
1221         if (eph_dup($line)) {
1222                 dbg("PCPROT: Ephemeral dup, dropped") if isdbg('chanerr');
1223         } else {
1224                 unless ($self->{isolate}) {
1225                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1226                 }
1227         }
1228 }
1229
1230 #
1231 # This is called from inside the main cluster processing loop and is used
1232 # for despatching commands that are doing some long processing job
1233 #
1234 sub process
1235 {
1236         my $t = time;
1237         my @dxchan = DXChannel->get_all();
1238         my $dxchan;
1239         my $pc50s;
1240
1241         # send out a pc50 on EVERY channel all at once
1242         if ($t >= $last_pc50 + $DXProt::pc50_interval) {
1243                 $pc50s = pc50($main::me, scalar DXChannel::get_all_users);
1244                 eph_dup($pc50s);
1245                 $last_pc50 = $t;
1246         }
1247
1248         foreach $dxchan (@dxchan) {
1249                 next unless $dxchan->is_node();
1250                 next if $dxchan == $main::me;
1251
1252                 # send the pc50
1253                 $dxchan->send($pc50s) if $pc50s;
1254
1255                 # send a ping out on this channel
1256                 if ($dxchan->{pingint} && $t >= $dxchan->{pingint} + $dxchan->{lastping}) {
1257                         if ($dxchan->{nopings} <= 0) {
1258                                 $dxchan->disconnect;
1259                         } else {
1260                                 addping($main::mycall, $dxchan->call);
1261                                 $dxchan->{nopings} -= 1;
1262                                 $dxchan->{lastping} = $t;
1263                         }
1264                 }
1265         }
1266
1267         # every ten seconds
1268         if ($t - $last10 >= 10) {
1269                 # clean out ephemera
1270
1271                 eph_clean();
1272
1273                 $last10 = $t;
1274         }
1275
1276         if ($main::systime - 3600 > $last_hour) {
1277                 $last_hour = $main::systime;
1278         }
1279 }
1280
1281 #
1282 # finish up a pc context
1283 #
1284
1285 #
1286 # some active measures
1287 #
1288
1289 sub send_dx_spot
1290 {
1291         my $self = shift;
1292         my $line = shift;
1293         my @dxchan = DXChannel->get_all();
1294         my $dxchan;
1295
1296         # send it if it isn't the except list and isn't isolated and still has a hop count
1297         # taking into account filtering and so on
1298         foreach $dxchan (@dxchan) {
1299                 next if $dxchan == $main::me;
1300                 next if $dxchan == $self && $self->is_node;
1301                 $dxchan->dx_spot($line, $self->{isolate}, @_, $self->{call});
1302         }
1303 }
1304
1305 sub dx_spot
1306 {
1307         my $self = shift;
1308         my $line = shift;
1309         my $isolate = shift;
1310         my ($filter, $hops);
1311
1312         if ($self->{spotsfilter}) {
1313                 ($filter, $hops) = $self->{spotsfilter}->it(@_);
1314                 return unless $filter;
1315         }
1316         send_prot_line($self, $filter, $hops, $isolate, $line);
1317 }
1318
1319 sub send_prot_line
1320 {
1321         my ($self, $filter, $hops, $isolate, $line) = @_;
1322         my $routeit;
1323
1324         if ($hops) {
1325                 $routeit = $line;
1326                 $routeit =~ s/\^H\d+\^\~$/\^H$hops\^\~/;
1327         } else {
1328                 $routeit = adjust_hops($self, $line);  # adjust its hop count by node name
1329                 return unless $routeit;
1330         }
1331         if ($filter) {
1332                 $self->send($routeit);
1333         } else {
1334                 $self->send($routeit) unless $self->{isolate} || $isolate;
1335         }
1336 }
1337
1338
1339 sub send_wwv_spot
1340 {
1341         my $self = shift;
1342         my $line = shift;
1343         my @dxchan = DXChannel->get_all();
1344         my $dxchan;
1345         my ($wwv_dxcc, $wwv_itu, $wwv_cq, $org_dxcc, $org_itu, $org_cq) = (0..0);
1346         my @dxcc = Prefix::extract($_[6]);
1347         if (@dxcc > 0) {
1348                 $wwv_dxcc = $dxcc[1]->dxcc;
1349                 $wwv_itu = $dxcc[1]->itu;
1350                 $wwv_cq = $dxcc[1]->cq;
1351         }
1352         @dxcc = Prefix::extract($_[7]);
1353         if (@dxcc > 0) {
1354                 $org_dxcc = $dxcc[1]->dxcc;
1355                 $org_itu = $dxcc[1]->itu;
1356                 $org_cq = $dxcc[1]->cq;
1357         }
1358
1359         # send it if it isn't the except list and isn't isolated and still has a hop count
1360         # taking into account filtering and so on
1361         foreach $dxchan (@dxchan) {
1362                 next if $dxchan == $main::me;
1363                 next if $dxchan == $self && $self->is_node;
1364                 my $routeit;
1365                 my ($filter, $hops);
1366
1367                 $dxchan->wwv($line, $self->{isolate}, @_, $self->{call}, $wwv_dxcc, $wwv_itu, $wwv_cq, $org_dxcc, $org_itu, $org_cq);
1368         }
1369
1370 }
1371
1372 sub wwv
1373 {
1374         my $self = shift;
1375         my $line = shift;
1376         my $isolate = shift;
1377         my ($filter, $hops);
1378
1379         if ($self->{wwvfilter}) {
1380                 ($filter, $hops) = $self->{wwvfilter}->it(@_);
1381                 return unless $filter;
1382         }
1383         send_prot_line($self, $filter, $hops, $isolate, $line)
1384 }
1385
1386 sub send_wcy_spot
1387 {
1388         my $self = shift;
1389         my $line = shift;
1390         my @dxchan = DXChannel->get_all();
1391         my $dxchan;
1392         my ($wcy_dxcc, $wcy_itu, $wcy_cq, $org_dxcc, $org_itu, $org_cq) = (0..0);
1393         my @dxcc = Prefix::extract($_[10]);
1394         if (@dxcc > 0) {
1395                 $wcy_dxcc = $dxcc[1]->dxcc;
1396                 $wcy_itu = $dxcc[1]->itu;
1397                 $wcy_cq = $dxcc[1]->cq;
1398         }
1399         @dxcc = Prefix::extract($_[11]);
1400         if (@dxcc > 0) {
1401                 $org_dxcc = $dxcc[1]->dxcc;
1402                 $org_itu = $dxcc[1]->itu;
1403                 $org_cq = $dxcc[1]->cq;
1404         }
1405
1406         # send it if it isn't the except list and isn't isolated and still has a hop count
1407         # taking into account filtering and so on
1408         foreach $dxchan (@dxchan) {
1409                 next if $dxchan == $main::me;
1410                 next if $dxchan == $self;
1411
1412                 $dxchan->wcy($line, $self->{isolate}, @_, $self->{call}, $wcy_dxcc, $wcy_itu, $wcy_cq, $org_dxcc, $org_itu, $org_cq);
1413         }
1414 }
1415
1416 sub wcy
1417 {
1418         my $self = shift;
1419         my $line = shift;
1420         my $isolate = shift;
1421         my ($filter, $hops);
1422
1423         if ($self->{wcyfilter}) {
1424                 ($filter, $hops) = $self->{wcyfilter}->it(@_);
1425                 return unless $filter;
1426         }
1427         send_prot_line($self, $filter, $hops, $isolate, $line) if $self->is_clx || $self->is_spider || $self->is_dxnet;
1428 }
1429
1430 # send an announce
1431 sub send_announce
1432 {
1433         my $self = shift;
1434         my $line = shift;
1435         my @dxchan = DXChannel->get_all();
1436         my $dxchan;
1437         my $target;
1438         my $to = 'To ';
1439         my $text = unpad($_[2]);
1440
1441         if ($_[3] eq '*') {     # sysops
1442                 $target = "SYSOP";
1443         } elsif ($_[3] gt ' ') { # speciality list handling
1444                 my ($name) = split /\./, $_[3];
1445                 $target = "$name"; # put the rest in later (if bothered)
1446         }
1447
1448         if ($_[5] eq '1') {
1449                 $target = "WX";
1450                 $to = '';
1451         }
1452         $target = "ALL" if !$target;
1453
1454
1455         # obtain country codes etc
1456         my ($ann_dxcc, $ann_itu, $ann_cq, $org_dxcc, $org_itu, $org_cq) = (0..0);
1457         my @dxcc = Prefix::extract($_[0]);
1458         if (@dxcc > 0) {
1459                 $ann_dxcc = $dxcc[1]->dxcc;
1460                 $ann_itu = $dxcc[1]->itu;
1461                 $ann_cq = $dxcc[1]->cq;
1462         }
1463         @dxcc = Prefix::extract($_[4]);
1464         if (@dxcc > 0) {
1465                 $org_dxcc = $dxcc[1]->dxcc;
1466                 $org_itu = $dxcc[1]->itu;
1467                 $org_cq = $dxcc[1]->cq;
1468         }
1469
1470         if ($self->{inannfilter}) {
1471                 my ($filter, $hops) =
1472                         $self->{inannfilter}->it(@_, $self->{call},
1473                                                                          $ann_dxcc, $ann_itu, $ann_cq,
1474                                                                          $org_dxcc, $org_itu, $org_cq);
1475                 unless ($filter) {
1476                         dbg("PCPROT: Rejected by input announce filter") if isdbg('chanerr');
1477                         return;
1478                 }
1479         }
1480
1481         if (AnnTalk::dup($_[0], $_[1], $_[2])) {
1482                 dbg("PCPROT: Duplicate Announce ignored") if isdbg('chanerr');
1483                 return;
1484         }
1485
1486         Log('ann', $target, $_[0], $text);
1487
1488         # send it if it isn't the except list and isn't isolated and still has a hop count
1489         # taking into account filtering and so on
1490         foreach $dxchan (@dxchan) {
1491                 next if $dxchan == $main::me;
1492                 next if $dxchan == $self && $self->is_node;
1493                 $dxchan->announce($line, $self->{isolate}, $to, $target, $text, @_, $self->{call}, $ann_dxcc, $ann_itu, $ann_cq, $org_dxcc, $org_itu, $org_cq);
1494         }
1495 }
1496
1497 sub announce
1498 {
1499         my $self = shift;
1500         my $line = shift;
1501         my $isolate = shift;
1502         my $to = shift;
1503         my $target = shift;
1504         my $text = shift;
1505         my ($filter, $hops);
1506
1507         if ($self->{annfilter}) {
1508                 ($filter, $hops) = $self->{annfilter}->it(@_);
1509                 return unless $filter;
1510         }
1511         send_prot_line($self, $filter, $hops, $isolate, $line) unless $_[1] eq $main::mycall;
1512 }
1513
1514
1515 sub send_local_config
1516 {
1517         my $self = shift;
1518         my $n;
1519         my @nodes;
1520         my @localnodes;
1521         my @remotenodes;
1522
1523         dbg('DXProt::send_local_config') if isdbg('trace');
1524
1525         # send our nodes
1526         if ($self->{isolate}) {
1527                 @localnodes = ( $main::routeroot );
1528         } else {
1529                 # create a list of all the nodes that are not connected to this connection
1530                 # and are not themselves isolated, this to make sure that isolated nodes
1531         # don't appear outside of this node
1532                 my @dxchan = grep { $_->call ne $main::mycall && $_ != $self && !$_->{isolate} } DXChannel::get_all_nodes();
1533                 @localnodes = map { my $r = Route::Node::get($_->{call}); $r ? $r : () } @dxchan if @dxchan;
1534                 my @intcalls = map { $_->nodes } @localnodes if @localnodes;
1535                 my $ref = Route::Node::get($self->{call});
1536                 my @rnodes = $ref->nodes;
1537                 for my $n (@intcalls) {
1538                         push @remotenodes, Route::Node::get($n) unless grep $n eq $_, @rnodes;
1539                 }
1540                 unshift @localnodes, $main::routeroot;
1541         }
1542
1543         send_route($self, \&pc19, scalar(@localnodes)+scalar(@remotenodes), @localnodes, @remotenodes);
1544
1545         # get all the users connected on the above nodes and send them out
1546         foreach $n (@localnodes, @remotenodes) {
1547                 if ($n) {
1548                         send_route($self, \&pc16, 1, $n, map {my $r = Route::User::get($_); $r ? ($r) : ()} $n->users);
1549                 } else {
1550                         dbg("sent a null value") if isdbg('chanerr');
1551                 }
1552         }
1553 }
1554
1555 #
1556 # route a message down an appropriate interface for a callsign
1557 #
1558 # is called route(to, pcline);
1559 #
1560 sub route
1561 {
1562         my ($self, $call, $line) = @_;
1563
1564         if (ref $self && $call eq $self->{call}) {
1565                 dbg("PCPROT: Trying to route back to source, dropped") if isdbg('chanerr');
1566                 return;
1567         }
1568
1569         # always send it down the local interface if available
1570         my $dxchan = DXChannel->get($call);
1571         unless ($dxchan) {
1572                 my $cl = Route::get($call);
1573                 $dxchan = $cl->dxchan if $cl;
1574                 if (ref $dxchan) {
1575                         if (ref $self && $dxchan eq $self) {
1576                                 dbg("PCPROT: Trying to route back to source, dropped") if isdbg('chanerr');
1577                                 return;
1578                         }
1579                 }
1580         }
1581         if ($dxchan) {
1582                 my $routeit = adjust_hops($dxchan, $line);   # adjust its hop count by node name
1583                 if ($routeit) {
1584                         $dxchan->send($routeit) unless $dxchan == $main::me;
1585                 }
1586         } else {
1587                 dbg("PCPROT: No route available, dropped") if isdbg('chanerr');
1588         }
1589 }
1590
1591 #
1592 # obtain the hops from the list for this callsign and pc no
1593 #
1594
1595 sub get_hops
1596 {
1597         my $pcno = shift;
1598         my $hops = $DXProt::hopcount{$pcno};
1599         $hops = $DXProt::def_hopcount if !$hops;
1600         return "H$hops";
1601 }
1602
1603 #
1604 # adjust the hop count on a per node basis using the user loadable
1605 # hop table if available or else decrement an existing one
1606 #
1607
1608 sub adjust_hops
1609 {
1610         my $self = shift;
1611         my $s = shift;
1612         my $call = $self->{call};
1613         my $hops;
1614
1615         if (($hops) = $s =~ /\^H(\d+)\^~?$/o) {
1616                 my ($pcno) = $s =~ /^PC(\d\d)/o;
1617                 confess "$call called adjust_hops with '$s'" unless $pcno;
1618                 my $ref = $nodehops{$call} if %nodehops;
1619                 if ($ref) {
1620                         my $newhops = $ref->{$pcno};
1621                         return "" if defined $newhops && $newhops == 0;
1622                         $newhops = $ref->{default} unless $newhops;
1623                         return "" if defined $newhops && $newhops == 0;
1624                         $newhops = $hops if !$newhops;
1625                         $s =~ s/\^H(\d+)(\^~?)$/\^H$newhops$2/ if $newhops;
1626                 } else {
1627                         # simply decrement it
1628                         $hops--;
1629                         return "" if !$hops;
1630                         $s =~ s/\^H(\d+)(\^~?)$/\^H$hops$2/ if $hops;
1631                 }
1632         }
1633         return $s;
1634 }
1635
1636 #
1637 # load hop tables
1638 #
1639 sub load_hops
1640 {
1641         my $self = shift;
1642         return $self->msg('lh1') unless -e "$main::data/hop_table.pl";
1643         do "$main::data/hop_table.pl";
1644         return $@ if $@;
1645         return 0;
1646 }
1647
1648
1649 # add a ping request to the ping queues
1650 sub addping
1651 {
1652         my ($from, $to) = @_;
1653         my $ref = $pings{$to} || [];
1654         my $r = {};
1655         $r->{call} = $from;
1656         $r->{t} = [ gettimeofday ];
1657         route(undef, $to, pc51($to, $main::mycall, 1));
1658         push @$ref, $r;
1659         $pings{$to} = $ref;
1660 }
1661
1662 sub process_rcmd
1663 {
1664         my ($self, $tonode, $fromnode, $user, $cmd) = @_;
1665         if ($tonode eq $main::mycall) {
1666                 my $ref = DXUser->get_current($fromnode);
1667                 my $cref = Route::Node::get($fromnode);
1668                 Log('rcmd', 'in', $ref->{priv}, $fromnode, $cmd);
1669                 if ($cmd !~ /^\s*rcmd/i && $cref && $ref && $cref->call eq $ref->homenode) { # not allowed to relay RCMDS!
1670                         if ($ref->{priv}) {             # you have to have SOME privilege, the commands have further filtering
1671                                 $self->{remotecmd} = 1; # for the benefit of any command that needs to know
1672                                 my $oldpriv = $self->{priv};
1673                                 $self->{priv} = $ref->{priv}; # assume the user's privilege level
1674                                 my @in = (DXCommandmode::run_cmd($self, $cmd));
1675                                 $self->{priv} = $oldpriv;
1676                                 $self->send_rcmd_reply($main::mycall, $fromnode, $user, @in);
1677                                 delete $self->{remotecmd};
1678                         } else {
1679                                 $self->send_rcmd_reply($main::mycall, $fromnode, $user, "sorry...!");
1680                         }
1681                 } else {
1682                         $self->send_rcmd_reply($main::mycall, $fromnode, $user, "your attempt is logged, Tut tut tut...!");
1683                 }
1684         } else {
1685                 my $ref = DXUser->get_current($tonode);
1686                 if ($ref && $ref->is_clx) {
1687                         $self->route($tonode, pc84($fromnode, $tonode, $user, $cmd));
1688                 } else {
1689                         $self->route($tonode, pc34($fromnode, $tonode, $cmd));
1690                 }
1691         }
1692 }
1693
1694 sub process_rcmd_reply
1695 {
1696         my ($self, $tonode, $fromnode, $user, $line) = @_;
1697         if ($tonode eq $main::mycall) {
1698                 my $s = $rcmds{$fromnode};
1699                 if ($s) {
1700                         my $dxchan = DXChannel->get($s->{call});
1701                         my $ref = $user eq $tonode ? $dxchan : (DXChannel->get($user) || $dxchan);
1702                         $ref->send($line) if $ref;
1703                         delete $rcmds{$fromnode} if !$dxchan;
1704                 } else {
1705                         # send unsolicited ones to the sysop
1706                         my $dxchan = DXChannel->get($main::myalias);
1707                         $dxchan->send($line) if $dxchan;
1708                 }
1709         } else {
1710                 my $ref = DXUser->get_current($tonode);
1711                 if ($ref && $ref->is_clx) {
1712                         $self->route($tonode, pc85($fromnode, $tonode, $user, $line));
1713                 } else {
1714                         $self->route($tonode, pc35($fromnode, $tonode, $line));
1715                 }
1716         }
1717 }
1718
1719 sub send_rcmd_reply
1720 {
1721         my $self = shift;
1722         my $tonode = shift;
1723         my $fromnode = shift;
1724         my $user = shift;
1725         while (@_) {
1726                 my $line = shift;
1727                 $line =~ s/\s*$//;
1728                 Log('rcmd', 'out', $fromnode, $line);
1729                 if ($self->is_clx) {
1730                         $self->send(pc85($main::mycall, $fromnode, $user, "$main::mycall:$line"));
1731                 } else {
1732                         $self->send(pc35($main::mycall, $fromnode, "$main::mycall:$line"));
1733                 }
1734         }
1735 }
1736
1737 # add a rcmd request to the rcmd queues
1738 sub addrcmd
1739 {
1740         my ($self, $to, $cmd) = @_;
1741
1742         my $r = {};
1743         $r->{call} = $self->{call};
1744         $r->{t} = $main::systime;
1745         $r->{cmd} = $cmd;
1746         $rcmds{$to} = $r;
1747
1748         my $ref = Route::Node::get($to);
1749         my $dxchan = $ref->dxchan;
1750         if ($dxchan && $dxchan->is_clx) {
1751                 route(undef, $to, pc84($main::mycall, $to, $self->{call}, $cmd));
1752         } else {
1753                 route(undef, $to, pc34($main::mycall, $to, $cmd));
1754         }
1755 }
1756
1757 sub disconnect
1758 {
1759         my $self = shift;
1760         my $pc39flag = shift;
1761         my $call = $self->call;
1762
1763         return if $self->{disconnecting}++;
1764
1765         unless ($pc39flag && $pc39flag == 1) {
1766                 $self->send_now("D", DXProt::pc39($main::mycall, $self->msg('disc1', "System Op")));
1767         }
1768
1769         # do routing stuff
1770         my $node = Route::Node::get($call);
1771         my @rout;
1772         if ($node) {
1773                 @rout = $node->del($main::routeroot);
1774         }
1775
1776         # unbusy and stop and outgoing mail
1777         my $mref = DXMsg::get_busy($call);
1778         $mref->stop_msg($call) if $mref;
1779
1780         # broadcast to all other nodes that all the nodes connected to via me are gone
1781         unless ($pc39flag && $pc39flag == 2) {
1782                 $self->route_pc21(@rout) if @rout;
1783         }
1784
1785         # remove outstanding pings
1786         delete $pings{$call};
1787
1788         # I was the last node visited
1789     $self->user->node($main::mycall);
1790
1791         # send info to all logged in thingies
1792         $self->tell_login('logoutn');
1793
1794         Log('DXProt', $call . " Disconnected");
1795
1796         $self->SUPER::disconnect;
1797 }
1798
1799
1800 #
1801 # send a talk message to this thingy
1802 #
1803 sub talk
1804 {
1805         my ($self, $from, $to, $via, $line, $origin) = @_;
1806
1807         $line =~ s/\^/\\5E/g;                   # remove any ^ characters
1808         $self->send(DXProt::pc10($from, $to, $via, $line, $origin));
1809         Log('talk', $to, $from, $via?$via:$self->call, $line) unless $origin && $origin ne $main::mycall;
1810 }
1811
1812 # send it if it isn't the except list and isn't isolated and still has a hop count
1813 # taking into account filtering and so on
1814 sub send_route
1815 {
1816         my $self = shift;
1817         my $generate = shift;
1818         my $no = shift;     # the no of things to filter on
1819         my $routeit;
1820         my ($filter, $hops);
1821         my @rin;
1822
1823         for (; @_ && $no; $no--) {
1824                 my $r = shift;
1825
1826                 if (!$self->{isolate} && $self->{routefilter}) {
1827                         $filter = undef;
1828                         if ($r) {
1829                                 ($filter, $hops) = $self->{routefilter}->it($self->{call}, $self->{dxcc}, $self->{itu}, $self->{cq}, $r->call, $r->dxcc, $r->itu, $r->cq);
1830                                 if ($filter) {
1831                                         push @rin, $r;
1832                                 } else {
1833                                         dbg("DXPROT: $self->{call}/" . $r->call . " rejected by output filter") if isdbg('chanerr');
1834                                 }
1835                         } else {
1836                                 dbg("was sent a null value") if isdbg('chanerr');
1837                         }
1838                 } else {
1839                         push @rin, $r unless $self->{isolate} && $r->call ne $main::mycall;
1840                 }
1841         }
1842         if (@rin) {
1843                 foreach my $line (&$generate(@rin, @_)) {
1844                         if ($hops) {
1845                                 $routeit = $line;
1846                                 $routeit =~ s/\^H\d+\^\~$/\^H$hops\^\~/;
1847                         } else {
1848                                 $routeit = adjust_hops($self, $line);  # adjust its hop count by node name
1849                                 next unless $routeit;
1850                         }
1851                         $self->send($routeit);
1852                 }
1853         }
1854 }
1855
1856 sub broadcast_route
1857 {
1858         my $self = shift;
1859         my $generate = shift;
1860         my @dxchan = DXChannel::get_all_nodes();
1861         my $dxchan;
1862         my $line;
1863
1864         unless ($self->{isolate}) {
1865                 foreach $dxchan (@dxchan) {
1866                         next if $dxchan == $self;
1867                         next if $dxchan == $main::me;
1868                         $dxchan->send_route($generate, @_);
1869                 }
1870         }
1871 }
1872
1873 sub route_pc16
1874 {
1875         my $self = shift;
1876         broadcast_route($self, \&pc16, 1, @_);
1877 }
1878
1879 sub route_pc17
1880 {
1881         my $self = shift;
1882         broadcast_route($self, \&pc17, 1, @_);
1883 }
1884
1885 sub route_pc19
1886 {
1887         my $self = shift;
1888         broadcast_route($self, \&pc19, scalar @_, @_);
1889 }
1890
1891 sub route_pc21
1892 {
1893         my $self = shift;
1894         broadcast_route($self, \&pc21, scalar @_, @_);
1895 }
1896
1897 sub route_pc24
1898 {
1899         my $self = shift;
1900         broadcast_route($self, \&pc24, 1, @_);
1901 }
1902
1903 sub route_pc41
1904 {
1905         my $self = shift;
1906         broadcast_route($self, \&pc41, 1, @_);
1907 }
1908
1909 sub route_pc50
1910 {
1911         my $self = shift;
1912         broadcast_route($self, \&pc50, 1, @_);
1913 }
1914
1915 sub in_filter_route
1916 {
1917         my $self = shift;
1918         my $r = shift;
1919         my ($filter, $hops) = (1, 1);
1920
1921         if ($self->{inroutefilter}) {
1922                 ($filter, $hops) = $self->{inroutefilter}->it($self->{call}, $self->{dxcc}, $self->{itu}, $self->{cq}, $r->call, $r->dxcc, $r->itu, $r->cq);
1923                 dbg("PCPROT: $self->{call}/" . $r->call . ' rejected by in_filter_route') if !$filter && isdbg('chanerr');
1924         }
1925         return $filter;
1926 }
1927
1928 sub eph_dup
1929 {
1930         my $s = shift;
1931         my $t = shift || $eph_restime;
1932         my $r;
1933
1934         # chop the end off
1935         $s =~ s/\^H\d\d?\^?\~?$//;
1936         $r = 1 if exists $eph{$s};    # pump up the dup if it keeps circulating
1937         $eph{$s} = $main::systime + $t;
1938         return $r;
1939 }
1940
1941 sub eph_del_regex
1942 {
1943         my $regex = shift;
1944         my ($key, $val);
1945         while (($key, $val) = each %eph) {
1946                 if ($key =~ m{$regex}) {
1947                         delete $eph{$key};
1948                 }
1949         }
1950 }
1951
1952 sub eph_clean
1953 {
1954         my ($key, $val);
1955
1956         while (($key, $val) = each %eph) {
1957                 if ($main::systime >= $val) {
1958                         delete $eph{$key};
1959                 }
1960         }
1961 }
1962
1963 sub eph_list
1964 {
1965         my ($key, $val);
1966         my @out;
1967
1968         while (($key, $val) = each %eph) {
1969                 push @out, $key, $val;
1970         }
1971         return @out;
1972 }
1973
1974 sub run_cmd
1975 {
1976         goto &DXCommandmode::run_cmd;
1977 }
1978 1;
1979 __END__