perl/DXProt.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 # $Id$
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXCluster;
  19 use DXProtVars;
  20 use DXCommandmode;
  21 use DXLog;
  22 use Spot;
  23 use DXProtout;
  24 use Carp;
  25
  26 use strict;
  27 use vars qw($me $pc11_max_age $pc11_dup_age %dup $last_hour %pings %rcmds);
  28
  29 $me = undef;                                    # the channel id for this cluster
  30 $pc11_max_age = 1*3600;                 # the maximum age for an incoming 'real-time' pc11
  31 $pc11_dup_age = 24*3600;                # the maximum time to keep the dup list for
  32 %dup = ();                                              # the pc11 and 26 dup hash
  33 $last_hour = time;                              # last time I did an hourly periodic update
  34 %pings = ();                    # outstanding ping requests outbound
  35 %rcmds = ();                    # outstanding rcmd requests outbound
  36
  37 sub init
  38 {
  39         my $user = DXUser->get($main::mycall);
  40         $me = DXProt->new($main::mycall, undef, $user);
  41         $me->{here} = 1;
  42         #  $me->{sort} = 'M';    # M for me
  43 }
  44
  45 #
  46 # obtain a new connection this is derived from dxchannel
  47 #
  48
  49 sub new
  50 {
  51         my $self = DXChannel::alloc(@_);
  52         $self->{sort} = 'A';            # in absence of how to find out what sort of an object I am
  53         return $self;
  54 }
  55
  56 # this is how a pc connection starts (for an incoming connection)
  57 # issue a PC38 followed by a PC18, then wait for a PC20 (remembering
  58 # all the crap that comes between).
  59 sub start
  60 {
  61         my ($self, $line, $sort) = @_;
  62         my $call = $self->{call};
  63         my $user = $self->{user};
  64
  65         # remember type of connection
  66         $self->{consort} = $line;
  67         $self->{outbound} = $sort eq 'O';
  68         $self->{priv} = $user->priv;
  69         $self->{lang} = $user->lang;
  70         $self->{consort} = $line;       # save the connection type
  71         $self->{here} = 1;
  72
  73         # set unbuffered
  74         $self->send_now('B',"0");
  75
  76         # send initialisation string
  77         if (!$self->{outbound}) {
  78                 $self->send(pc38()) if DXNode->get_all();
  79                 $self->send(pc18());
  80         }
  81         $self->state('init');
  82         $self->pc50_t(time);
  83
  84         Log('DXProt', "$call connected");
  85 }
  86
  87 #
  88 # This is the normal pcxx despatcher
  89 #
  90 sub normal
  91 {
  92         my ($self, $line) = @_;
  93         my @field = split /[\^\~]/, $line;
  94
  95         # ignore any lines that don't start with PC
  96         return if !$field[0] =~ /^PC/;
  97
  98         # process PC frames
  99         my ($pcno) = $field[0] =~ /^PC(\d\d)/; # just get the number
 100         return if $pcno < 10 || $pcno > 51;
 101
 102  SWITCH: {
 103                 if ($pcno == 10) {              # incoming talk
 104
 105                         # is it for me or one of mine?
 106                         my $call = ($field[5] gt ' ') ? $field[5] : $field[2];
 107                         if ($call eq $main::mycall || grep $_ eq $call, get_all_user_calls()) {
 108
 109                                 # yes, it is
 110                                 my $text = unpad($field[3]);
 111                                 Log('talk', $call, $field[1], $field[6], $text);
 112                                 $call = $main::myalias if $call eq $main::mycall;
 113                                 my $ref = DXChannel->get($call);
 114                                 $ref->send("$call de $field[1]: $text") if $ref;
 115                         } else {
 116                                 route($field[2], $line); # relay it on its way
 117                         }
 118                         return;
 119                 }
 120
 121                 if ($pcno == 11 || $pcno == 26) { # dx spot
 122
 123                         # if this is a 'nodx' node then ignore it
 124                         last SWITCH if grep $field[7] =~ /^$_/,  @DXProt::nodx_node;
 125
 126                         # convert the date to a unix date
 127                         my $d = cltounix($field[3], $field[4]);
 128                         return if !$d || ($pcno == 11 && $d < $main::systime - $pc11_max_age); # bang out (and don't pass on) if date is invalid or the spot is too old
 129
 130                         # strip off the leading & trailing spaces from the comment
 131                         my $text = unpad($field[5]);
 132
 133                         # store it away
 134                         my $spotter = $field[6];
 135                         $spotter =~ s/-\d+$//o; # strip off the ssid from the spotter
 136
 137                         # do some de-duping
 138                         my $dupkey = "$field[1]$field[2]$d$text$field[6]";
 139                         return if $dup{$dupkey};
 140                         $dup{$dupkey} = $d;
 141
 142                         my $spot = Spot::add($field[1], $field[2], $d, $text, $spotter);
 143
 144                         # send orf to the users
 145                         if ($spot && $pcno == 11) {
 146                                 my $buf = Spot::formatb($field[1], $field[2], $d, $text, $spotter);
 147                                 broadcast_users("$buf\a\a");
 148                         }
 149
 150                         last SWITCH;
 151                 }
 152
 153                 if ($pcno == 12) {              # announces
 154
 155                         if ($field[2] eq '*' || $field[2] eq $main::mycall) {
 156
 157                                 # strip leading and trailing stuff
 158                                 my $text = unpad($field[3]);
 159                                 my $target;
 160                                 my $to = 'To ';
 161                                 my @list;
 162
 163                                 if ($field[4] eq '*') { # sysops
 164                                         $target = "SYSOP";
 165                                         @list = map { $_->priv >= 5 ? $_ : () } get_all_users();
 166                                 } elsif ($field[4] gt ' ') { # speciality list handling
 167                                         my ($name) = split /\./, $field[4];
 168                                         $target = "$name"; # put the rest in later (if bothered)
 169                                 }
 170
 171                                 if ($field[6] eq '1') {
 172                                         $target = "WX";
 173                                         $to = '';
 174                                 }
 175                                 $target = "All" if !$target;
 176
 177                                 if (@list > 0) {
 178                                         broadcast_list("$to$target de $field[1]: $text", @list);
 179                                 } else {
 180                                         broadcast_users("$target de $field[1]: $text");
 181                                 }
 182                                 Log('ann', $target, $field[1], $text);
 183
 184                                 return if $field[2] eq $main::mycall; # it's routed to me
 185                         } else {
 186                                 route($field[2], $line);
 187                                 return;                 # only on a routed one
 188                         }
 189
 190                         last SWITCH;
 191                 }
 192
 193                 if ($pcno == 13) {
 194                         last SWITCH;
 195                 }
 196                 if ($pcno == 14) {
 197                         last SWITCH;
 198                 }
 199                 if ($pcno == 15) {
 200                         last SWITCH;
 201                 }
 202
 203                 if ($pcno == 16) {              # add a user
 204                         my $node = DXCluster->get_exact($field[1]);
 205                         last SWITCH if !$node; # ignore if havn't seen a PC19 for this one yet
 206                         my $i;
 207
 208
 209                         for ($i = 2; $i < $#field; $i++) {
 210                                 my ($call, $confmode, $here) = $field[$i] =~ /^(\S+) (-) (\d)/o;
 211                                 next if length $call < 3;
 212                                 next if !$confmode;
 213                                 $call = uc $call;
 214                                 next if DXCluster->get_exact($call); # we already have this (loop?)
 215
 216                                 $confmode = $confmode eq '*';
 217                                 DXNodeuser->new($self, $node, $call, $confmode, $here);
 218
 219                                 # add this station to the user database, if required
 220                                 $call =~ s/-\d+$//o;        # remove ssid for users
 221                                 my $user = DXUser->get_current($call);
 222                                 $user = DXUser->new($call) if !$user;
 223                                 $user->homenode($node->call) if !$user->homenode;
 224                                 $user->node($node->call);
 225                                 $user->lastin($main::systime);
 226                                 $user->put;
 227                         }
 228
 229                         # queue up any messages (look for privates only)
 230                         DXMsg::queue_msg(1) if $self->state eq 'normal';
 231                         last SWITCH;
 232                 }
 233
 234                 if ($pcno == 17) {              # remove a user
 235
 236                         my $ref = DXCluster->get_exact($field[1]);
 237                         $ref->del() if $ref;
 238                         last SWITCH;
 239                 }
 240
 241                 if ($pcno == 18) {              # link request
 242                         $self->send_local_config();
 243                         $self->send(pc20());
 244                         $self->state('init');
 245                         last SWITCH;
 246                 }
 247
 248                 if ($pcno == 19) {              # incoming cluster list
 249                         my $i;
 250                         for ($i = 1; $i < $#field-1; $i += 4) {
 251                                 my $here = $field[$i];
 252                                 my $call = uc $field[$i+1];
 253                                 my $confmode = $field[$i+2] eq '*';
 254                                 my $ver = $field[$i+3];
 255
 256                                 # now check the call over
 257                                 next if DXCluster->get_exact($call); # we already have this
 258
 259                                 # check for sane parameters
 260                                 next if $ver < 5000; # only works with version 5 software
 261                                 next if length $call < 3; # min 3 letter callsigns
 262                                 DXNode->new($self, $call, $confmode, $here, $ver);
 263
 264                                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 265                                 my $mref = DXMsg::get_busy($call);
 266                                 $mref->stop_msg($self) if $mref;
 267
 268                                 # add this station to the user database, if required (don't remove SSID from nodes)
 269                                 my $user = DXUser->get_current($call);
 270                                 if (!$user) {
 271                                         $user = DXUser->new($call);
 272                                         $user->sort('A');
 273                                         $user->priv(1);                   # I have relented and defaulted nodes
 274                                         $self->{priv} = 1;                # to user RCMDs allowed
 275                                         $user->homenode($call);
 276                                         $user->node($call);
 277                                 }
 278                                 $user->lastin($main::systime);
 279                                 $user->put;
 280                         }
 281
 282                         # queue up any messages
 283                         DXMsg::queue_msg() if $self->state eq 'normal';
 284                         last SWITCH;
 285                 }
 286
 287                 if ($pcno == 20) {              # send local configuration
 288                         $self->send_local_config();
 289                         $self->send(pc22());
 290                         $self->state('normal');
 291
 292                         # queue mail
 293                         DXMsg::queue_msg();
 294                         return;
 295                 }
 296
 297                 if ($pcno == 21) {              # delete a cluster from the list
 298                         my $call = uc $field[1];
 299                         if ($call ne $main::mycall) { # don't allow malicious buggers to disconnect me!
 300                                 my $ref = DXCluster->get_exact($call);
 301                                 $ref->del() if $ref;
 302                         }
 303                         last SWITCH;
 304                 }
 305
 306                 if ($pcno == 22) {
 307                         $self->state('normal');
 308
 309                         # queue mail
 310                         DXMsg::queue_msg();
 311                         return;
 312                 }
 313
 314                 if ($pcno == 23 || $pcno == 27) { # WWV info
 315                         Geomag::update(@field[1..$#field]);
 316                         last SWITCH;
 317                 }
 318
 319                 if ($pcno == 24) {              # set here status
 320                         my $call = uc $field[1];
 321                         my $ref = DXCluster->get_exact($call);
 322                         $ref->here($field[2]) if $ref;
 323                         last SWITCH;
 324                 }
 325
 326                 if ($pcno == 25) {
 327                         last SWITCH;
 328                 }
 329
 330                 if (($pcno >= 28 && $pcno <= 33) || $pcno == 40 || $pcno == 42 || $pcno == 49) { # mail/file handling
 331                         DXMsg::process($self, $line);
 332                         return;
 333                 }
 334
 335                 if ($pcno == 34 || $pcno == 36) { # remote commands (incoming)
 336                         if ($field[1] eq $main::mycall) {
 337                                 my $ref = DXUser->get_current($field[2]);
 338                                 Log('rcmd', 'in', $ref->{priv}, $field[2], $field[3]);
 339                                 unless ($field[3] =~ /rcmd/i) {    # not allowed to relay RCMDS!
 340                                         if ($ref->{priv}) {     # you have to have SOME privilege, the commands have further filtering
 341                                                 $self->{remotecmd} = 1; # for the benefit of any command that needs to know
 342                                                 my @in = (DXCommandmode::run_cmd($self, $field[3]));
 343                                                 for (@in) {
 344                                                         s/\s*$//og;
 345                                                         $self->send(pc35($main::mycall, $field[2], "$main::mycall:$_"));
 346                                                         Log('rcmd', 'out', $field[2], $_);
 347                                                 }
 348                                                 delete $self->{remotecmd};
 349                                         }
 350                                 } else {
 351                                         $self->send(pc35($main::mycall, $field[2], "$main::mycall:Tut tut tut...!"));
 352                                 }
 353                         } else {
 354                                 route($field[1], $line);
 355                         }
 356                         return;
 357                 }
 358
 359                 if ($pcno == 35) {              # remote command replies
 360                         if ($field[1] eq $main::mycall) {
 361                                 my $s = $rcmds{$field[2]};
 362                                 if ($s) {
 363                                         my $dxchan = DXChannel->get($s->{call});
 364                                         $dxchan->send($field[3]) if $dxchan;
 365                                         delete $rcmds{$field[2]} if !$dxchan;
 366                                 }
 367                         } else {
 368                                 route($field[1], $line);
 369                         }
 370                         return;
 371                 }
 372
 373                 if ($pcno == 37) {
 374                         last SWITCH;
 375                 }
 376
 377                 if ($pcno == 38) {              # node connected list from neighbour
 378                         return;
 379                 }
 380
 381                 if ($pcno == 39) {              # incoming disconnect
 382                         $self->disconnect();
 383                         return;
 384                 }
 385
 386                 if ($pcno == 41) {              # user info
 387                         # add this station to the user database, if required
 388                         my $user = DXUser->get_current($field[1]);
 389                         if (!$user) {
 390                                 # then try without an SSID
 391                                 $field[1] =~ s/-\d+$//o;
 392                                 $user = DXUser->get_current($field[1]);
 393                         }
 394                         $user = DXUser->new($field[1]) if !$user;
 395
 396                         if ($field[2] == 1) {
 397                                 $user->name($field[3]);
 398                         } elsif ($field[2] == 2) {
 399                                 $user->qth($field[3]);
 400                         } elsif ($field[2] == 3) {
 401                                 my ($lat, $long) = DXBearing::stoll($field[3]);
 402                                 $user->lat($lat);
 403                                 $user->long($long);
 404                         } elsif ($field[2] == 4) {
 405                                 $user->homenode($field[3]);
 406                         }
 407                         $user->put;
 408                         last SWITCH;
 409                 }
 410                 if ($pcno == 43) {
 411                         last SWITCH;
 412                 }
 413                 if ($pcno == 44) {
 414                         last SWITCH;
 415                 }
 416                 if ($pcno == 45) {
 417                         last SWITCH;
 418                 }
 419                 if ($pcno == 46) {
 420                         last SWITCH;
 421                 }
 422                 if ($pcno == 47) {
 423                         last SWITCH;
 424                 }
 425                 if ($pcno == 48) {
 426                         last SWITCH;
 427                 }
 428
 429                 if ($pcno == 50) {              # keep alive/user list
 430                         my $ref = DXCluster->get_exact($field[1]);
 431                         $ref->update_users($field[2]) if $ref;
 432                         last SWITCH;
 433                 }
 434
 435                 if ($pcno == 51) {              # incoming ping requests/answers
 436
 437                         # is it for us?
 438                         if ($field[1] eq $main::mycall) {
 439                                 my $flag = $field[3];
 440                                 if ($flag == 1) {
 441                                         $self->send(pc51($field[2], $field[1], '0'));
 442                                 } else {
 443                                         # it's a reply, look in the ping list for this one
 444                                         my $ref = $pings{$field[2]};
 445                                         if ($ref) {
 446                                                 my $r = shift @$ref;
 447                                                 my $dxchan = DXChannel->get($r->{call});
 448                                                 $dxchan->send($dxchan->msg('pingi', $field[2], atime($main::systime), $main::systime - $r->{t})) if $dxchan;
 449                                         }
 450                                 }
 451
 452                         } else {
 453                                 # route down an appropriate thingy
 454                                 route($field[1], $line);
 455                         }
 456                         return;
 457                 }
 458         }
 459
 460          # if get here then rebroadcast the thing with its Hop count decremented (if
 461          # there is one). If it has a hop count and it decrements to zero then don't
 462          # rebroadcast it.
 463          #
 464          # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
 465          #        REBROADCAST!!!!
 466          #
 467
 468          my $hops;
 469         if (($hops) = $line =~ /H(\d+)\^\~?$/o) {
 470                 my $newhops = $hops - 1;
 471                 if ($newhops > 0) {
 472                         $line =~ s/\^H$hops(\^\~?)$/\^H$newhops$1/;     # change the hop count
 473                         broadcast_ak1a($line, $self); # send it to everyone but me
 474                 }
 475         }
 476 }
 477
 478 #
 479 # This is called from inside the main cluster processing loop and is used
 480 # for despatching commands that are doing some long processing job
 481 #
 482 sub process
 483 {
 484         my $t = time;
 485         my @chan = DXChannel->get_all();
 486         my $chan;
 487
 488         foreach $chan (@chan) {
 489                 next if !$chan->is_ak1a();
 490
 491                 # send a pc50 out on this channel
 492                 if ($t >= $chan->pc50_t + $DXProt::pc50_interval) {
 493                         $chan->send(pc50());
 494                         $chan->pc50_t($t);
 495                 }
 496         }
 497
 498         my $key;
 499         my $val;
 500         my $cutoff;
 501         if ($main::systime - 3600 > $last_hour) {
 502                 $cutoff  = $main::systime - $pc11_dup_age;
 503                 while (($key, $val) = each %dup) {
 504                         delete $dup{$key} if $val < $cutoff;
 505                 }
 506                 $last_hour = $main::systime;
 507         }
 508 }
 509
 510 #
 511 # finish up a pc context
 512 #
 513 sub finish
 514 {
 515         my $self = shift;
 516         my $call = $self->call;
 517         my $ref = DXCluster->get_exact($call);
 518
 519         # unbusy and stop and outgoing mail
 520         my $mref = DXMsg::get_busy($call);
 521         $mref->stop_msg($self) if $mref;
 522
 523         # broadcast to all other nodes that all the nodes connected to via me are gone
 524         my @gonenodes = map { $_->dxchan == $self ? $_ : () } DXNode::get_all();
 525         my $node;
 526
 527         foreach $node (@gonenodes) {
 528                 next if $node->call eq $call;
 529                 broadcast_ak1a(pc21($node->call, 'Gone'), $self); # done like this 'cos DXNodes don't have a pc21 method
 530                 $node->del();
 531         }
 532
 533         # remove outstanding pings
 534         delete $pings{$call};
 535
 536         # now broadcast to all other ak1a nodes that I have gone
 537         broadcast_ak1a(pc21($call, 'Gone.'), $self);
 538
 539         Log('DXProt', $call . " Disconnected");
 540         $ref->del() if $ref;
 541 }
 542
 543 #
 544 # some active measures
 545 #
 546
 547 sub send_local_config
 548 {
 549         my $self = shift;
 550         my $n;
 551
 552         # send our nodes
 553         my @nodes = DXNode::get_all();
 554
 555         # create a list of all the nodes that are not connected to this connection
 556         @nodes = grep { $_->dxchan != $self } @nodes;
 557         $self->send($me->pc19(@nodes));
 558
 559         # get all the users connected on the above nodes and send them out
 560         foreach $n (@nodes) {
 561                 my @users = values %{$n->list};
 562                 $self->send(DXProt::pc16($n, @users));
 563         }
 564 }
 565
 566 #
 567 # route a message down an appropriate interface for a callsign
 568 #
 569 # is called route(to, pcline);
 570 #
 571 sub route
 572 {
 573         my ($call, $line) = @_;
 574         my $cl = DXCluster->get_exact($call);
 575         if ($cl) {
 576                 my $hops;
 577                 my $dxchan = $cl->{dxchan};
 578                 if (($hops) = $line =~ /H(\d+)\^\~?$/o) {
 579                         my $newhops = $hops - 1;
 580                         if ($newhops > 0) {
 581                                 $line =~ s/\^H$hops(\^\~?)$/\^H$newhops$1/;     # change the hop count
 582                                 $dxchan->send($line) if $dxchan;
 583                         }
 584                 } else {
 585                         $dxchan->send($line) if $dxchan; # for them wot don't have Hops
 586                 }
 587         }
 588 }
 589
 590 # broadcast a message to all clusters [except those mentioned after buffer]
 591 sub broadcast_ak1a
 592 {
 593         my $s = shift;                          # the line to be rebroadcast
 594         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 595         my @chan = get_all_ak1a();
 596         my $chan;
 597
 598         foreach $chan (@chan) {
 599                 next if grep $chan == $_, @except;
 600                 $chan->send($s);                # send it if it isn't the except list
 601         }
 602 }
 603
 604 # broadcast to all users
 605 sub broadcast_users
 606 {
 607         my $s = shift;                          # the line to be rebroadcast
 608         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 609         my @chan = get_all_users();
 610         my $chan;
 611
 612         foreach $chan (@chan) {
 613                 next if grep $chan == $_, @except;
 614                 $s =~ s/\a//og if !$chan->{beep};
 615                 $chan->send($s);                # send it if it isn't the except list
 616         }
 617 }
 618
 619 # broadcast to a list of users
 620 sub broadcast_list
 621 {
 622         my $s = shift;
 623         my $chan;
 624
 625         foreach $chan (@_) {
 626                 $chan->send($s);                # send it
 627         }
 628 }
 629
 630 #
 631 # gimme all the ak1a nodes
 632 #
 633 sub get_all_ak1a
 634 {
 635         my @list = DXChannel->get_all();
 636         my $ref;
 637         my @out;
 638         foreach $ref (@list) {
 639                 push @out, $ref if $ref->is_ak1a;
 640         }
 641         return @out;
 642 }
 643
 644 # return a list of all users
 645 sub get_all_users
 646 {
 647         my @list = DXChannel->get_all();
 648         my $ref;
 649         my @out;
 650         foreach $ref (@list) {
 651                 push @out, $ref if $ref->is_user;
 652         }
 653         return @out;
 654 }
 655
 656 # return a list of all user callsigns
 657 sub get_all_user_calls
 658 {
 659         my @list = DXChannel->get_all();
 660         my $ref;
 661         my @out;
 662         foreach $ref (@list) {
 663                 push @out, $ref->call if $ref->is_user;
 664         }
 665         return @out;
 666 }
 667
 668 #
 669 # obtain the hops from the list for this callsign and pc no
 670 #
 671
 672 sub get_hops
 673 {
 674         my ($pcno) = @_;
 675         my $hops = $DXProt::hopcount{$pcno};
 676         $hops = $DXProt::def_hopcount if !$hops;
 677         return "H$hops";
 678 }
 679
 680 # remove leading and trailing spaces from an input string
 681 sub unpad
 682 {
 683         my $s = shift;
 684         $s =~ s/^\s+|\s+$//;
 685         return $s;
 686 }
 687
 688 # add a ping request to the ping queues
 689 sub addping
 690 {
 691         my ($from, $to) = @_;
 692         my $ref = $pings{$to};
 693         $ref = $pings{$to} = [] if !$ref;
 694         my $r = {};
 695         $r->{call} = $from;
 696         $r->{t} = $main::systime;
 697         route($to, pc51($to, $main::mycall, 1));
 698         push @$ref, $r;
 699 }
 700
 701 # add a rcmd request to the rcmd queues
 702 sub addrcmd
 703 {
 704         my ($from, $to, $cmd) = @_;
 705         my $r = {};
 706         $r->{call} = $from;
 707         $r->{t} = $main::systime;
 708         $r->{cmd} = $cmd;
 709         route($to, pc34($main::mycall, $to, $cmd));
 710         $rcmds{$to} = $r;
 711 }
 712 1;
 713 __END__