perl/DXCommandmode.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the user facing command mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 # $Id$
   8 #
   9
  10 package DXCommandmode;
  11
  12 use POSIX;
  13
  14 @ISA = qw(DXChannel);
  15
  16 use DXUtil;
  17 use DXChannel;
  18 use DXUser;
  19 use DXVars;
  20 use DXDebug;
  21 use DXM;
  22 use DXLog;
  23 use DXLogPrint;
  24 use DXBearing;
  25 use CmdAlias;
  26 use Filter;
  27 use Minimuf;
  28 use DXDb;
  29 use AnnTalk;
  30 use WCY;
  31 use Sun;
  32 use Internet;
  33 use Script;
  34 use Net::Telnet;
  35 use QSL;
  36 use DB_File;
  37 use VE7CC;
  38 use Thingy;
  39 use Thingy::Dx;
  40 use Thingy::Hello;
  41 use Thingy::Bye;
  42
  43 use strict;
  44 use vars qw(%Cache %cmd_cache $errstr %aliases $scriptbase $maxerrors %nothereslug $maxbadcount $msgpolltime);
  45
  46 %Cache = ();                                    # cache of dynamically loaded routine's mod times
  47 %cmd_cache = ();                                # cache of short names
  48 $errstr = ();                                   # error string from eval
  49 %aliases = ();                                  # aliases for (parts of) commands
  50 $scriptbase = "$main::root/scripts"; # the place where all users start scripts go
  51 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
  52 $maxbadcount = 3;                               # no of bad words allowed before disconnection
  53 $msgpolltime = 3600;                    # the time between polls for new messages
  54
  55
  56 use vars qw($VERSION $BRANCH);
  57
  58 main::mkver($VERSION = q$Revision$);
  59
  60 #
  61 # obtain a new connection this is derived from dxchannel
  62 #
  63
  64 sub new
  65 {
  66         my $self = DXChannel::alloc(@_);
  67
  68         # routing, this must go out here to prevent race condx
  69         my $pkg = shift;
  70         my $call = shift;
  71         my @rout = $main::routeroot->add_user($call, 1);
  72
  73
  74         my $ref = Route::User::get($call);
  75         $main::me->route_pc16($main::mycall, undef, $main::routeroot, $ref) if $ref;
  76         return $self;
  77 }
  78
  79 # this is how a a connection starts, you get a hello message and the motd with
  80 # possibly some other messages asking you to set various things up if you are
  81 # new (or nearly new and slacking) user.
  82
  83 sub start
  84 {
  85         my ($self, $line, $sort) = @_;
  86         my $user = $self->{user};
  87         my $call = $self->{call};
  88         my $name = $user->{name};
  89
  90         # log it
  91         my $host = $self->{conn}->{peerhost} || "unknown";
  92         Log('DXCommand', "$call connected from $host");
  93
  94         $self->{name} = $name ? $name : $call;
  95         $self->send($self->msg('l2',$self->{name}));
  96         $self->state('prompt');         # a bit of room for further expansion, passwords etc
  97         $self->{priv} = $user->priv || 0;
  98         $self->{lang} = $user->lang || $main::lang || 'en';
  99         $self->{pagelth} = $user->pagelth || 20;
 100         ($self->{width}) = $line =~ /width=(\d+)/; $line =~ s/\s*width=\d+\s*//;
 101         $self->{width} = 80 unless $self->{width} && $self->{width} > 80;
 102         $self->{consort} = $line;       # save the connection type
 103
 104         # set some necessary flags on the user if they are connecting
 105         $self->{beep} = $user->wantbeep;
 106         $self->{ann} = $user->wantann;
 107         $self->{wwv} = $user->wantwwv;
 108         $self->{wcy} = $user->wantwcy;
 109         $self->{talk} = $user->wanttalk;
 110         $self->{wx} = $user->wantwx;
 111         $self->{dx} = $user->wantdx;
 112         $self->{logininfo} = $user->wantlogininfo;
 113         $self->{ann_talk} = $user->wantann_talk;
 114         $self->{here} = 1;
 115         $self->{prompt} = $user->prompt if $user->prompt;
 116
 117         # sort out new dx spot stuff
 118         $user->wantdxcq(0) unless defined $user->{wantdxcq};
 119         $user->wantdxitu(0) unless defined $user->{wantdxitu};
 120         $user->wantusstate(0) unless defined $user->{wantusstate};
 121
 122         # sort out registration
 123         if ($main::reqreg == 1) {
 124                 $self->{registered} = $user->registered;
 125         } elsif ($main::reqreg == 2) {
 126                 $self->{registered} = !$user->registered;
 127         } else {
 128                 $self->{registered} = 1;
 129         }
 130
 131
 132         # decide which motd to send
 133         my $motd;
 134         unless ($self->{registered}) {
 135                 $motd = "${main::motd}_nor_$self->{lang}";
 136                 $motd = "${main::motd}_nor" unless -e $motd;
 137         }
 138         $motd = "${main::motd}_$self->{lang}" unless $motd && -e $motd;
 139         $motd = $main::motd unless $motd && -e $motd;
 140         $self->send_file($motd) if -e $motd;
 141
 142         # sort out privilege reduction
 143         $self->{priv} = 0 if $line =~ /^(ax|te)/ && !$self->conn->{usedpasswd};
 144
 145         # get the filters
 146         $self->{spotsfilter} = Filter::read_in('spots', $call, 0) || Filter::read_in('spots', 'user_default', 0);
 147         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0) || Filter::read_in('wwv', 'user_default', 0);
 148         $self->{wcyfilter} = Filter::read_in('wcy', $call, 0) || Filter::read_in('wcy', 'user_default', 0);
 149         $self->{annfilter} = Filter::read_in('ann', $call, 0) || Filter::read_in('ann', 'user_default', 0) ;
 150
 151         # clean up qra locators
 152         my $qra = $user->qra;
 153         $qra = undef if ($qra && !DXBearing::is_qra($qra));
 154         unless ($qra) {
 155                 my $lat = $user->lat;
 156                 my $long = $user->long;
 157                 $user->qra(DXBearing::lltoqra($lat, $long)) if (defined $lat && defined $long);
 158         }
 159
 160         # decide on echo
 161         my $echo = $user->wantecho;
 162         unless ($echo) {
 163                 $self->send_now('E', "0");
 164                 $self->send($self->msg('echow'));
 165                 $self->conn->echo($echo) if $self->conn->can('echo');
 166         }
 167
 168         $self->tell_login('loginu');
 169
 170         # do we need to send a forward/opernam?
 171         my $lastoper = $user->lastoper || 0;
 172         my $homenode = $user->homenode || "";
 173         if ($homenode eq $main::mycall && $main::systime >= $lastoper + $DXUser::lastoperinterval) {
 174                 run_cmd($main::me, "forward/opernam $call");
 175                 $user->lastoper($main::systime + ((int rand(10)) * 86400));
 176         }
 177
 178         # ALWAYS output the user
 179         my $thing = Thingy::Hello->new(user => $call, h => $self->{here});
 180         $thing->broadcast($self);
 181         $self->lasthello($main::systime);
 182
 183         # run a script send the output to the punter
 184         my $script = new Script(lc $call) || new Script('user_default');
 185         $script->run($self) if $script;
 186
 187         # send cluster info
 188         my $info = Route::cluster();
 189         $self->send("Cluster:$info");
 190
 191         # send prompts and things
 192         $self->send($self->msg('namee1')) if !$user->name;
 193         $self->send($self->msg('qthe1')) if !$user->qth;
 194         $self->send($self->msg('qll')) if !$user->qra || (!$user->lat && !$user->long);
 195         $self->send($self->msg('hnodee1')) if !$user->qth;
 196         $self->send($self->msg('m9')) if DXMsg::for_me($call);
 197         $self->lastmsgpoll($main::systime);
 198         $self->prompt;
 199 }
 200
 201 #
 202 # This is the normal command prompt driver
 203 #
 204
 205 sub normal
 206 {
 207         my $self = shift;
 208         my $cmdline = shift;
 209         my @ans;
 210
 211         # save this for them's that need it
 212         my $rawline = $cmdline;
 213
 214         # remove leading and trailing spaces
 215         $cmdline =~ s/^\s*(.*)\s*$/$1/;
 216
 217         if ($self->{state} eq 'page') {
 218                 my $i = $self->{pagelth};
 219                 my $ref = $self->{pagedata};
 220                 my $tot = @$ref;
 221
 222                 # abort if we get a line starting in with a
 223                 if ($cmdline =~ /^a/io) {
 224                         undef $ref;
 225                         $i = 0;
 226                 }
 227
 228                 # send a tranche of data
 229                 while ($i-- > 0 && @$ref) {
 230                         my $line = shift @$ref;
 231                         $line =~ s/\s+$//o;     # why am having to do this?
 232                         $self->send($line);
 233                 }
 234
 235                 # reset state if none or else chuck out an intermediate prompt
 236                 if ($ref && @$ref) {
 237                         $tot -= $self->{pagelth};
 238                         $self->send($self->msg('page', $tot));
 239                 } else {
 240                         $self->state('prompt');
 241                 }
 242         } elsif ($self->{state} eq 'sysop') {
 243                 my $passwd = $self->{user}->passwd;
 244                 if ($passwd) {
 245                         my @pw = grep {$_ !~ /\s/} split //, $passwd;
 246                         my @l = @{$self->{passwd}};
 247                         my $str = "$pw[$l[0]].*$pw[$l[1]].*$pw[$l[2]].*$pw[$l[3]].*$pw[$l[4]]";
 248                         if ($cmdline =~ /$str/) {
 249                                 $self->{priv} = $self->{user}->priv;
 250                         } else {
 251                                 $self->send($self->msg('sorry'));
 252                         }
 253                 } else {
 254                         $self->send($self->msg('sorry'));
 255                 }
 256                 $self->state('prompt');
 257         } elsif ($self->{state} eq 'passwd') {
 258                 my $passwd = $self->{user}->passwd;
 259                 if ($passwd && $cmdline eq $passwd) {
 260                         $self->send($self->msg('pw1'));
 261                         $self->state('passwd1');
 262                 } else {
 263                         $self->conn->{echo} = $self->conn->{decho};
 264                         delete $self->conn->{decho};
 265                         $self->send($self->msg('sorry'));
 266                         $self->state('prompt');
 267                 }
 268         } elsif ($self->{state} eq 'passwd1') {
 269                 $self->{passwd} = $cmdline;
 270                 $self->send($self->msg('pw2'));
 271                 $self->state('passwd2');
 272         } elsif ($self->{state} eq 'passwd2') {
 273                 if ($cmdline eq $self->{passwd}) {
 274                         $self->{user}->passwd($cmdline);
 275                         $self->send($self->msg('pw3'));
 276                 } else {
 277                         $self->send($self->msg('pw4'));
 278                 }
 279                 $self->conn->{echo} = $self->conn->{decho};
 280                 delete $self->conn->{decho};
 281                 $self->state('prompt');
 282         } elsif ($self->{state} eq 'talk') {
 283                 if ($cmdline =~ m{^(?:/EX|/ABORT)}i) {
 284                         for (@{$self->{talklist}}) {
 285                                 $self->send_talks($_,  $self->msg('talkend'));
 286                         }
 287                         $self->state('prompt');
 288                         delete $self->{talklist};
 289                 } elsif ($cmdline =~ m|^/+\w+|) {
 290                         $cmdline =~ s|^/||;
 291                         my $sendit = $cmdline =~ s|^/+||;
 292                         my @in = $self->run_cmd($cmdline);
 293                         $self->send_ans(@in);
 294                         if ($sendit && $self->{talklist} && @{$self->{talklist}}) {
 295                                 foreach my $l (@in) {
 296                                         my @bad;
 297                                         if (@bad = BadWords::check($l)) {
 298                                                 $self->badcount(($self->badcount||0) + @bad);
 299                                                 Log('DXCommand', "$self->{call} swore: $l");
 300                                         } else {
 301                                                 for (@{$self->{talklist}}) {
 302                                                         $self->send_talks($_, $l);
 303                                                 }
 304                                         }
 305                                 }
 306                         }
 307                         $self->send($self->talk_prompt);
 308                 } elsif ($self->{talklist} && @{$self->{talklist}}) {
 309                         # send what has been said to whoever is in this person's talk list
 310                         my @bad;
 311                         if (@bad = BadWords::check($cmdline)) {
 312                                 $self->badcount(($self->badcount||0) + @bad);
 313                                 Log('DXCommand', "$self->{call} swore: $cmdline");
 314                         } else {
 315                                 for (@{$self->{talklist}}) {
 316                                         $self->send_talks($_, $rawline);
 317                                 }
 318                         }
 319                         $self->send($self->talk_prompt) if $self->{state} eq 'talk';
 320                 } else {
 321                         # for safety
 322                         $self->state('prompt');
 323                 }
 324         } elsif (my $func = $self->{func}) {
 325                 no strict 'refs';
 326                 my @ans;
 327                 if (ref $self->{edit}) {
 328                         eval { @ans = $self->{edit}->$func($self, $rawline)};
 329                 } else {
 330                         eval {  @ans = &{$self->{func}}($self, $rawline) };
 331                 }
 332                 if ($@) {
 333                         $self->send_ans("Syserr: on stored func $self->{func}", $@);
 334                         delete $self->{func};
 335                         $self->state('prompt');
 336                         undef $@;
 337                 }
 338                 $self->send_ans(@ans);
 339         } else {
 340                 $self->send_ans(run_cmd($self, $cmdline));
 341         }
 342
 343         # check for excessive swearing
 344         if ($self->{badcount} && $self->{badcount} >= $maxbadcount) {
 345                 Log('DXCommand', "$self->{call} logged out for excessive swearing");
 346                 $self->disconnect;
 347                 return;
 348         }
 349
 350         # send a prompt only if we are in a prompt state
 351         $self->prompt() if $self->{state} =~ /^prompt/o;
 352 }
 353
 354 # send out the talk messages taking into account vias and connectivity
 355 sub send_talks
 356 {
 357         my ($self, $ent, $line) = @_;
 358
 359         my ($to, $via) = $ent =~ /(\S+)>(\S+)/;
 360         $to = $ent unless $to;
 361         my $call = $via ? $via : $to;
 362         my $clref = Route::get($call);
 363         my $dxchan = $clref->dxchan if $clref;
 364         if ($dxchan) {
 365                 $dxchan->talk($self->{call}, $to, $via, $line);
 366         } else {
 367                 $self->send($self->msg('disc2', $via ? $via : $to));
 368                 my @l = grep { $_ ne $ent } @{$self->{talklist}};
 369                 if (@l) {
 370                         $self->{talklist} = \@l;
 371                 } else {
 372                         delete $self->{talklist};
 373                         $self->state('prompt');
 374                 }
 375         }
 376 }
 377
 378 sub talk_prompt
 379 {
 380         my $self = shift;
 381         my @call;
 382         for (@{$self->{talklist}}) {
 383                 my ($to, $via) = /(\S+)>(\S+)/;
 384                 $to = $_ unless $to;
 385                 push @call, $to;
 386         }
 387         return $self->msg('talkprompt', join(',', @call));
 388 }
 389
 390 #
 391 # send a load of stuff to a command user with page prompting
 392 # and stuff
 393 #
 394
 395 sub send_ans
 396 {
 397         my $self = shift;
 398
 399         if ($self->{pagelth} && @_ > $self->{pagelth}) {
 400                 my $i;
 401                 for ($i = $self->{pagelth}; $i-- > 0; ) {
 402                         my $line = shift @_;
 403                         $line =~ s/\s+$//o;     # why am having to do this?
 404                         $self->send($line);
 405                 }
 406                 $self->{pagedata} =  [ @_ ];
 407                 $self->state('page');
 408                 $self->send($self->msg('page', scalar @_));
 409         } else {
 410                 for (@_) {
 411                         if (defined $_) {
 412                                 $self->send($_);
 413                         } else {
 414                                 $self->send('');
 415                         }
 416                 }
 417         }
 418 }
 419 #
 420 # this is the thing that runs the command, it is done like this for the
 421 # benefit of remote command execution
 422 #
 423
 424 sub run_cmd
 425 {
 426         my $self = shift;
 427         my $user = $self->{user};
 428         my $call = $self->{call};
 429         my $cmdline = shift;
 430         my @ans;
 431
 432
 433         return () if length $cmdline == 0;
 434
 435         # split the command line up into parts, the first part is the command
 436         my ($cmd, $args) = split /\s+/, $cmdline, 2;
 437         $args = "" unless defined $args;
 438
 439         if ($cmd) {
 440                 # strip out // on command only
 441                 $cmd =~ s|//|/|g;
 442
 443                 my ($path, $fcmd);
 444
 445                 dbg("cmd: $cmd") if isdbg('command');
 446
 447                 # alias it if possible
 448                 my $acmd = CmdAlias::get_cmd($cmd);
 449                 if ($acmd) {
 450                         ($cmd, $args) = split /\s+/, "$acmd $args", 2;
 451                         $args = "" unless defined $args;
 452                         dbg("aliased cmd: $cmd $args") if isdbg('command');
 453                 }
 454
 455                 # first expand out the entry to a command
 456                 ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 457                 ($path, $fcmd) = search($main::cmd, $cmd, "pl") if !$path || !$fcmd;
 458
 459                 if ($path && $cmd) {
 460                         dbg("path: $cmd cmd: $fcmd") if isdbg('command');
 461
 462                         my $package = find_cmd_name($path, $fcmd);
 463                         return ($@) if $@;
 464
 465                         if ($package) {
 466                                 no strict 'refs';
 467                                 dbg("package: $package") if isdbg('command');
 468                                 eval { @ans = &$package($self, $args) };
 469                                 return (DXDebug::shortmess($@)) if $@;
 470                         }
 471                 } else {
 472                         dbg("cmd: $cmd not found") if isdbg('command');
 473                         if (++$self->{errors} > $maxerrors) {
 474                                 $self->send($self->msg('e26'));
 475                                 $self->disconnect;
 476                                 return ();
 477                         } else {
 478                                 return ($self->msg('e1'));
 479                         }
 480                 }
 481         }
 482
 483         my $ok = shift @ans;
 484         if ($ok) {
 485                 delete $self->{errors};
 486         } else {
 487                 if (++$self->{errors} > $maxerrors) {
 488                         $self->send($self->msg('e26'));
 489                         $self->disconnect;
 490                         return ();
 491                 }
 492         }
 493         return map {s/([^\s])\s+$/$1/; $_} @ans;
 494 }
 495
 496 #
 497 # This is called from inside the main cluster processing loop and is used
 498 # for despatching commands that are doing some long processing job
 499 #
 500 sub process
 501 {
 502         my $t = time;
 503         my @dxchan = DXChannel::get_all();
 504         my $dxchan;
 505
 506         foreach $dxchan (@dxchan) {
 507                 next if $dxchan->sort ne 'U';
 508
 509                 # send a outstanding message prompt if required
 510                 if ($t >= $dxchan->lastmsgpoll + $msgpolltime) {
 511                         $dxchan->send($dxchan->msg('m9')) if DXMsg::for_me($dxchan->call);
 512                         $dxchan->lastmsgpoll($t);
 513                 }
 514
 515                 # send a prompt if no activity out on this channel
 516                 if ($t >= $dxchan->t + $main::user_interval) {
 517                         $dxchan->prompt() if $dxchan->{state} =~ /^prompt/o;
 518                         $dxchan->t($t);
 519                 }
 520         }
 521
 522         while (my ($k, $v) = each %nothereslug) {
 523                 if ($main::systime >= $v + 300) {
 524                         delete $nothereslug{$k};
 525                 }
 526         }
 527 }
 528
 529 #
 530 # finish up a user context
 531 #
 532 sub disconnect
 533 {
 534         my $self = shift;
 535         my $call = $self->call;
 536
 537         return if $self->{disconnecting}++;
 538
 539         delete $self->{senddbg};
 540
 541         my $uref = Route::User::get($call);
 542         my @rout;
 543         if ($uref) {
 544                 @rout = $main::routeroot->del_user($uref);
 545                 dbg("B/C PC17 on $main::mycall for: $call") if isdbg('route');
 546
 547                 # issue a pc17 to everybody interested
 548                 $main::me->route_pc17($main::mycall, undef, $main::routeroot, $uref);
 549
 550                 my $thing = Thingy::Bye->new(user=>$call);
 551                 $thing->broadcast($self);
 552         } else {
 553                 confess "trying to disconnect a non existant user $call";
 554         }
 555
 556         # I was the last node visited
 557     $self->user->node($main::mycall);
 558
 559         # send info to all logged in thingies
 560         $self->tell_login('logoutu');
 561
 562         # remove any outstanding pings I have sent
 563         Thingy::Ping::forget($call);
 564
 565         Log('DXCommand', "$call disconnected");
 566
 567         $self->SUPER::disconnect;
 568 }
 569
 570 #
 571 # short cut to output a prompt
 572 #
 573
 574 sub prompt
 575 {
 576         my $self = shift;
 577         my $call = $self->call;
 578         my $date = cldate($main::systime);
 579         my $time = ztime($main::systime);
 580         my $prompt = $self->{prompt} || $self->msg('pr');
 581
 582         $call = "($call)" unless $self->here;
 583         $prompt =~ s/\%C/$call/g;
 584         $prompt =~ s/\%D/$date/g;
 585         $prompt =~ s/\%T/$time/g;
 586         $prompt =~ s/\%M/$main::mycall/g;
 587
 588         $self->send($prompt);
 589 }
 590
 591 # broadcast a message to all users [except those mentioned after buffer]
 592 sub broadcast
 593 {
 594         my $pkg = shift;                        # ignored
 595         my $s = shift;                          # the line to be rebroadcast
 596
 597     foreach my $dxchan (DXChannel::get_all()) {
 598                 next unless $dxchan->{sort} eq 'U'; # only interested in user channels
 599                 next if grep $dxchan == $_, @_;
 600                 $dxchan->send($s);                      # send it
 601         }
 602 }
 603
 604 # gimme all the users
 605 sub get_all
 606 {
 607         return grep {$_->{sort} eq 'U'} DXChannel::get_all();
 608 }
 609
 610 # run a script for this user
 611 sub run_script
 612 {
 613         my $self = shift;
 614         my $silent = shift || 0;
 615
 616 }
 617
 618 #
 619 # search for the command in the cache of short->long form commands
 620 #
 621
 622 sub search
 623 {
 624         my ($path, $short_cmd, $suffix) = @_;
 625         my ($apath, $acmd);
 626
 627         # commands are lower case
 628         $short_cmd = lc $short_cmd;
 629         dbg("command: $path $short_cmd\n") if isdbg('command');
 630
 631         # do some checking for funny characters
 632         return () if $short_cmd =~ /\/$/;
 633
 634         # return immediately if we have it
 635         ($apath, $acmd) = split ',', $cmd_cache{$short_cmd} if $cmd_cache{$short_cmd};
 636         if ($apath && $acmd) {
 637                 dbg("cached $short_cmd = ($apath, $acmd)\n") if isdbg('command');
 638                 return ($apath, $acmd);
 639         }
 640
 641         # if not guess
 642         my @parts = split '/', $short_cmd;
 643         my $dirfn;
 644         my $curdir = $path;
 645         my $p;
 646         my $i;
 647         my @lparts;
 648
 649         for ($i = 0; $i < @parts; $i++) {
 650                 my  $p = $parts[$i];
 651                 opendir(D, $curdir) or confess "can't open $curdir $!";
 652                 my @ls = readdir D;
 653                 closedir D;
 654                 my $l;
 655                 foreach $l (sort @ls) {
 656                         next if $l =~ /^\./;
 657                         if ($i < $#parts) {             # we are dealing with directories
 658                                 if ((-d "$curdir/$l") && $p eq substr($l, 0, length $p)) {
 659                                         dbg("got dir: $curdir/$l\n") if isdbg('command');
 660                                         $dirfn .= "$l/";
 661                                         $curdir .= "/$l";
 662                                         last;
 663                                 }
 664                         } else {                        # we are dealing with commands
 665                                 @lparts = split /\./, $l;
 666                                 next if $lparts[$#lparts] ne $suffix;        # only look for .$suffix files
 667                                 if ($p eq substr($l, 0, length $p)) {
 668                                         pop @lparts; #  remove the suffix
 669                                         $l = join '.', @lparts;
 670                                         #                 chop $dirfn;               # remove trailing /
 671                                         $dirfn = "" unless $dirfn;
 672                                         $cmd_cache{$short_cmd} = join(',', ($path, "$dirfn$l")); # cache it
 673                                         dbg("got path: $path cmd: $dirfn$l\n") if isdbg('command');
 674                                         return ($path, "$dirfn$l");
 675                                 }
 676                         }
 677                 }
 678         }
 679         return ();
 680 }
 681
 682 # clear the command name cache
 683 sub clear_cmd_cache
 684 {
 685         no strict 'refs';
 686
 687         for (keys %Cache) {
 688                 undef *{$_} unless /cmd_cache/;
 689                 dbg("Undefining cmd $_") if isdbg('command');
 690         }
 691         %cmd_cache = ();
 692         %Cache = ();
 693 }
 694
 695 #
 696 # the persistant execution of things from the command directories
 697 #
 698 #
 699 # This allows perl programs to call functions dynamically
 700 #
 701 # This has been nicked directly from the perlembed pages
 702 #
 703
 704 #require Devel::Symdump;
 705
 706 sub valid_package_name {
 707         my($string) = @_;
 708         $string =~ s|([^A-Za-z0-9_/])|sprintf("_%2x",unpack("C",$1))|eg;
 709
 710         $string =~ s|/|_|g;
 711         return "cmd_$string";
 712 }
 713
 714 #
 715 # this bit of magic finds a command in the offered directory
 716 sub find_cmd_name {
 717         my $path = shift;
 718         my $cmdname = shift;
 719         my $package = valid_package_name($cmdname);
 720         my $filename = "$path/$cmdname.pl";
 721         my $mtime = -M $filename;
 722
 723         # return if we can't find it
 724         $errstr = undef;
 725         unless (defined $mtime) {
 726                 $errstr = DXM::msg('e1');
 727                 return undef;
 728         }
 729
 730         if(defined $Cache{$package}->{mtime} &&$Cache{$package}->{mtime} <= $mtime) {
 731                 #we have compiled this subroutine already,
 732                 #it has not been updated on disk, nothing left to do
 733                 #print STDERR "already compiled $package->handler\n";
 734                 ;
 735         } else {
 736
 737                 my $sub = readfilestr($filename);
 738                 unless ($sub) {
 739                         $errstr = "Syserr: can't open '$filename' $!";
 740                         return undef;
 741                 };
 742
 743                 #wrap the code into a subroutine inside our unique package
 744                 my $eval = qq( sub $package { $sub } );
 745
 746                 if (isdbg('eval')) {
 747                         my @list = split /\n/, $eval;
 748                         my $line;
 749                         for (@list) {
 750                                 dbg($_ . "\n") if isdbg('eval');
 751                         }
 752                 }
 753
 754                 # get rid of any existing sub and try to compile the new one
 755                 no strict 'refs';
 756
 757                 if (exists $Cache{$package}) {
 758                         dbg("Redefining $package") if isdbg('command');
 759                         undef *$package;
 760                 } else {
 761                         dbg("Defining $package") if isdbg('command');
 762                 }
 763                 eval $eval;
 764
 765                 $Cache{$package} = {mtime => $mtime };
 766
 767         }
 768
 769         return $package;
 770 }
 771
 772 sub local_send
 773 {
 774         my ($self, $let, $buf) = @_;
 775         if ($self->{state} eq 'prompt' || $self->{state} eq 'talk') {
 776                 if ($self->{enhanced}) {
 777                         $self->send_later($let, $buf);
 778                 } else {
 779                         $self->send($buf);
 780                 }
 781         } else {
 782                 $self->delay($buf);
 783         }
 784 }
 785
 786 # send a talk message here
 787 sub talk
 788 {
 789         my ($self, $from, $to, $via, $line) = @_;
 790         $line =~ s/\\5E/\^/g;
 791         $self->local_send('T', "$to de $from: $line") if $self->{talk};
 792         Log('talk', $to, $from, $via?$via:$main::mycall, $line);
 793         # send a 'not here' message if required
 794         unless ($self->{here} && $from ne $to) {
 795                 my $key = "$to$from";
 796                 unless (exists $nothereslug{$key}) {
 797                         my ($ref, $dxchan);
 798                         if (($ref = Route::get($from)) && ($dxchan = $ref->dxchan)) {
 799                                 my $name = $self->user->name || $to;
 800                                 my $s = $self->user->nothere || $dxchan->msg('nothere', $name);
 801                                 $nothereslug{$key} = $main::systime;
 802                                 $dxchan->talk($to, $from, undef, $s);
 803                         }
 804                 }
 805         }
 806 }
 807
 808 # send an announce
 809 sub announce
 810 {
 811         my $self = shift;
 812         my $line = shift;
 813         my $isolate = shift;
 814         my $to = shift;
 815         my $target = shift;
 816         my $text = shift;
 817         my ($filter, $hops);
 818
 819         if (!$self->{ann_talk} && $to ne $self->{call}) {
 820                 my $call = AnnTalk::is_talk_candidate($_[0], $text);
 821                 return if $call;
 822         }
 823
 824         if ($self->{annfilter}) {
 825                 ($filter, $hops) = $self->{annfilter}->it(@_ );
 826                 return unless $filter;
 827         }
 828
 829         unless ($self->{ann}) {
 830                 return if $_[0] ne $main::myalias && $_[0] ne $main::mycall;
 831         }
 832         return if $target eq 'SYSOP' && $self->{priv} < 5;
 833         my $buf = "$to$target de $_[0]: $text";
 834         $buf =~ s/\%5E/^/g;
 835         $buf .= "\a\a" if $self->{beep};
 836         $self->local_send($target eq 'WX' ? 'W' : 'N', $buf);
 837 }
 838
 839 # send a chat
 840 sub chat
 841 {
 842         my $self = shift;
 843         my $line = shift;
 844         my $isolate = shift;
 845         my $target = shift;
 846         my $to = shift;
 847         my $text = shift;
 848         my ($filter, $hops);
 849
 850         return unless grep uc $_ eq $target, @{$self->{user}->{group}};
 851
 852         $text =~ s/^\#\d+ //;
 853         my $buf = "$target de $_[0]: $text";
 854         $buf =~ s/\%5E/^/g;
 855         $buf .= "\a\a" if $self->{beep};
 856         $self->local_send('C', $buf);
 857 }
 858
 859
 860 sub wwv
 861 {
 862         my $self = shift;
 863         my $line = shift;
 864         my $isolate = shift;
 865         my ($filter, $hops);
 866
 867         return unless $self->{wwv};
 868
 869         if ($self->{wwvfilter}) {
 870                 ($filter, $hops) = $self->{wwvfilter}->it(@_ );
 871                 return unless $filter;
 872         }
 873
 874         my $buf = "WWV de $_[6] <$_[1]>:   SFI=$_[2], A=$_[3], K=$_[4], $_[5]";
 875         $buf .= "\a\a" if $self->{beep};
 876         $self->local_send('V', $buf);
 877 }
 878
 879 sub wcy
 880 {
 881         my $self = shift;
 882         my $line = shift;
 883         my $isolate = shift;
 884         my ($filter, $hops);
 885
 886         return unless $self->{wcy};
 887
 888         if ($self->{wcyfilter}) {
 889                 ($filter, $hops) = $self->{wcyfilter}->it(@_ );
 890                 return unless $filter;
 891         }
 892
 893         my $buf = "WCY de $_[10] <$_[1]> : K=$_[4] expK=$_[5] A=$_[3] R=$_[6] SFI=$_[2] SA=$_[7] GMF=$_[8] Au=$_[9]";
 894         $buf .= "\a\a" if $self->{beep};
 895         $self->local_send('Y', $buf);
 896 }
 897
 898 # broadcast debug stuff to all interested parties
 899 sub broadcast_debug
 900 {
 901         my $s = shift;                          # the line to be rebroadcast
 902
 903         foreach my $dxchan (DXChannel::get_all) {
 904                 next unless $dxchan->{enhanced} && $dxchan->{senddbg};
 905                 $dxchan->send_later('L', $s);
 906         }
 907 }
 908
 909 sub do_entry_stuff
 910 {
 911         my $self = shift;
 912         my $line = shift;
 913         my @out;
 914
 915         if ($self->state eq 'enterbody') {
 916                 my $loc = $self->{loc} || confess "local var gone missing" ;
 917                 if ($line eq "\032" || $line eq '%1A' || uc $line eq "/EX") {
 918                         no strict 'refs';
 919                         push @out, &{$loc->{endaction}}($self);          # like this for < 5.8.0
 920                         $self->func(undef);
 921                         $self->state('prompt');
 922                 } elsif ($line eq "\031" || uc $line eq "/ABORT" || uc $line eq "/QUIT") {
 923                         push @out, $self->msg('m10');
 924                         delete $loc->{lines};
 925                         delete $self->{loc};
 926                         $self->func(undef);
 927                         $self->state('prompt');
 928                 } else {
 929                         push @{$loc->{lines}}, length($line) > 0 ? $line : " ";
 930                         # i.e. it ain't and end or abort, therefore store the line
 931                 }
 932         } else {
 933                 confess "Invalid state $self->{state}";
 934         }
 935         return @out;
 936 }
 937
 938 sub store_startup_script
 939 {
 940         my $self = shift;
 941         my $loc = $self->{loc} || confess "local var gone missing" ;
 942         my @out;
 943         my $call = $loc->{call} || confess "callsign gone missing";
 944         confess "lines array gone missing" unless ref $loc->{lines};
 945         my $r = Script::store($call, $loc->{lines});
 946         if (defined $r) {
 947                 if ($r) {
 948                         push @out, $self->msg('m19', $call, $r);
 949                 } else {
 950                         push @out, $self->msg('m20', $call);
 951                 }
 952         } else {
 953                 push @out, "error opening startup script $call $!";
 954         }
 955         return @out;
 956 }
 957
 958 1;
 959 __END__