perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   'sort' => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wx => '0,Want WX,yesno',
  55                   talk => '0,Want Talk,yesno',
  56                   ann => '0,Want Announce,yesno',
  57                   here => '0,Here?,yesno',
  58                   confmode => '0,In Conference?,yesno',
  59                   dx => '0,DX Spots,yesno',
  60                   redirect => '0,Redirect messages to',
  61                   lang => '0,Language',
  62                   func => '9,Function',
  63                   loc => '9,Local Vars', # used by func to store local variables in
  64                   beep => '0,Want Beeps,yesno',
  65                   lastread => '9,Last Msg Read',
  66                   outbound => '9,outbound?,yesno',
  67                   remotecmd => '9,doing rcmd,yesno',
  68                   pagelth => '0,Page Length',
  69                   pagedata => '9,Page Data Store',
  70                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  71                   isolate => '9,Isolate network,yesno',
  72                   delayed => '9,Delayed messages,parray',
  73                   annfilter => '9,Announce Filter',
  74                   wwvfilter => '9,WWV Filter',
  75                   spotfilter => '9,Spot Filter',
  76                  );
  77
  78 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  79 sub alloc
  80 {
  81         my ($pkg, $call, $conn, $user) = @_;
  82         my $self = {};
  83
  84         die "trying to create a duplicate channel for $call" if $channels{$call};
  85         $self->{call} = $call;
  86         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  87         if (defined $user) {
  88                 $self->{user} = $user;
  89                 $self->{lang} = $user->lang;
  90                 $user->new_group() if !$user->group;
  91                 $self->{group} = $user->group;
  92         }
  93         $self->{startt} = $self->{t} = time;
  94         $self->{state} = 0;
  95         $self->{oldstate} = 0;
  96         $self->{lang} = $main::lang if !$self->{lang};
  97         $self->{func} = "";
  98         bless $self, $pkg;
  99         return $channels{$call} = $self;
 100 }
 101
 102 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 103 sub get
 104 {
 105         my ($pkg, $call) = @_;
 106         return $channels{$call};
 107 }
 108
 109 # obtain all the channel objects
 110 sub get_all
 111 {
 112         my ($pkg) = @_;
 113         return values(%channels);
 114 }
 115
 116 # obtain a channel object by searching for its connection reference
 117 sub get_by_cnum
 118 {
 119         my ($pkg, $conn) = @_;
 120         my $self;
 121
 122         foreach $self (values(%channels)) {
 123                 return $self if ($self->{conn} == $conn);
 124         }
 125         return undef;
 126 }
 127
 128 # get rid of a channel object [$obj->del()]
 129 sub del
 130 {
 131         my $self = shift;
 132
 133         $self->{group} = undef;         # belt and braces
 134         delete $channels{$self->{call}};
 135 }
 136
 137 # is it an ak1a cluster ?
 138 sub is_ak1a
 139 {
 140         my $self = shift;
 141         return $self->{'sort'} eq 'A';
 142 }
 143
 144 # is it a user?
 145 sub is_user
 146 {
 147         my $self = shift;
 148         return $self->{'sort'} eq 'U';
 149 }
 150
 151 # is it a connect type
 152 sub is_connect
 153 {
 154         my $self = shift;
 155         return $self->{'sort'} eq 'C';
 156 }
 157
 158 # handle out going messages, immediately without waiting for the select to drop
 159 # this could, in theory, block
 160 sub send_now
 161 {
 162         my $self = shift;
 163         my $conn = $self->{conn};
 164         my $sort = shift;
 165         my $call = $self->{call};
 166
 167         for (@_) {
 168                 chomp;
 169                 $conn->send_now("$sort$call|$_") if $conn;
 170                 dbg('chan', "-> $sort $call $_") if $conn;
 171         }
 172         $self->{t} = time;
 173 }
 174
 175 #
 176 # the normal output routine
 177 #
 178 sub send                                                # this is always later and always data
 179 {
 180         my $self = shift;
 181         my $conn = $self->{conn};
 182         my $call = $self->{call};
 183
 184         for (@_) {
 185                 chomp;
 186                 $conn->send_later("D$call|$_") if $conn;
 187                 dbg('chan', "-> D $call $_") if $conn;
 188         }
 189         $self->{t} = time;
 190 }
 191
 192 # send a file (always later)
 193 sub send_file
 194 {
 195         my ($self, $fn) = @_;
 196         my $call = $self->{call};
 197         my $conn = $self->{conn};
 198         my @buf;
 199
 200         open(F, $fn) or die "can't open $fn for sending file ($!)";
 201         @buf = <F>;
 202         close(F);
 203         $self->send(@buf);
 204 }
 205
 206 # this will implement language independence (in time)
 207 sub msg
 208 {
 209         my $self = shift;
 210         return DXM::msg($self->{lang}, @_);
 211 }
 212
 213 # stick a broadcast on the delayed queue
 214 sub delay
 215 {
 216         my $self = shift;
 217         my $s = shift;
 218
 219         $self->{delayed} = [] unless $self->{delayed};
 220         push @{$self->{delayed}}, $s;
 221 }
 222
 223 # change the state of the channel - lots of scope for debugging here :-)
 224 sub state
 225 {
 226         my $self = shift;
 227         if (@_) {
 228                 $self->{oldstate} = $self->{state};
 229                 $self->{state} = shift;
 230                 $self->{func} = '' unless defined $self->{func};
 231                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 232
 233                 # if there is any queued up broadcasts then splurge them out here
 234                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 235                         for (@{$self->{delayed}}) {
 236                                 $self->send($_);
 237                         }
 238                         delete $self->{delayed};
 239                 }
 240         }
 241         return $self->{state};
 242 }
 243
 244 # disconnect this channel
 245 sub disconnect
 246 {
 247         my $self = shift;
 248         my $user = $self->{user};
 249         my $conn = $self->{conn};
 250         my $call = $self->{call};
 251
 252         $self->finish();
 253         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 254         $user->close() if defined $user;
 255         $conn->disconnect() if $conn;
 256         $self->del();
 257 }
 258
 259 #
 260 # just close all the socket connections down without any fiddling about, cleaning, being
 261 # nice to other processes and otherwise telling them what is going on.
 262 #
 263 # This is for the benefit of forked processes to prepare for starting new programs, they
 264 # don't want or need all this baggage.
 265 #
 266
 267 sub closeall
 268 {
 269         my $ref;
 270         foreach $ref (values %channels) {
 271                 $ref->{conn}->disconnect() if $ref->{conn};
 272         }
 273 }
 274
 275 # various access routines
 276
 277 #
 278 # return a list of valid elements
 279 #
 280
 281 sub fields
 282 {
 283         return keys(%valid);
 284 }
 285
 286 #
 287 # return a prompt for a field
 288 #
 289
 290 sub field_prompt
 291 {
 292         my ($self, $ele) = @_;
 293         return $valid{$ele};
 294 }
 295
 296 no strict;
 297 sub AUTOLOAD
 298 {
 299         my $self = shift;
 300         my $name = $AUTOLOAD;
 301         return if $name =~ /::DESTROY$/;
 302         $name =~ s/.*:://o;
 303
 304         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 305         @_ ? $self->{$name} = shift : $self->{$name} ;
 306 }
 307
 308 1;
 309 __END__;