perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   do_pc9x => '9,Handles PC9x,yesno',
 123                   inqueue => '9,Input Queue,parray',
 124                   next_pc92_update => '9,Next PC92 Update,atime',
 125                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 126                  );
 127
 128 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group unless $user->group;
 157                 $user->new_buddies unless $user->buddies;
 158                 $self->{group} = $user->group;
 159                 $self->{sort} = $user->sort;
 160         }
 161         $self->{startt} = $self->{t} = time;
 162         $self->{state} = 0;
 163         $self->{oldstate} = 0;
 164         $self->{lang} = $main::lang if !$self->{lang};
 165         $self->{func} = "";
 166
 167         # add in all the dxcc, itu, zone info
 168         my @dxcc = Prefix::extract($call);
 169         if (@dxcc > 0) {
 170                 $self->{dxcc} = $dxcc[1]->dxcc;
 171                 $self->{itu} = $dxcc[1]->itu;
 172                 $self->{cq} = $dxcc[1]->cq;
 173         }
 174         $self->{inqueue} = [];
 175
 176         $count++;
 177         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 178         bless $self, $pkg;
 179         return $channels{$call} = $self;
 180 }
 181
 182 # count errors and disconnect if too many
 183 # this has to be here because it can come from rcmd (DXProt) as
 184 # well as DXCommandmode.
 185 sub _error_out
 186 {
 187         my $self = shift;
 188         my $e = shift;
 189         if (++$self->{errors} > $maxerrors) {
 190                 $self->send($self->msg('e26'));
 191                 $self->disconnect;
 192                 return ();
 193         } else {
 194                 return ($self->msg($e));
 195         }
 196 }
 197
 198 # rebless this channel as something else
 199 sub rebless
 200 {
 201         my $self = shift;
 202         my $class = shift;
 203         return $channels{$self->{call}} = bless $self, $class;
 204 }
 205
 206 sub rec
 207 {
 208         my ($self, $msg) = @_;
 209
 210         # queue the message and the channel object for later processing
 211         if (defined $msg) {
 212                 push @{$self->{inqueue}}, $msg;
 213         }
 214 }
 215
 216 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 217 sub get
 218 {
 219         my $call = shift;
 220         return $channels{$call};
 221 }
 222
 223 # obtain all the channel objects
 224 sub get_all
 225 {
 226         return values(%channels);
 227 }
 228
 229 #
 230 # gimme all the ak1a nodes
 231 #
 232 sub get_all_nodes
 233 {
 234         my $ref;
 235         my @out;
 236         foreach $ref (values %channels) {
 237                 push @out, $ref if $ref->is_node;
 238         }
 239         return @out;
 240 }
 241
 242 # return a list of all users
 243 sub get_all_users
 244 {
 245         my $ref;
 246         my @out;
 247         foreach $ref (values %channels) {
 248                 push @out, $ref if $ref->is_user;
 249         }
 250         return @out;
 251 }
 252
 253 # return a list of all user callsigns
 254 sub get_all_user_calls
 255 {
 256         my $ref;
 257         my @out;
 258         foreach $ref (values %channels) {
 259                 push @out, $ref->{call} if $ref->is_user;
 260         }
 261         return @out;
 262 }
 263
 264 # obtain a channel object by searching for its connection reference
 265 sub get_by_cnum
 266 {
 267         my ($pkg, $conn) = @_;
 268         my $self;
 269
 270         foreach $self (values(%channels)) {
 271                 return $self if ($self->{conn} == $conn);
 272         }
 273         return undef;
 274 }
 275
 276 # get rid of a channel object [$obj->del()]
 277 sub del
 278 {
 279         my $self = shift;
 280
 281         $self->{group} = undef;         # belt and braces
 282         delete $channels{$self->{call}};
 283 }
 284
 285 # is it a bbs
 286 sub is_bbs
 287 {
 288         my $self = shift;
 289         return $self->{'sort'} eq 'B';
 290 }
 291
 292 sub is_node
 293 {
 294         my $self = shift;
 295         return $self->{'sort'} =~ /[ACRSXW]/;
 296 }
 297 # is it an ak1a node ?
 298 sub is_ak1a
 299 {
 300         my $self = shift;
 301         return $self->{'sort'} eq 'A';
 302 }
 303
 304 # is it a user?
 305 sub is_user
 306 {
 307         my $self = shift;
 308         return $self->{'sort'} eq 'U';
 309 }
 310
 311 # is it a clx node
 312 sub is_clx
 313 {
 314         my $self = shift;
 315         return $self->{'sort'} eq 'C';
 316 }
 317
 318 # it is Aranea
 319 sub is_aranea
 320 {
 321         my $self = shift;
 322         return $self->{'sort'} eq 'W';
 323 }
 324
 325 # is it a spider node
 326 sub is_spider
 327 {
 328         my $self = shift;
 329         return $self->{'sort'} eq 'S';
 330 }
 331
 332 # is it a DXNet node
 333 sub is_dxnet
 334 {
 335         my $self = shift;
 336         return $self->{'sort'} eq 'X';
 337 }
 338
 339 # is it a ar-cluster node
 340 sub is_arcluster
 341 {
 342         my $self = shift;
 343         return $self->{'sort'} eq 'R';
 344 }
 345
 346 # for perl 5.004's benefit
 347 sub sort
 348 {
 349         my $self = shift;
 350         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 351 }
 352
 353 # find out whether we are prepared to believe this callsign on this interface
 354 sub is_believed
 355 {
 356         my $self = shift;
 357         my $call = shift;
 358
 359         return grep $call eq $_, $self->user->believe;
 360 }
 361
 362 # handle out going messages, immediately without waiting for the select to drop
 363 # this could, in theory, block
 364 sub send_now
 365 {
 366         my $self = shift;
 367         my $conn = $self->{conn};
 368         return unless $conn;
 369         my $sort = shift;
 370         my $call = $self->{call};
 371
 372         for (@_) {
 373 #               chomp;
 374         my @lines = split /\n/;
 375                 for (@lines) {
 376                         $conn->send_now("$sort$call|$_");
 377                         # debug log it, but not if it is a log message
 378                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 379                 }
 380         }
 381         $self->{t} = time;
 382 }
 383
 384 #
 385 # send later with letter (more control)
 386 #
 387
 388 sub send_later
 389 {
 390         my $self = shift;
 391         my $conn = $self->{conn};
 392         return unless $conn;
 393         my $sort = shift;
 394         my $call = $self->{call};
 395
 396         for (@_) {
 397 #               chomp;
 398         my @lines = split /\n/;
 399                 for (@lines) {
 400                         $conn->send_later("$sort$call|$_");
 401                         # debug log it, but not if it is a log message
 402                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 403                 }
 404         }
 405         $self->{t} = time;
 406 }
 407
 408 #
 409 # the normal output routine
 410 #
 411 sub send                                                # this is always later and always data
 412 {
 413         my $self = shift;
 414         my $conn = $self->{conn};
 415         return unless $conn;
 416         my $call = $self->{call};
 417
 418         foreach my $l (@_) {
 419                 for (ref $l ? @$l : $l) {
 420                         my @lines = split /\n/;
 421                         for (@lines) {
 422                                 $conn->send_later("D$call|$_");
 423                                 dbg("-> D $call $_") if isdbg('chan');
 424                         }
 425                 }
 426         }
 427         $self->{t} = $main::systime;
 428 }
 429
 430 # send a file (always later)
 431 sub send_file
 432 {
 433         my ($self, $fn) = @_;
 434         my $call = $self->{call};
 435         my $conn = $self->{conn};
 436         my @buf;
 437
 438         open(F, $fn) or die "can't open $fn for sending file ($!)";
 439         @buf = <F>;
 440         close(F);
 441         $self->send(@buf);
 442 }
 443
 444 # this will implement language independence (in time)
 445 sub msg
 446 {
 447         my $self = shift;
 448         return DXM::msg($self->{lang}, @_);
 449 }
 450
 451 # stick a broadcast on the delayed queue (but only up to 20 items)
 452 sub delay
 453 {
 454         my $self = shift;
 455         my $s = shift;
 456
 457         $self->{delayed} = [] unless $self->{delayed};
 458         push @{$self->{delayed}}, $s;
 459         if (@{$self->{delayed}} >= 20) {
 460                 shift @{$self->{delayed}};   # lose oldest one
 461         }
 462 }
 463
 464 # change the state of the channel - lots of scope for debugging here :-)
 465 sub state
 466 {
 467         my $self = shift;
 468         if (@_) {
 469                 $self->{oldstate} = $self->{state};
 470                 $self->{state} = shift;
 471                 $self->{func} = '' unless defined $self->{func};
 472                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 473
 474                 # if there is any queued up broadcasts then splurge them out here
 475                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 476                         $self->send (@{$self->{delayed}});
 477                         delete $self->{delayed};
 478                 }
 479         }
 480         return $self->{state};
 481 }
 482
 483 # disconnect this channel
 484 sub disconnect
 485 {
 486         my $self = shift;
 487         my $user = $self->{user};
 488
 489         $user->close() if defined $user;
 490         $self->{conn}->disconnect if $self->{conn};
 491         $self->del();
 492 }
 493
 494 #
 495 # just close all the socket connections down without any fiddling about, cleaning, being
 496 # nice to other processes and otherwise telling them what is going on.
 497 #
 498 # This is for the benefit of forked processes to prepare for starting new programs, they
 499 # don't want or need all this baggage.
 500 #
 501
 502 sub closeall
 503 {
 504         my $ref;
 505         foreach $ref (values %channels) {
 506                 $ref->{conn}->disconnect() if $ref->{conn};
 507         }
 508 }
 509
 510 #
 511 # Tell all the users that we have come in or out (if they want to know)
 512 #
 513 sub tell_login
 514 {
 515         my ($self, $m, $call) = @_;
 516
 517         $call ||= $self->{call};
 518
 519         # send info to all logged in thingies
 520         my @dxchan = get_all_users();
 521         my $dxchan;
 522         foreach $dxchan (@dxchan) {
 523                 next if $dxchan == $self;
 524                 next if $dxchan->{call} eq $main::mycall;
 525                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 526         }
 527 }
 528
 529 #
 530 # Tell all the users if a buddy is logged or out
 531 #
 532 sub tell_buddies
 533 {
 534         my ($self, $m, $call, $node) = @_;
 535
 536         $call ||= $self->{call};
 537         $call =~ s/-\d+$//;
 538         $m .= 'n' if $node;
 539
 540         # send info to all logged in thingies
 541         my @dxchan = get_all_users();
 542         my $dxchan;
 543         foreach $dxchan (@dxchan) {
 544                 next if $dxchan == $self;
 545                 next if $dxchan->{call} eq $main::mycall;
 546                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 547         }
 548 }
 549
 550 # various access routines
 551
 552 #
 553 # return a list of valid elements
 554 #
 555
 556 sub fields
 557 {
 558         return keys(%valid);
 559 }
 560
 561 #
 562 # return a prompt for a field
 563 #
 564
 565 sub field_prompt
 566 {
 567         my ($self, $ele) = @_;
 568         return $valid{$ele};
 569 }
 570
 571 # take a standard input message and decode it into its standard parts
 572 sub decode_input
 573 {
 574         my $dxchan = shift;
 575         my $data = shift;
 576         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 577
 578         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 579
 580         # the above regexp must work
 581         unless (defined $sort && defined $call && defined $line) {
 582 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 583                 dbg("DUFF Line on $chcall: $data");
 584                 return ();
 585         }
 586
 587         if(ref($dxchan) && $call ne $chcall) {
 588                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 589                 return();
 590         }
 591
 592         return ($sort, $call, $line);
 593 }
 594
 595 # broadcast a message to all clusters taking into account isolation
 596 # [except those mentioned after buffer]
 597 sub broadcast_nodes
 598 {
 599         my $s = shift;                          # the line to be rebroadcast
 600         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 601         my @dxchan = get_all_nodes();
 602         my $dxchan;
 603
 604         # send it if it isn't the except list and isn't isolated and still has a hop count
 605         foreach $dxchan (@dxchan) {
 606                 next if grep $dxchan == $_, @except;
 607                 next if $dxchan == $main::me;
 608
 609                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 610
 611                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 612         }
 613 }
 614
 615 # broadcast a message to all clusters ignoring isolation
 616 # [except those mentioned after buffer]
 617 sub broadcast_all_nodes
 618 {
 619         my $s = shift;                          # the line to be rebroadcast
 620         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 621         my @dxchan = get_all_nodes();
 622         my $dxchan;
 623
 624         # send it if it isn't the except list and isn't isolated and still has a hop count
 625         foreach $dxchan (@dxchan) {
 626                 next if grep $dxchan == $_, @except;
 627                 next if $dxchan == $main::me;
 628
 629                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 630                 $dxchan->send($routeit);
 631         }
 632 }
 633
 634 # broadcast to all users
 635 # storing the spot or whatever until it is in a state to receive it
 636 sub broadcast_users
 637 {
 638         my $s = shift;                          # the line to be rebroadcast
 639         my $sort = shift;           # the type of transmission
 640         my $fref = shift;           # a reference to an object to filter on
 641         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 642         my @dxchan = get_all_users();
 643         my $dxchan;
 644         my @out;
 645
 646         foreach $dxchan (@dxchan) {
 647                 next if grep $dxchan == $_, @except;
 648                 push @out, $dxchan;
 649         }
 650         broadcast_list($s, $sort, $fref, @out);
 651 }
 652
 653
 654 # broadcast to a list of users
 655 sub broadcast_list
 656 {
 657         my $s = shift;
 658         my $sort = shift;
 659         my $fref = shift;
 660         my $dxchan;
 661
 662         foreach $dxchan (@_) {
 663                 my $filter = 1;
 664                 next if $dxchan == $main::me;
 665
 666                 if ($sort eq 'dx') {
 667                     next unless $dxchan->{dx};
 668                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 669                         next unless $filter;
 670                 }
 671                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 672                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 673                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 674                 next if $sort eq 'wx' && !$dxchan->{wx};
 675
 676                 $s =~ s/\a//og unless $dxchan->{beep};
 677
 678                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 679                         $dxchan->send($s);
 680                 } else {
 681                         $dxchan->delay($s);
 682                 }
 683         }
 684 }
 685
 686 sub process
 687 {
 688         foreach my $dxchan (get_all()) {
 689
 690                 while (my $data = shift @{$dxchan->{inqueue}}) {
 691                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 692                         next unless defined $sort;
 693
 694                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 695                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 696                         if ($dxchan->{disconnecting}) {
 697                                 dbg('In disconnection, ignored');
 698                                 next;
 699                         }
 700
 701                         # handle A records
 702                         my $user = $dxchan->user;
 703                         if ($sort eq 'A' || $sort eq 'O') {
 704                                 $dxchan->start($line, $sort);
 705                         } elsif ($sort eq 'I') {
 706                                 die "\$user not defined for $call" if !defined $user;
 707
 708                                 # normal input
 709                                 $dxchan->normal($line);
 710                         } elsif ($sort eq 'Z') {
 711                                 $dxchan->disconnect;
 712                         } elsif ($sort eq 'D') {
 713                                 ;                               # ignored (an echo)
 714                         } elsif ($sort eq 'G') {
 715                                 $dxchan->enhanced($line);
 716                         } else {
 717                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 718                         }
 719                 }
 720         }
 721 }
 722
 723 sub handle_xml
 724 {
 725         my $self = shift;
 726         my $r = 0;
 727
 728         if (DXXml::available()) {
 729                 $r = $self->{handle_xml} || 0;
 730         } else {
 731                 delete $self->{handle_xml} if exists $self->{handle_xml};
 732         }
 733         return $r;
 734 }
 735
 736 #no strict;
 737 sub AUTOLOAD
 738 {
 739         no strict;
 740         my $name = $AUTOLOAD;
 741         return if $name =~ /::DESTROY$/;
 742         $name =~ s/^.*:://o;
 743
 744         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 745
 746         # this clever line of code creates a subroutine which takes over from autoload
 747         # from OO Perl - Conway
 748         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 749         goto &$AUTOLOAD;
 750 }
 751
 752
 753 1;
 754 __END__;