perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = undef;
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   sort => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   talk => '0,Want Talk,yesno',
  55                   ann => '0,Want Announce,yesno',
  56                   here => '0,Here?,yesno',
  57                   confmode => '0,In Conference?,yesno',
  58                   dx => '0,DX Spots,yesno',
  59                   redirect => '0,Redirect messages to',
  60                   lang => '0,Language',
  61                   func => '9,Function',
  62                   loc => '9,Local Vars', # used by func to store local variables in
  63                   beep => '0,Want Beeps,yesno',
  64                   lastread => '9,Last Msg Read',
  65                   outbound => '9,outbound?,yesno',
  66                   remotecmd => '9,doing rcmd,yesno',
  67                   pagelth => '0,Page Length',
  68                   pagedata => '9,Page Data Store',
  69                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  70                   isolate => '9,Isolate network,yesno',
  71                  );
  72
  73 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  74 sub alloc
  75 {
  76         my ($pkg, $call, $conn, $user) = @_;
  77         my $self = {};
  78
  79         die "trying to create a duplicate channel for $call" if $channels{$call};
  80         $self->{call} = $call;
  81         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  82         $self->{user} = $user if defined $user;
  83         $self->{startt} = $self->{t} = time;
  84         $self->{state} = 0;
  85         $self->{oldstate} = 0;
  86         $self->{lang} = $user->{lang} if defined $user;
  87         $self->{lang} = $main::lang if !$self->{lang};
  88         $user->new_group() if !$user->group;
  89         $self->{group} = $user->group;
  90         bless $self, $pkg;
  91         return $channels{$call} = $self;
  92 }
  93
  94 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
  95 sub get
  96 {
  97         my ($pkg, $call) = @_;
  98         return $channels{$call};
  99 }
 100
 101 # obtain all the channel objects
 102 sub get_all
 103 {
 104         my ($pkg) = @_;
 105         return values(%channels);
 106 }
 107
 108 # obtain a channel object by searching for its connection reference
 109 sub get_by_cnum
 110 {
 111         my ($pkg, $conn) = @_;
 112         my $self;
 113
 114         foreach $self (values(%channels)) {
 115                 return $self if ($self->{conn} == $conn);
 116         }
 117         return undef;
 118 }
 119
 120 # get rid of a channel object [$obj->del()]
 121 sub del
 122 {
 123         my $self = shift;
 124
 125         $self->{group} = undef;         # belt and braces
 126         delete $channels{$self->{call}};
 127 }
 128
 129 # is it an ak1a cluster ?
 130 sub is_ak1a
 131 {
 132         my $self = shift;
 133         return $self->{sort} eq 'A';
 134 }
 135
 136 # is it a user?
 137 sub is_user
 138 {
 139         my $self = shift;
 140         return $self->{sort} eq 'U';
 141 }
 142
 143 # is it a connect type
 144 sub is_connect
 145 {
 146         my $self = shift;
 147         return $self->{sort} eq 'C';
 148 }
 149
 150 # handle out going messages, immediately without waiting for the select to drop
 151 # this could, in theory, block
 152 sub send_now
 153 {
 154         my $self = shift;
 155         my $conn = $self->{conn};
 156         my $sort = shift;
 157         my $call = $self->{call};
 158         my $line;
 159
 160         foreach $line (@_) {
 161                 chomp $line;
 162                 $conn->send_now("$sort$call|$line") if $conn;
 163                 dbg('chan', "-> $sort $call $line") if $conn;
 164         }
 165         $self->{t} = time;
 166 }
 167
 168 #
 169 # the normal output routine
 170 #
 171 sub send                                                # this is always later and always data
 172 {
 173         my $self = shift;
 174         my $conn = $self->{conn};
 175         my $call = $self->{call};
 176         my $line;
 177
 178         foreach $line (@_) {
 179                 chomp $line;
 180                 $conn->send_later("D$call|$line") if $conn;
 181                 dbg('chan', "-> D $call $line") if $conn;
 182         }
 183         $self->{t} = time;
 184 }
 185
 186 # send a file (always later)
 187 sub send_file
 188 {
 189         my ($self, $fn) = @_;
 190         my $call = $self->{call};
 191         my $conn = $self->{conn};
 192         my @buf;
 193
 194         open(F, $fn) or die "can't open $fn for sending file ($!)";
 195         @buf = <F>;
 196         close(F);
 197         $self->send(@buf);
 198 }
 199
 200 # this will implement language independence (in time)
 201 sub msg
 202 {
 203         my $self = shift;
 204         return DXM::msg($self->{lang}, @_);
 205 }
 206
 207 # change the state of the channel - lots of scope for debugging here :-)
 208 sub state
 209 {
 210         my $self = shift;
 211         if (@_) {
 212                 $self->{oldstate} = $self->{state};
 213                 $self->{state} = shift;
 214                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 215         }
 216         return $self->{state};
 217 }
 218
 219 # disconnect this channel
 220 sub disconnect
 221 {
 222         my $self = shift;
 223         my $user = $self->{user};
 224         my $conn = $self->{conn};
 225         my $call = $self->{call};
 226
 227         $self->finish();
 228         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 229         $user->close() if defined $user;
 230         $conn->disconnect() if $conn;
 231         $self->del();
 232 }
 233
 234 # various access routines
 235
 236 #
 237 # return a list of valid elements
 238 #
 239
 240 sub fields
 241 {
 242         return keys(%valid);
 243 }
 244
 245 #
 246 # return a prompt for a field
 247 #
 248
 249 sub field_prompt
 250 {
 251         my ($self, $ele) = @_;
 252         return $valid{$ele};
 253 }
 254
 255 no strict;
 256 sub AUTOLOAD
 257 {
 258         my $self = shift;
 259         my $name = $AUTOLOAD;
 260         return if $name =~ /::DESTROY$/;
 261         $name =~ s/.*:://o;
 262
 263         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 264         @_ ? $self->{$name} = shift : $self->{$name} ;
 265 }
 266
 267 1;
 268 __END__;