perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   do_pc9x => '9,Handles PC9x,yesno',
 123                   inqueue => '9,Input Queue,parray',
 124                   next_pc92_update => '9,Next PC92 Update,atime',
 125                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 126                  );
 127
 128 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group unless $user->group;
 157                 $user->new_buddies unless $user->buddies;
 158                 $self->{group} = $user->group;
 159                 $self->{sort} = $user->sort;
 160         }
 161         $self->{startt} = $self->{t} = time;
 162         $self->{state} = 0;
 163         $self->{oldstate} = 0;
 164         $self->{lang} = $main::lang if !$self->{lang};
 165         $self->{func} = "";
 166
 167         # add in all the dxcc, itu, zone info
 168         my @dxcc = Prefix::extract($call);
 169         if (@dxcc > 0) {
 170                 $self->{dxcc} = $dxcc[1]->dxcc;
 171                 $self->{itu} = $dxcc[1]->itu;
 172                 $self->{cq} = $dxcc[1]->cq;
 173         }
 174         $self->{inqueue} = [];
 175
 176         $count++;
 177         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 178         bless $self, $pkg;
 179         return $channels{$call} = $self;
 180 }
 181
 182 # count errors and disconnect if too many
 183 # this has to be here because it can come from rcmd (DXProt) as
 184 # well as DXCommandmode.
 185 sub _error_out
 186 {
 187         my $self = shift;
 188         my $e = shift;
 189         if (++$self->{errors} > $maxerrors) {
 190                 $self->send($self->msg('e26'));
 191                 $self->disconnect;
 192                 return ();
 193         } else {
 194                 return ($self->msg($e));
 195         }
 196 }
 197
 198 # rebless this channel as something else
 199 sub rebless
 200 {
 201         my $self = shift;
 202         my $class = shift;
 203         return $channels{$self->{call}} = bless $self, $class;
 204 }
 205
 206 sub rec
 207 {
 208         my ($self, $msg) = @_;
 209
 210         # queue the message and the channel object for later processing
 211         if (defined $msg) {
 212                 push @{$self->{inqueue}}, $msg;
 213         }
 214 }
 215
 216 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 217 sub get
 218 {
 219         my $call = shift;
 220         return $channels{$call};
 221 }
 222
 223 # obtain all the channel objects
 224 sub get_all
 225 {
 226         return values(%channels);
 227 }
 228
 229 #
 230 # gimme all the ak1a nodes
 231 #
 232 sub get_all_nodes
 233 {
 234         my $ref;
 235         my @out;
 236         foreach $ref (values %channels) {
 237                 push @out, $ref if $ref->is_node;
 238         }
 239         return @out;
 240 }
 241
 242 # return a list of node calls
 243 sub get_all_node_calls
 244 {
 245         my $ref;
 246         my @out;
 247         foreach $ref (values %channels) {
 248                 push @out, $ref->{call} if $ref->is_node;
 249         }
 250         return @out;
 251 }
 252
 253 # return a list of all users
 254 sub get_all_users
 255 {
 256         my $ref;
 257         my @out;
 258         foreach $ref (values %channels) {
 259                 push @out, $ref if $ref->is_user;
 260         }
 261         return @out;
 262 }
 263
 264 # return a list of all user callsigns
 265 sub get_all_user_calls
 266 {
 267         my $ref;
 268         my @out;
 269         foreach $ref (values %channels) {
 270                 push @out, $ref->{call} if $ref->is_user;
 271         }
 272         return @out;
 273 }
 274
 275 # obtain a channel object by searching for its connection reference
 276 sub get_by_cnum
 277 {
 278         my ($pkg, $conn) = @_;
 279         my $self;
 280
 281         foreach $self (values(%channels)) {
 282                 return $self if ($self->{conn} == $conn);
 283         }
 284         return undef;
 285 }
 286
 287 # get rid of a channel object [$obj->del()]
 288 sub del
 289 {
 290         my $self = shift;
 291
 292         $self->{group} = undef;         # belt and braces
 293         delete $channels{$self->{call}};
 294 }
 295
 296 # is it a bbs
 297 sub is_bbs
 298 {
 299         my $self = shift;
 300         return $self->{'sort'} eq 'B';
 301 }
 302
 303 sub is_node
 304 {
 305         my $self = shift;
 306         return $self->{'sort'} =~ /[ACRSXW]/;
 307 }
 308 # is it an ak1a node ?
 309 sub is_ak1a
 310 {
 311         my $self = shift;
 312         return $self->{'sort'} eq 'A';
 313 }
 314
 315 # is it a user?
 316 sub is_user
 317 {
 318         my $self = shift;
 319         return $self->{'sort'} eq 'U';
 320 }
 321
 322 # is it a clx node
 323 sub is_clx
 324 {
 325         my $self = shift;
 326         return $self->{'sort'} eq 'C';
 327 }
 328
 329 # it is Aranea
 330 sub is_aranea
 331 {
 332         my $self = shift;
 333         return $self->{'sort'} eq 'W';
 334 }
 335
 336 # is it a spider node
 337 sub is_spider
 338 {
 339         my $self = shift;
 340         return $self->{'sort'} eq 'S';
 341 }
 342
 343 # is it a DXNet node
 344 sub is_dxnet
 345 {
 346         my $self = shift;
 347         return $self->{'sort'} eq 'X';
 348 }
 349
 350 # is it a ar-cluster node
 351 sub is_arcluster
 352 {
 353         my $self = shift;
 354         return $self->{'sort'} eq 'R';
 355 }
 356
 357 # for perl 5.004's benefit
 358 sub sort
 359 {
 360         my $self = shift;
 361         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 362 }
 363
 364 # find out whether we are prepared to believe this callsign on this interface
 365 sub is_believed
 366 {
 367         my $self = shift;
 368         my $call = shift;
 369
 370         return grep $call eq $_, $self->user->believe;
 371 }
 372
 373 # handle out going messages, immediately without waiting for the select to drop
 374 # this could, in theory, block
 375 sub send_now
 376 {
 377         my $self = shift;
 378         my $conn = $self->{conn};
 379         return unless $conn;
 380         my $sort = shift;
 381         my $call = $self->{call};
 382
 383         for (@_) {
 384 #               chomp;
 385         my @lines = split /\n/;
 386                 for (@lines) {
 387                         $conn->send_now("$sort$call|$_");
 388                         # debug log it, but not if it is a log message
 389                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 390                 }
 391         }
 392         $self->{t} = time;
 393 }
 394
 395 #
 396 # send later with letter (more control)
 397 #
 398
 399 sub send_later
 400 {
 401         my $self = shift;
 402         my $conn = $self->{conn};
 403         return unless $conn;
 404         my $sort = shift;
 405         my $call = $self->{call};
 406
 407         for (@_) {
 408 #               chomp;
 409         my @lines = split /\n/;
 410                 for (@lines) {
 411                         $conn->send_later("$sort$call|$_");
 412                         # debug log it, but not if it is a log message
 413                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 414                 }
 415         }
 416         $self->{t} = time;
 417 }
 418
 419 #
 420 # the normal output routine
 421 #
 422 sub send                                                # this is always later and always data
 423 {
 424         my $self = shift;
 425         my $conn = $self->{conn};
 426         return unless $conn;
 427         my $call = $self->{call};
 428
 429         foreach my $l (@_) {
 430                 for (ref $l ? @$l : $l) {
 431                         my @lines = split /\n/;
 432                         for (@lines) {
 433                                 $conn->send_later("D$call|$_");
 434                                 dbg("-> D $call $_") if isdbg('chan');
 435                         }
 436                 }
 437         }
 438         $self->{t} = $main::systime;
 439 }
 440
 441 # send a file (always later)
 442 sub send_file
 443 {
 444         my ($self, $fn) = @_;
 445         my $call = $self->{call};
 446         my $conn = $self->{conn};
 447         my @buf;
 448
 449         open(F, $fn) or die "can't open $fn for sending file ($!)";
 450         @buf = <F>;
 451         close(F);
 452         $self->send(@buf);
 453 }
 454
 455 # this will implement language independence (in time)
 456 sub msg
 457 {
 458         my $self = shift;
 459         return DXM::msg($self->{lang}, @_);
 460 }
 461
 462 # stick a broadcast on the delayed queue (but only up to 20 items)
 463 sub delay
 464 {
 465         my $self = shift;
 466         my $s = shift;
 467
 468         $self->{delayed} = [] unless $self->{delayed};
 469         push @{$self->{delayed}}, $s;
 470         if (@{$self->{delayed}} >= 20) {
 471                 shift @{$self->{delayed}};   # lose oldest one
 472         }
 473 }
 474
 475 # change the state of the channel - lots of scope for debugging here :-)
 476 sub state
 477 {
 478         my $self = shift;
 479         if (@_) {
 480                 $self->{oldstate} = $self->{state};
 481                 $self->{state} = shift;
 482                 $self->{func} = '' unless defined $self->{func};
 483                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 484
 485                 # if there is any queued up broadcasts then splurge them out here
 486                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 487                         $self->send (@{$self->{delayed}});
 488                         delete $self->{delayed};
 489                 }
 490         }
 491         return $self->{state};
 492 }
 493
 494 # disconnect this channel
 495 sub disconnect
 496 {
 497         my $self = shift;
 498         my $user = $self->{user};
 499
 500         $user->close() if defined $user;
 501         $self->{conn}->disconnect if $self->{conn};
 502         $self->del();
 503 }
 504
 505 #
 506 # just close all the socket connections down without any fiddling about, cleaning, being
 507 # nice to other processes and otherwise telling them what is going on.
 508 #
 509 # This is for the benefit of forked processes to prepare for starting new programs, they
 510 # don't want or need all this baggage.
 511 #
 512
 513 sub closeall
 514 {
 515         my $ref;
 516         foreach $ref (values %channels) {
 517                 $ref->{conn}->disconnect() if $ref->{conn};
 518         }
 519 }
 520
 521 #
 522 # Tell all the users that we have come in or out (if they want to know)
 523 #
 524 sub tell_login
 525 {
 526         my ($self, $m, $call) = @_;
 527
 528         $call ||= $self->{call};
 529
 530         # send info to all logged in thingies
 531         my @dxchan = get_all_users();
 532         my $dxchan;
 533         foreach $dxchan (@dxchan) {
 534                 next if $dxchan == $self;
 535                 next if $dxchan->{call} eq $main::mycall;
 536                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 537         }
 538 }
 539
 540 #
 541 # Tell all the users if a buddy is logged or out
 542 #
 543 sub tell_buddies
 544 {
 545         my ($self, $m, $call, $node) = @_;
 546
 547         $call ||= $self->{call};
 548         $call =~ s/-\d+$//;
 549         $m .= 'n' if $node;
 550
 551         # send info to all logged in thingies
 552         my @dxchan = get_all_users();
 553         my $dxchan;
 554         foreach $dxchan (@dxchan) {
 555                 next if $dxchan == $self;
 556                 next if $dxchan->{call} eq $main::mycall;
 557                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 558         }
 559 }
 560
 561 # various access routines
 562
 563 #
 564 # return a list of valid elements
 565 #
 566
 567 sub fields
 568 {
 569         return keys(%valid);
 570 }
 571
 572 #
 573 # return a prompt for a field
 574 #
 575
 576 sub field_prompt
 577 {
 578         my ($self, $ele) = @_;
 579         return $valid{$ele};
 580 }
 581
 582 # take a standard input message and decode it into its standard parts
 583 sub decode_input
 584 {
 585         my $dxchan = shift;
 586         my $data = shift;
 587         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 588
 589         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 590
 591         # the above regexp must work
 592         unless (defined $sort && defined $call && defined $line) {
 593 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 594                 dbg("DUFF Line on $chcall: $data");
 595                 return ();
 596         }
 597
 598         if(ref($dxchan) && $call ne $chcall) {
 599                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 600                 return();
 601         }
 602
 603         return ($sort, $call, $line);
 604 }
 605
 606 # broadcast a message to all clusters taking into account isolation
 607 # [except those mentioned after buffer]
 608 sub broadcast_nodes
 609 {
 610         my $s = shift;                          # the line to be rebroadcast
 611         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 612         my @dxchan = get_all_nodes();
 613         my $dxchan;
 614
 615         # send it if it isn't the except list and isn't isolated and still has a hop count
 616         foreach $dxchan (@dxchan) {
 617                 next if grep $dxchan == $_, @except;
 618                 next if $dxchan == $main::me;
 619
 620                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 621
 622                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 623         }
 624 }
 625
 626 # broadcast a message to all clusters ignoring isolation
 627 # [except those mentioned after buffer]
 628 sub broadcast_all_nodes
 629 {
 630         my $s = shift;                          # the line to be rebroadcast
 631         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 632         my @dxchan = get_all_nodes();
 633         my $dxchan;
 634
 635         # send it if it isn't the except list and isn't isolated and still has a hop count
 636         foreach $dxchan (@dxchan) {
 637                 next if grep $dxchan == $_, @except;
 638                 next if $dxchan == $main::me;
 639
 640                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 641                 $dxchan->send($routeit);
 642         }
 643 }
 644
 645 # broadcast to all users
 646 # storing the spot or whatever until it is in a state to receive it
 647 sub broadcast_users
 648 {
 649         my $s = shift;                          # the line to be rebroadcast
 650         my $sort = shift;           # the type of transmission
 651         my $fref = shift;           # a reference to an object to filter on
 652         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 653         my @dxchan = get_all_users();
 654         my $dxchan;
 655         my @out;
 656
 657         foreach $dxchan (@dxchan) {
 658                 next if grep $dxchan == $_, @except;
 659                 push @out, $dxchan;
 660         }
 661         broadcast_list($s, $sort, $fref, @out);
 662 }
 663
 664
 665 # broadcast to a list of users
 666 sub broadcast_list
 667 {
 668         my $s = shift;
 669         my $sort = shift;
 670         my $fref = shift;
 671         my $dxchan;
 672
 673         foreach $dxchan (@_) {
 674                 my $filter = 1;
 675                 next if $dxchan == $main::me;
 676
 677                 if ($sort eq 'dx') {
 678                     next unless $dxchan->{dx};
 679                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 680                         next unless $filter;
 681                 }
 682                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 683                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 684                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 685                 next if $sort eq 'wx' && !$dxchan->{wx};
 686
 687                 $s =~ s/\a//og unless $dxchan->{beep};
 688
 689                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 690                         $dxchan->send($s);
 691                 } else {
 692                         $dxchan->delay($s);
 693                 }
 694         }
 695 }
 696
 697 sub process
 698 {
 699         foreach my $dxchan (get_all()) {
 700
 701                 while (my $data = shift @{$dxchan->{inqueue}}) {
 702                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 703                         next unless defined $sort;
 704
 705                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 706                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 707                         if ($dxchan->{disconnecting}) {
 708                                 dbg('In disconnection, ignored');
 709                                 next;
 710                         }
 711
 712                         # handle A records
 713                         my $user = $dxchan->user;
 714                         if ($sort eq 'A' || $sort eq 'O') {
 715                                 $dxchan->start($line, $sort);
 716                         } elsif ($sort eq 'I') {
 717                                 die "\$user not defined for $call" if !defined $user;
 718
 719                                 # normal input
 720                                 $dxchan->normal($line);
 721                         } elsif ($sort eq 'Z') {
 722                                 $dxchan->disconnect;
 723                         } elsif ($sort eq 'D') {
 724                                 ;                               # ignored (an echo)
 725                         } elsif ($sort eq 'G') {
 726                                 $dxchan->enhanced($line);
 727                         } else {
 728                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 729                         }
 730                 }
 731         }
 732 }
 733
 734 sub handle_xml
 735 {
 736         my $self = shift;
 737         my $r = 0;
 738
 739         if (DXXml::available()) {
 740                 $r = $self->{handle_xml} || 0;
 741         } else {
 742                 delete $self->{handle_xml} if exists $self->{handle_xml};
 743         }
 744         return $r;
 745 }
 746
 747 #no strict;
 748 sub AUTOLOAD
 749 {
 750         no strict;
 751         my $name = $AUTOLOAD;
 752         return if $name =~ /::DESTROY$/;
 753         $name =~ s/^.*:://o;
 754
 755         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 756
 757         # this clever line of code creates a subroutine which takes over from autoload
 758         # from OO Perl - Conway
 759         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 760         goto &$AUTOLOAD;
 761 }
 762
 763
 764 1;
 765 __END__;