perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = undef;
  38
  39 %valid = (
  40   call => '0,Callsign',
  41   conn => '9,Msg Conn ref',
  42   user => '9,DXUser ref',
  43   startt => '0,Start Time,atime',
  44   t => '9,Time,atime',
  45   pc50_t => '9,Last PC50 Time,atime',
  46   priv => '9,Privilege',
  47   state => '0,Current State',
  48   oldstate => '5,Last State',
  49   list => '9,Dep Chan List',
  50   name => '0,User Name',
  51   consort => '9,Connection Type',
  52   sort => '9,Type of Channel',
  53   wwv => '0,Want WWV,yesno',
  54   talk => '0,Want Talk,yesno',
  55   ann => '0,Want Announce,yesno',
  56   here => '0,Here?,yesno',
  57   confmode => '0,In Conference?,yesno',
  58   dx => '0,DX Spots,yesno',
  59   redirect => '0,Redirect messages to',
  60   lang => '0,Language',
  61   func => '9,Function',
  62   loc => '9,Local Vars',     # used by func to store local variables in
  63   beep => '0,Want Beeps,yesno',
  64   lastread => '9,Last Msg Read',
  65   outbound => '9,outbound?,yesno',
  66   remotecmd => '9,doing rcmd,yesno',
  67   pagelth => '0,Page Length',
  68   pagedata => '9,Page Data Store',
  69   group => '0,Access Group,parray',               # used to create a group of users/nodes for some purpose or other
  70 );
  71
  72 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  73 sub alloc
  74 {
  75   my ($pkg, $call, $conn, $user) = @_;
  76   my $self = {};
  77
  78   die "trying to create a duplicate channel for $call" if $channels{$call};
  79   $self->{call} = $call;
  80   $self->{conn} = $conn if defined $conn;   # if this isn't defined then it must be a list
  81   $self->{user} = $user if defined $user;
  82   $self->{startt} = $self->{t} = time;
  83   $self->{state} = 0;
  84   $self->{oldstate} = 0;
  85   $self->{lang} = $user->{lang} if defined $user;
  86   $self->{lang} = $main::lang if !$self->{lang};
  87   $user->new_group() if !$user->group;
  88   $self->{group} = $user->group;
  89   bless $self, $pkg;
  90   return $channels{$call} = $self;
  91 }
  92
  93 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
  94 sub get
  95 {
  96   my ($pkg, $call) = @_;
  97   return $channels{$call};
  98 }
  99
 100 # obtain all the channel objects
 101 sub get_all
 102 {
 103   my ($pkg) = @_;
 104   return values(%channels);
 105 }
 106
 107 # obtain a channel object by searching for its connection reference
 108 sub get_by_cnum
 109 {
 110   my ($pkg, $conn) = @_;
 111   my $self;
 112
 113   foreach $self (values(%channels)) {
 114     return $self if ($self->{conn} == $conn);
 115   }
 116   return undef;
 117 }
 118
 119 # get rid of a channel object [$obj->del()]
 120 sub del
 121 {
 122   my $self = shift;
 123   $self->{group} = undef;      # belt and braces
 124   delete $channels{$self->{call}};
 125 }
 126
 127 # is it an ak1a cluster ?
 128 sub is_ak1a
 129 {
 130   my $self = shift;
 131   return $self->{sort} eq 'A';
 132 }
 133
 134 # is it a user?
 135 sub is_user
 136 {
 137   my $self = shift;
 138   return $self->{sort} eq 'U';
 139 }
 140
 141 # is it a connect type
 142 sub is_connect
 143 {
 144   my $self = shift;
 145   return $self->{sort} eq 'C';
 146 }
 147
 148 # handle out going messages, immediately without waiting for the select to drop
 149 # this could, in theory, block
 150 sub send_now
 151 {
 152   my $self = shift;
 153   my $conn = $self->{conn};
 154   my $sort = shift;
 155   my $call = $self->{call};
 156   my $line;
 157
 158   foreach $line (@_) {
 159     chomp $line;
 160         $conn->send_now("$sort$call|$line") if $conn;
 161         dbg('chan', "-> $sort $call $line") if $conn;
 162   }
 163   $self->{t} = time;
 164 }
 165
 166 #
 167 # the normal output routine
 168 #
 169 sub send              # this is always later and always data
 170 {
 171   my $self = shift;
 172   my $conn = $self->{conn};
 173   my $call = $self->{call};
 174   my $line;
 175
 176   foreach $line (@_) {
 177     chomp $line;
 178         $conn->send_later("D$call|$line") if $conn;
 179         dbg('chan', "-> D $call $line") if $conn;
 180   }
 181   $self->{t} = time;
 182 }
 183
 184 # send a file (always later)
 185 sub send_file
 186 {
 187   my ($self, $fn) = @_;
 188   my $call = $self->{call};
 189   my $conn = $self->{conn};
 190   my @buf;
 191
 192   open(F, $fn) or die "can't open $fn for sending file ($!)";
 193   @buf = <F>;
 194   close(F);
 195   $self->send(@buf);
 196 }
 197
 198 # this will implement language independence (in time)
 199 sub msg
 200 {
 201   my $self = shift;
 202   return DXM::msg($self->{lang}, @_);
 203 }
 204
 205 # change the state of the channel - lots of scope for debugging here :-)
 206 sub state
 207 {
 208   my $self = shift;
 209   if (@_) {
 210     $self->{oldstate} = $self->{state};
 211     $self->{state} = shift;
 212     dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 213   }
 214   return $self->{state};
 215 }
 216
 217 # disconnect this channel
 218 sub disconnect
 219 {
 220   my $self = shift;
 221   my $user = $self->{user};
 222   my $conn = $self->{conn};
 223   $self->finish();
 224   $user->close() if defined $user;
 225   $conn->disconnect() if defined $conn;
 226   $self->del();
 227 }
 228
 229 # various access routines
 230
 231 #
 232 # return a list of valid elements
 233 #
 234
 235 sub fields
 236 {
 237   return keys(%valid);
 238 }
 239
 240 #
 241 # return a prompt for a field
 242 #
 243
 244 sub field_prompt
 245 {
 246   my ($self, $ele) = @_;
 247   return $valid{$ele};
 248 }
 249
 250 no strict;
 251 sub AUTOLOAD
 252 {
 253   my $self = shift;
 254   my $name = $AUTOLOAD;
 255   return if $name =~ /::DESTROY$/;
 256   $name =~ s/.*:://o;
 257
 258   confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 259   @_ ? $self->{$name} = shift : $self->{$name} ;
 260 }
 261
 262 1;
 263 __END__;