perl/Route.pm

   1 #
   2 #
   3 # This module impliments the abstracted routing for all protocols and
   4 # is probably what I SHOULD have done the first time.
   5 #
   6 # Heyho.
   7 #
   8 # This is just a container class which I expect to subclass
   9 #
  10 # Copyright (c) 2001 Dirk Koopman G1TLH
  11 #
  12 #
  13 #
  14
  15 package Route;
  16
  17 use DXDebug;
  18 use DXChannel;
  19 use Prefix;
  20 use DXUtil;
  21
  22 use strict;
  23
  24
  25 use vars qw(%list %valid $filterdef $maxlevel);
  26
  27 %valid = (
  28                   parent => '0,Parent Calls,parray',
  29                   call => "0,Callsign",
  30                   flags => "0,Flags,phex",
  31                   dxcc => '0,Country Code',
  32                   itu => '0,ITU Zone',
  33                   cq => '0,CQ Zone',
  34                   state => '0,State',
  35                   city => '0,City',
  36                   ip => '0,IP Address',
  37                  );
  38
  39 $filterdef = bless ([
  40                           # tag, sort, field, priv, special parser
  41                           ['channel', 'c', 0],
  42                           ['channel_dxcc', 'nc', 1],
  43                           ['channel_itu', 'ni', 2],
  44                           ['channel_zone', 'nz', 3],
  45                           ['call', 'c', 4],
  46                           ['by', 'c', 4],
  47                           ['call_dxcc', 'nc', 5],
  48                           ['by_dxcc', 'nc', 5],
  49                           ['call_itu', 'ni', 6],
  50                           ['by_itu', 'ni', 6],
  51                           ['call_zone', 'nz', 7],
  52                           ['by_zone', 'nz', 7],
  53                           ['channel_state', 'ns', 8],
  54                           ['call_state', 'ns', 9],
  55                           ['by_state', 'ns', 9],
  56                          ], 'Filter::Cmd');
  57
  58 $maxlevel = 25;                 # maximum recursion level in Route::config
  59
  60 sub new
  61 {
  62         my ($pkg, $call) = @_;
  63         $pkg = ref $pkg if ref $pkg;
  64
  65         my $self = bless {call => $call}, $pkg;
  66         dbg("create $pkg with $call") if isdbg('routelow');
  67
  68         # add in all the dxcc, itu, zone info
  69         ($self->{dxcc}, $self->{itu}, $self->{cq}, $self->{state}, $self->{city}) =
  70                 Prefix::cty_data($call);
  71
  72         $self->{flags} = here(1);
  73
  74         return $self;
  75 }
  76
  77 #
  78 # get a callsign from a passed reference or a string
  79 #
  80
  81 sub _getcall
  82 {
  83         my $self = shift;
  84         my $thingy = shift;
  85         $thingy = $self unless $thingy;
  86         $thingy = $thingy->call if ref $thingy;
  87         $thingy = uc $thingy if $thingy;
  88         return $thingy;
  89 }
  90
  91 #
  92 # add and delete a callsign to/from a list
  93 #
  94
  95 sub _addlist
  96 {
  97         my $self = shift;
  98         my $field = shift;
  99         my @out;
 100         foreach my $c (@_) {
 101                 confess "Need a ref here" unless ref($c);
 102
 103                 my $call = $c->{call};
 104                 unless (grep $_ eq $call, @{$self->{$field}}) {
 105                         push @{$self->{$field}}, $call;
 106                         dbg(ref($self) . " adding $call to " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 107                         push @out, $c;
 108                 }
 109         }
 110         return @out;
 111 }
 112
 113 sub _dellist
 114 {
 115         my $self = shift;
 116         my $field = shift;
 117         my @out;
 118         foreach my $c (@_) {
 119                 confess "Need a ref here" unless ref($c);
 120                 my $call = $c->{call};
 121                 if (grep $_ eq $call, @{$self->{$field}}) {
 122                         $self->{$field} = [ grep {$_ ne $call} @{$self->{$field}} ];
 123                         dbg(ref($self) . " deleting $call from " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 124                         push @out, $c;
 125                 }
 126         }
 127         return @out;
 128 }
 129
 130 sub is_empty
 131 {
 132         my $self = shift;
 133         return @{$self->{$_[0]}} == 0;
 134 }
 135
 136 #
 137 # flag field constructors/enquirers
 138 #
 139 # These can be called in various ways:-
 140 #
 141 # Route::here or $ref->here returns 1 or 0 depending on value of the here flag
 142 # Route::here(1) returns 2 (the bit value of the here flag)
 143 # $ref->here(1) or $ref->here(0) sets the here flag
 144 #
 145
 146 sub here
 147 {
 148         my $self = shift;
 149         my $r = shift;
 150         return $self ? 2 : 0 unless ref $self;
 151         return ($self->{flags} & 2) ? 1 : 0 unless defined $r;
 152         $self->{flags} = (($self->{flags} & ~2) | ($r ? 2 : 0));
 153         return $r ? 1 : 0;
 154 }
 155
 156 sub conf
 157 {
 158         my $self = shift;
 159         my $r = shift;
 160         return $self ? 1 : 0 unless ref $self;
 161         return ($self->{flags} & 1) ? 1 : 0 unless defined $r;
 162         $self->{flags} = (($self->{flags} & ~1) | ($r ? 1 : 0));
 163         return $r ? 1 : 0;
 164 }
 165
 166 sub parents
 167 {
 168         my $self = shift;
 169         return @{$self->{parent}};
 170 }
 171
 172 #
 173 # display routines
 174 #
 175
 176 sub user_call
 177 {
 178         my $self = shift;
 179         my $call = sprintf "%s", $self->{call};
 180         return $self->here ? "$call" : "($call)";
 181 }
 182
 183 sub config
 184 {
 185         my $self = shift;
 186         my $nodes_only = shift || 0;
 187         my $width = shift || 79;
 188         my $level = shift;
 189         my $seen = shift;
 190         my @out;
 191         my $line;
 192         my $call = $self->{call};
 193         my $printit = 1;
 194
 195         dbg("config: $call nodes: $nodes_only level: $level calls: " . join(',', @_)) if isdbg('routec');
 196
 197         # allow ranges
 198         if (@_) {
 199                 $printit = grep $call =~ m|$_|, @_;
 200         }
 201
 202         if ($printit) {
 203                 my $pcall = $self->user_call;
 204                 $pcall .= ":" . $self->obscount if isdbg('obscount');
 205
 206
 207                 $line = ' ' x ($level*2) . $pcall;
 208                 $pcall = ' ' x length $pcall;
 209
 210                 # recursion detector
 211                 if ((DXChannel::get($call) && $level > 1) || $seen->{$call} || $level > $maxlevel) {
 212                         $line .= ' ...';
 213                         push @out, $line;
 214                         return @out;
 215                 }
 216                 $seen->{$call}++;
 217
 218                 # print users
 219                 unless ($nodes_only) {
 220                         if (@{$self->{users}}) {
 221                                 $line .= '->';
 222                                 foreach my $ucall (sort @{$self->{users}}) {
 223                                         my $uref = Route::User::get($ucall);
 224                                         my $c;
 225                                         if ($uref) {
 226                                                 $c = $uref->user_call;
 227                                         } else {
 228                                                 $c = "$ucall?";
 229                                         }
 230                                         if ((length $line) + (length $c) + 1 < $width) {
 231                                                 $line .= $c . ' ';
 232                                         } else {
 233                                                 $line =~ s/\s+$//;
 234                                                 push @out, $line;
 235                                                 $line = ' ' x ($level*2) . "$pcall->$c ";
 236                                         }
 237                                 }
 238                         }
 239                 }
 240                 $line =~ s/->$//g;
 241                 $line =~ s/\s+$//;
 242                 push @out, $line if length $line;
 243         } else {
 244                 # recursion detector
 245                 if ((DXChannel::get($call) && $level > 1) || $seen->{$call} || $level > $maxlevel) {
 246                         return @out;
 247                 }
 248                 $seen->{$call}++;
 249         }
 250
 251         # deal with more nodes
 252         foreach my $ncall (sort @{$self->{nodes}}) {
 253                 my $nref = Route::Node::get($ncall);
 254
 255                 if ($nref) {
 256                         my $c = $nref->user_call;
 257                         dbg("recursing from $call -> $c") if isdbg('routec');
 258                         my @rout = $nref->config($nodes_only, $width, $level+1, $seen, @_);
 259                         if (@rout && @_) {
 260                                 push @out, ' ' x ($level*2) . $self->user_call unless grep /^\s+$call/, @out;
 261                         }
 262                         push @out, @rout;
 263                 } else {
 264                         push @out, ' ' x (($level+1)*2)  . "$ncall?" if @_ == 0 || (@_ && grep $ncall =~ m|$_|, @_);
 265                 }
 266         }
 267
 268         return @out;
 269 }
 270
 271 sub cluster
 272 {
 273         my $nodes = Route::Node::count();
 274         my $tot = Route::User::count();
 275         my ($users, $maxlocalusers) = DXCommandmode::user_count();
 276         my $maxusers = Route::User::max();
 277         my $uptime = main::uptime();
 278         my $localnodes = $DXChannel::count - $users;
 279
 280         return ($nodes, $tot, $users, $maxlocalusers, $maxusers, $uptime, $localnodes);
 281
 282
 283 }
 284
 285 #
 286 # routing things
 287 #
 288
 289 sub get
 290 {
 291         my $call = shift;
 292         return Route::Node::get($call) || Route::User::get($call);
 293 }
 294
 295 sub findroutes
 296 {
 297         my $call = shift;
 298         my %cand;
 299         my @out;
 300
 301         dbg("ROUTE: findroutes $call") if isdbg('findroutes');
 302
 303         my $nref = Route::get($call);
 304         return () unless $nref;
 305
 306         # we are directly connected, force "best possible" priority, but
 307         # carry on in case user is connected on other nodes.
 308         my $dxchan = DXChannel::get($call);
 309         if ($dxchan) {
 310                 dbg("ROUTE: findroutes $call -> directly connected") if isdbg('findroutes');
 311                 $cand{$call} = 99;
 312         }
 313
 314         # obtain the dxchannels that have seen this thingy
 315         my @parent = $nref->isa('Route::User') ? @{$nref->{parent}} : $call;
 316         foreach my $p (@parent) {
 317                 next if $p eq $main::mycall; # this is dealt with above
 318
 319                 # deal with directly connected nodes, again "best priority"
 320                 $dxchan = DXChannel::get($p);
 321                 if ($dxchan) {
 322                         dbg("ROUTE: findroutes $call -> connected direct via parent $p") if isdbg('findroutes');
 323                         $cand{$p} = 99;
 324                         next;
 325                 }
 326
 327                 my $r = Route::Node::get($p);
 328                 if ($r) {
 329                         my %r = $r->PC92C_dxchan;
 330                         while (my ($k, $v) = each %r) {
 331                                 $cand{$k} = $v if $v > ($cand{$k} || 0);
 332                         }
 333                 }
 334         }
 335
 336         # remove any dxchannels that have gone away
 337         while (my ($k, $v) = each %cand) {
 338                 if (my $dxc = DXChannel::get($k)) {
 339                         push @out, [$v, $dxc];
 340                 }
 341         }
 342
 343         # get a sorted list of dxchannels with the highest hop count first
 344         my @nout = sort {$b->[0] <=> $a->[0]} @out;
 345         if (isdbg('findroutes')) {
 346                 if (@nout) {
 347                         for (@nout) {
 348                                 dbg("ROUTE: findroutes $call -> $_->[0] " . $_->[1]->call);
 349                         }
 350                 }
 351         }
 352
 353         return @nout;
 354 }
 355
 356 # find all the possible dxchannels which this object might be on
 357 sub alldxchan
 358 {
 359         my $self = shift;
 360         my @dxchan = findroutes($self->{call});
 361         return map {$_->[1]} @dxchan;
 362 }
 363
 364 sub dxchan
 365 {
 366         my $self = shift;
 367
 368         # ALWAYS return the locally connected channel if present;
 369         my $dxchan = DXChannel::get($self->call);
 370         return $dxchan if $dxchan;
 371
 372         my @dxchan = $self->alldxchan;
 373         return undef unless @dxchan;
 374
 375         # dxchannels are now returned in order of "closeness"
 376         return $dxchan[0];
 377 }
 378
 379 sub delete_interface
 380 {
 381
 382 }
 383
 384 #
 385 # track destruction
 386 #
 387
 388 sub DESTROY
 389 {
 390         my $self = shift;
 391         my $pkg = ref $self;
 392
 393         dbg("$pkg $self->{call} destroyed") if isdbg('routelow');
 394 }
 395
 396 no strict;
 397 #
 398 # return a list of valid elements
 399 #
 400
 401 sub fields
 402 {
 403         my $pkg = shift;
 404         $pkg = ref $pkg if ref $pkg;
 405     my $val = "${pkg}::valid";
 406         my @out = keys %$val;
 407         push @out, keys %valid;
 408         return @out;
 409 }
 410
 411 #
 412 # return a prompt for a field
 413 #
 414
 415 sub field_prompt
 416 {
 417         my ($self, $ele) = @_;
 418         my $pkg = ref $self;
 419     my $val = "${pkg}::valid";
 420         return $val->{$ele} || $valid{$ele};
 421 }
 422
 423 #
 424 # generic AUTOLOAD for accessors
 425 #
 426 sub AUTOLOAD
 427 {
 428         no strict;
 429         my $name = $AUTOLOAD;
 430         return if $name =~ /::DESTROY$/;
 431         $name =~ s/^.*:://o;
 432
 433         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 434
 435         # this clever line of code creates a subroutine which takes over from autoload
 436         # from OO Perl - Conway
 437         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 438        goto &$AUTOLOAD;
 439
 440 }
 441
 442 1;