perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35
  36 use strict;
  37
  38 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  39                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  40                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  41                         $investigation_int $pc19_version $myprot_version
  42                         %nodehops $baddx $badspotter $badnode $censorpc
  43                         $allowzero $decode_dk0wcy $send_opernam @checklist
  44                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  45                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  46                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  47                         $pc92filterdef
  48                    );
  49
  50 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  51 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  52 $pc92_slug_changes = 60*5;              # slug any changes going outward for this long
  53 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  54 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  55 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  56         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  57                                 # this is actually the partition between "yesterday" and "today" but old.
  58
  59 $pc92filterdef = bless ([
  60                           # tag, sort, field, priv, special parser
  61                           ['call', 'c', 0],
  62                           ['by', 'c', 0],
  63                           ['dxcc', 'nc', 1],
  64                           ['itu', 'ni', 2],
  65                           ['zone', 'nz', 3],
  66                          ], 'Filter::Cmd');
  67
  68
  69 # incoming talk commands
  70 sub handle_10
  71 {
  72         my $self = shift;
  73         my $pcno = shift;
  74         my $line = shift;
  75         my $origin = shift;
  76         my $pc = shift;
  77
  78         # this is to catch loops caused by bad software ...
  79         if (eph_dup($line, $pc10_dupe_age)) {
  80                 return;
  81         }
  82
  83         # will we allow it at all?
  84         if ($censorpc) {
  85                 my @bad;
  86                 if (@bad = BadWords::check($pc->[3])) {
  87                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  88                         return;
  89                 }
  90         }
  91
  92         # is it for me or one of mine?
  93         my ($from, $to, $via, $call, $dxchan);
  94         $from = $pc->[1];
  95         if ($pc->[5] gt ' ') {
  96                 $via = $pc->[2];
  97                 $to = $pc->[5];
  98         } else {
  99                 $to = $pc->[2];
 100         }
 101
 102         # if this is a 'nodx' node then ignore it
 103         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 104                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 105                 return;
 106         }
 107
 108         # if this is a 'bad spotter' user then ignore it
 109         my $nossid = $from;
 110         $nossid =~ s/-\d+$//;
 111         if ($badspotter->in($nossid)) {
 112                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 113                 return;
 114         }
 115
 116         # if we are converting announces to talk is it a dup?
 117         if ($ann_to_talk) {
 118                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 119                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 120                         return;
 121                 }
 122         }
 123
 124         # convert this to a PC93, coming from mycall with origin set and process it as such
 125         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]));
 126 }
 127
 128 # DX Spot handling
 129 sub handle_11
 130 {
 131         my $self = shift;
 132         my $pcno = shift;
 133         my $line = shift;
 134         my $origin = shift;
 135         my $pc = shift;
 136
 137         # route 'foreign' pc26s
 138         if ($pcno == 26) {
 139                 if ($pc->[7] ne $main::mycall) {
 140                         $self->route($pc->[7], $line);
 141                         return;
 142                 }
 143         }
 144
 145 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 146
 147         # is the spotted callsign blank? This should really be trapped earlier but it
 148         # could break other protocol sentences. Also check for lower case characters.
 149         if ($pc->[2] =~ /^\s*$/) {
 150                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 151                 return;
 152         }
 153         if ($pc->[2] =~ /[a-z]/) {
 154                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 155                 return;
 156         }
 157
 158
 159         # if this is a 'nodx' node then ignore it
 160         if ($badnode->in($pc->[7])) {
 161                 dbg("PCPROT: Bad Node $pc->[7], dropped") if isdbg('chanerr');
 162                 return;
 163         }
 164
 165         # if this is a 'bad spotter' or an unknown user then ignore it. BUT if it's got an IP address then allow it through
 166         my $nossid = $pc->[6];
 167         $nossid =~ s/-\d+$//;
 168         if ($badspotter->in($nossid)) {
 169                 dbg("PCPROT: Bad Spotter $pc->[6], dropped") if isdbg('chanerr');
 170                 return;
 171         }
 172 #       unless (is_ipaddr($pc->[8]) || DXUser::get_current($pc->[6])) {
 173 #               dbg("PCPROT: Unknown Spotter $pc->[6], dropped") if isdbg('chanerr');
 174 #               return;
 175 #       }
 176
 177         # convert the date to a unix date
 178         my $d = cltounix($pc->[3], $pc->[4]);
 179         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 180         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 181                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n") if isdbg('chanerr');
 182                 return;
 183         }
 184
 185         # is it 'baddx'
 186         if ($baddx->in($pc->[2]) || BadWords::check($pc->[2])) {
 187                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 188                 return;
 189         }
 190
 191         # do some de-duping
 192         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 193         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 194         if ($pc->[2] =~ /BUST\w*$/) {
 195                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 196                 return;
 197         }
 198         if ($censorpc) {
 199                 my @bad;
 200                 if (@bad = BadWords::check($pc->[5])) {
 201                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 202                         return;
 203                 }
 204         }
 205
 206         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 207         # global spot filtering on INPUT
 208         if ($self->{inspotsfilter}) {
 209                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 210                 unless ($filter) {
 211                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 212                         return;
 213                 }
 214         }
 215
 216         # this goes after the input filtering, but before the add
 217         # so that if it is input filtered, it isn't added to the dup
 218         # list. This allows it to come in from a "legitimate" source
 219         if (Spot::dup(@spot[0..4,5])) {
 220                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         # add it
 225         Spot::add(@spot);
 226
 227         my $ip = '';
 228         $ip ||= $spot[14] if exists $spot[14];
 229         if (isdbg('progress')) {
 230                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 231                 $sip ||= '';
 232                 my $d = ztime($spot[2]);
 233                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 234                 $s .= $spot[3] ? " '$spot[3]'" : q{ ''};
 235                 $s .=  " route: $origin";
 236                 dbg($s);
 237         }
 238
 239         #
 240         # @spot at this point contains:-
 241         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 242         # then  spotted itu, spotted cq, spotters itu, spotters cq
 243         # you should be able to route on any of these
 244         #
 245
 246         # fix up qra locators of known users
 247         my $user = DXUser::get_current($spot[4]);
 248         if ($user) {
 249                 my $qra = $user->qra;
 250                 unless ($qra && is_qra($qra)) {
 251                         my $lat = $user->lat;
 252                         my $long = $user->long;
 253                         if (defined $lat && defined $long) {
 254                                 $user->qra(DXBearing::lltoqra($lat, $long));
 255                                 $user->put;
 256                         }
 257                 }
 258
 259                 # send a remote command to a distant cluster if it is visible and there is no
 260                 # qra locator and we havn't done it for a month.
 261
 262                 unless ($user->qra) {
 263                         my $node;
 264                         my $to = $user->homenode;
 265                         my $last = $user->lastoper || 0;
 266                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 267                                 my $cmd = "forward/opernam $spot[4]";
 268                                 # send the rcmd but we aren't interested in the replies...
 269                                 my $dxchan = $node->dxchan;
 270                                 if ($dxchan && $dxchan->is_clx) {
 271                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 272                                 } else {
 273                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 274                                 }
 275                                 if ($to ne $pc->[7]) {
 276                                         $to = $pc->[7];
 277                                         $node = Route::Node::get($to);
 278                                         if ($node) {
 279                                                 $dxchan = $node->dxchan;
 280                                                 if ($dxchan && $dxchan->is_clx) {
 281                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 282                                                 } else {
 283                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 284                                                 }
 285                                         }
 286                                 }
 287                                 $user->lastoper($main::systime);
 288                                 $user->put;
 289                         }
 290                 }
 291         }
 292
 293         # local processing
 294         if (defined &Local::spot) {
 295                 my $r;
 296                 eval {
 297                         $r = Local::spot($self, @spot);
 298                 };
 299                 return if $r;
 300         }
 301
 302         # DON'T be silly and send on PC26s!
 303         return if $pcno == 26;
 304
 305         # send out the filtered spots
 306         send_dx_spot($self, $line, @spot) if @spot;
 307 }
 308
 309 # announces
 310 sub handle_12
 311 {
 312         my $self = shift;
 313         my $pcno = shift;
 314         my $line = shift;
 315         my $origin = shift;
 316         my $pc = shift;
 317
 318         # announce duplicate checking
 319         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 320
 321         if ($censorpc) {
 322                 my @bad;
 323                 if (@bad = BadWords::check($pc->[3])) {
 324                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 325                         return;
 326                 }
 327         }
 328
 329         # if this is a 'nodx' node then ignore it
 330         if ($badnode->in($pc->[5])) {
 331                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 332                 return;
 333         }
 334
 335         # if this is a 'bad spotter' user then ignore it
 336         my $nossid = $pc->[1];
 337         $nossid =~ s/-\d+$//;
 338         if ($badspotter->in($nossid)) {
 339                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 340                 return;
 341         }
 342
 343         # ignore PC12s from origins that use PCxx protocol
 344         my $oref = Route::get($origin);
 345         if ($oref->do_pc9x) {
 346                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 347                 return;
 348         }
 349
 350         my $dxchan;
 351
 352         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 353                 $self->send_chat(0, $line, @$pc[1..6]);
 354         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 355
 356                 # ignore something that looks like a chat line coming in with sysop
 357                 # flag - this is a kludge...
 358                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 359                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 360                         return;
 361                 }
 362
 363                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 364                 # or one saying 'to <call>' to a talk if we can route to the recipient
 365                 if ($ann_to_talk) {
 366                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 367                         if ($call) {
 368                                 my $ref = Route::get($call);
 369                                 if ($ref) {
 370                                         $dxchan = $ref->dxchan;
 371                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 372                                         return;
 373                                 }
 374                         }
 375                 }
 376
 377                 # send it
 378                 $self->send_announce(0, $line, @$pc[1..6]);
 379         } else {
 380                 $self->route($pc->[2], $line);
 381         }
 382
 383         # local processing
 384         if (defined &Local::ann) {
 385                 my $r;
 386                 eval {
 387                         $r = Local::ann($self, $line, @$pc[1..6]);
 388                 };
 389                 return if $r;
 390         }
 391 }
 392
 393 sub handle_15
 394 {
 395         my $self = shift;
 396         my $pcno = shift;
 397         my $line = shift;
 398         my $origin = shift;
 399         my $pc = shift;
 400
 401         if (eph_dup($line, $eph_pc15_restime)) {
 402                 return;
 403         } else {
 404                 unless ($self->{isolate}) {
 405                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 406                 }
 407         }
 408 }
 409
 410 # incoming user
 411 sub handle_16
 412 {
 413         my $self = shift;
 414         my $pcno = shift;
 415         my $line = shift;
 416         my $origin = shift;
 417         my $pc = shift;
 418
 419         # general checks
 420         my $dxchan;
 421         my $ncall = $pc->[1];
 422         my $newline = "PC16^";
 423
 424         # dos I want users from this channel?
 425         unless ($self->user->wantpc16) {
 426                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 427                 return;
 428         }
 429
 430         # is it me?
 431         if ($ncall eq $main::mycall) {
 432                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 433                 return;
 434         }
 435
 436         my $h;
 437         $h = 1 if DXChannel::get($ncall);
 438         if ($h && $self->{call} ne $ncall) {
 439                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 440                 return;
 441         }
 442
 443         if (eph_dup($line)) {
 444                 return;
 445         }
 446
 447         # isolate now means only accept stuff from this call only
 448         if ($self->{isolate} && $ncall ne $self->{call}) {
 449                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 450                 return;
 451         }
 452
 453         my $parent = Route::Node::get($ncall);
 454
 455         if ($parent) {
 456                 $dxchan = $parent->dxchan;
 457                 if ($dxchan && $dxchan ne $self) {
 458                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 459                         return;
 460                 }
 461
 462                 # input filter if required
 463                 return unless $self->in_filter_route($parent);
 464         } else {
 465                 $parent = Route::Node->new($ncall);
 466         }
 467
 468         unless ($h) {
 469                 if ($parent->via_pc92) {
 470                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 471                         return;
 472                 }
 473         }
 474
 475         my $i;
 476         my @rout;
 477         for ($i = 2; $i < $#$pc; $i++) {
 478                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 479                 next unless $call && $conf && defined $here && is_callsign($call);
 480                 next if $call eq $main::mycall;
 481
 482                 eph_del_regex("^PC17\\^$call\\^$ncall");
 483
 484                 $conf = $conf eq '*';
 485
 486                 # reject this if we think it is a node already
 487                 my $r = Route::Node::get($call);
 488                 my $u = DXUser::get_current($call) unless $r;
 489                 if ($r || ($u && $u->is_node)) {
 490                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 491                         next;
 492                 }
 493
 494                 $r = Route::User::get($call);
 495                 my $flags = Route::here($here)|Route::conf($conf);
 496
 497                 if ($r) {
 498                         my $au = $r->addparent($parent);
 499                         if ($r->flags != $flags) {
 500                                 $r->flags($flags);
 501                                 $au = $r;
 502                         }
 503                         push @rout, $r if $h && $au;
 504                 } else {
 505                         my @ans = $parent->add_user($call, $flags);
 506                         push @rout, @ans if $h && @ans;
 507                 }
 508
 509                 # add this station to the user database, if required
 510                 my $user = DXUser::get_current($ncall);
 511                 $user = DXUser->new($call) unless $user;
 512                 $user->homenode($parent->call) if !$user->homenode;
 513                 $user->node($parent->call);
 514                 $user->lastin($main::systime) unless DXChannel::get($call);
 515                 $user->put;
 516
 517                 # send info to all logged in thingies
 518                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 519                 $self->tell_buddies('loginb', $call, $ncall);
 520         }
 521         if (@rout) {
 522                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 523 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 524         }
 525 }
 526
 527 # remove a user
 528 sub handle_17
 529 {
 530         my $self = shift;
 531         my $pcno = shift;
 532         my $line = shift;
 533         my $origin = shift;
 534         my $pc = shift;
 535
 536         my $dxchan;
 537         my $ncall = $pc->[2];
 538         my $ucall = $pc->[1];
 539
 540         eph_del_regex("^PC16\\^$ncall.*$ucall");
 541
 542         # do I want users from this channel?
 543         unless ($self->user->wantpc16) {
 544                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 545                 return;
 546         }
 547
 548         if ($ncall eq $main::mycall) {
 549                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 550                 return;
 551         }
 552
 553         # isolate now means only accept stuff from this call only
 554         if ($self->{isolate} && $ncall ne $self->{call}) {
 555                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 556                 return;
 557         }
 558
 559         my $uref = Route::User::get($ucall);
 560         unless ($uref) {
 561                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 562                 return;
 563         }
 564         my $parent = Route::Node::get($ncall);
 565         unless ($parent) {
 566                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 567                 return;
 568         }
 569
 570         $dxchan = DXChannel::get($ncall);
 571         if ($dxchan && $dxchan ne $self) {
 572                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 573                 return;
 574         }
 575
 576         unless ($dxchan) {
 577                 if ($parent->via_pc92) {
 578                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 579                         return;
 580                 }
 581         }
 582
 583         if (DXChannel::get($ucall)) {
 584                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 585                 return;
 586         }
 587
 588         # input filter if required and then remove user if present
 589 #               return unless $self->in_filter_route($parent);
 590         $parent->del_user($uref);
 591
 592         # send info to all logged in thingies
 593         my $user = DXUser::get_current($ncall);
 594         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 595         $self->tell_buddies('logoutb', $ucall, $ncall);
 596
 597         if (eph_dup($line)) {
 598                 return;
 599         }
 600
 601         $self->route_pc17($origin, $line, $parent, $uref);
 602 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 603 }
 604
 605 # link request
 606 sub handle_18
 607 {
 608         my $self = shift;
 609         my $pcno = shift;
 610         my $line = shift;
 611         my $origin = shift;
 612         my $pc = shift;
 613
 614         $self->state('init');
 615
 616         my $parent = Route::Node::get($self->{call});
 617
 618         # record the type and version offered
 619         if (my ($version) = $pc->[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 620                 $self->{version} = 53 + $version;
 621                 $self->user->version(53 + $version);
 622                 $parent->version(0 + $version);
 623                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 624                 $self->{build} = 0 + $build;
 625                 $self->user->build(0 + $build);
 626                 $parent->build(0 + $build);
 627                 dbg("DXSpider version $version build $build");
 628                 unless ($self->is_spider) {
 629                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 630                         $self->user->sort('S');
 631                         $self->user->put;
 632                         $self->sort('S');
 633                 }
 634 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 635         } else {
 636                 dbg("Unknown software");
 637                 $self->version(50.0);
 638                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 639                 $self->user->version($self->version);
 640         }
 641
 642         if ($pc->[1] =~ /\bpc9x/) {
 643                 if ($self->{isolate}) {
 644                         dbg("pc9x recognised, but $self->{call} is isolated, using old protocol");
 645                 } elsif (!$self->user->wantpc9x) {
 646                         dbg("pc9x explicitly switched off on $self->{call}, using old protocol");
 647                 } else {
 648                         $self->{do_pc9x} = 1;
 649                         dbg("Do px9x set on $self->{call}");
 650                 }
 651         }
 652
 653         # first clear out any nodes on this dxchannel
 654         my @rout = $parent->del_nodes;
 655         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 656         $self->send_local_config();
 657         $self->send(pc20());
 658 }
 659
 660 sub check_add_node
 661 {
 662         my $call = shift;
 663
 664         # add this station to the user database, if required (don't remove SSID from nodes)
 665         my $user = DXUser::get_current($call);
 666         if (!$user) {
 667                 $user = DXUser->new($call);
 668                 $user->priv(1);         # I have relented and defaulted nodes
 669                 $user->lockout(1);
 670                 $user->homenode($call);
 671                 $user->node($call);
 672                 $user->sort('A');
 673         }
 674         return $user;
 675 }
 676
 677 # incoming cluster list
 678 sub handle_19
 679 {
 680         my $self = shift;
 681         my $pcno = shift;
 682         my $line = shift;
 683         my $origin = shift;
 684         my $pc = shift;
 685
 686         my $i;
 687         my $newline = "PC19^";
 688
 689         # new routing list
 690         my (@rout, @pc92out);
 691
 692         # first get the INTERFACE node
 693         my $parent = Route::Node::get($self->{call});
 694         unless ($parent) {
 695                 dbg("PCPROT: my parent $self->{call} has disappeared");
 696                 $self->disconnect;
 697                 return;
 698         }
 699
 700         my $h;
 701
 702         # parse the PC19
 703         #
 704         # We are making a major change from now on. We are only going to accept
 705         # PC19s from directly connected nodes.  This means that we are probably
 706         # going to throw away most of the data that we are being sent.
 707         #
 708         # The justification for this is that most of it is wrong or out of date
 709         # anyway.
 710         #
 711         # From now on we are only going to believe PC92 data and locally connected
 712         # non-pc92 nodes.
 713         #
 714         for ($i = 1; $i < $#$pc-1; $i += 4) {
 715                 my $here = $pc->[$i];
 716                 my $call = uc $pc->[$i+1];
 717                 my $conf = $pc->[$i+2];
 718                 my $ver = $pc->[$i+3];
 719                 next unless defined $here && defined $conf && is_callsign($call);
 720
 721                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 722
 723                 # check for sane parameters
 724                 #                               $ver = 5000 if $ver eq '0000';
 725                 next unless $ver && $ver =~ /^\d+$/;
 726                 next if $ver < 5000;    # only works with version 5 software
 727                 next if length $call < 3; # min 3 letter callsigns
 728                 next if $call eq $main::mycall || $call eq $main::myalias;
 729
 730                 # check that this PC19 isn't trying to alter the wrong dxchan
 731                 $h = 0;
 732                 my $dxchan = DXChannel::get($call);
 733                 if ($dxchan) {
 734                         if ($dxchan == $self) {
 735                                 $h = 1;
 736                         } else {
 737                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 738                                 next;
 739                         }
 740                 }
 741
 742                 # isolate now means only accept stuff from this call only
 743                 if ($self->{isolate} && $call ne $self->{call}) {
 744                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 745                         next;
 746                 }
 747
 748                 my $user = check_add_node($call);
 749
 750 #               if (eph_dup($genline)) {
 751 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 752 #                       next;
 753 #               }
 754
 755
 756                 unless ($h) {
 757                         if ($parent->via_pc92) {
 758                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 759                                 next;
 760                         }
 761                 }
 762
 763                 my $r = Route::Node::get($call);
 764                 my $flags = Route::here($here)|Route::conf($conf);
 765
 766                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 767                 if ($r) {
 768                         my $ar;
 769                         if ($call ne $parent->call) {
 770                                 if ($self->in_filter_route($r)) {
 771                                         $ar = $parent->add($call, $ver, $flags);
 772 #                                       push @rout, $ar if $ar;
 773                                 } else {
 774                                         next;
 775                                 }
 776                         }
 777                         if ($r->version ne $ver || $r->flags != $flags) {
 778                                 $r->version($ver);
 779                                 $r->flags($flags);
 780                         }
 781                         push @rout, $r;
 782                 } else {
 783                         if ($call eq $self->{call} || $user->wantroutepc19) {
 784                                 my $new = Route->new($call); # throw away
 785                                 if ($self->in_filter_route($new)) {
 786                                         my $ar = $parent->add($call, $ver, $flags);
 787                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 788                                         push @rout, $ar if $ar;
 789                                         push @pc92out, $r if $h;
 790                                 } else {
 791                                         next;
 792                                 }
 793                         }
 794                 }
 795
 796                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 797                 my $mref = DXMsg::get_busy($call);
 798                 $mref->stop_msg($call) if $mref;
 799
 800                 $user->lastin($main::systime) unless DXChannel::get($call);
 801                 $user->put;
 802         }
 803
 804         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 805         # but remember there will only be one (pair) these because any extras will be
 806         # thrown away.
 807         if (@rout) {
 808 #               $self->route_pc21($self->{call}, $line, @rout);
 809                 $self->route_pc19($self->{call}, $line, @rout);
 810         }
 811         if (@pc92out && !$pc92_slug_changes) {
 812                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 813         }
 814 }
 815
 816 # send local configuration
 817 sub handle_20
 818 {
 819         my $self = shift;
 820         my $pcno = shift;
 821         my $line = shift;
 822         my $origin = shift;
 823         my $pc = shift;
 824
 825         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 826                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 827                 $self->{do_pc9x} = 0;
 828         }
 829         $self->send_local_config;
 830         $self->send(pc22());
 831         $self->state('normal');
 832         $self->{lastping} = 0;
 833         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 834 }
 835
 836 # delete a cluster from the list
 837 #
 838 # This should never occur for directly connected nodes.
 839 #
 840 sub handle_21
 841 {
 842         my $self = shift;
 843         my $pcno = shift;
 844         my $line = shift;
 845         my $origin = shift;
 846         my $pc = shift;
 847
 848         my $call = uc $pc->[1];
 849
 850         eph_del_regex("^PC1[679].*$call");
 851
 852         # if I get a PC21 from the same callsign as self then ignore it
 853         if ($call eq $self->{call}) {
 854                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 855                 return;
 856         }
 857
 858         # for the above reason and also because of the check for PC21s coming
 859         # in for self->call from outside being ignored further down
 860         # we don't need any isolation code here, because we will never
 861         # act on a PC21 with self->call in it.
 862
 863         my $parent = Route::Node::get($self->{call});
 864         unless ($parent) {
 865                 dbg("PCPROT: my parent $self->{call} has disappeared");
 866                 $self->disconnect;
 867                 return;
 868         }
 869
 870         my @rout;
 871
 872         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
 873                 my $node = Route::Node::get($call);
 874                 if ($node) {
 875
 876                         if ($node->via_pc92) {
 877                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 878                                 return;
 879                         }
 880
 881                         my $dxchan = DXChannel::get($call);
 882                         if ($dxchan && $dxchan != $self) {
 883                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
 884                                 return;
 885                         }
 886
 887                         # input filter it
 888                         return unless $self->in_filter_route($node);
 889
 890                         # routing objects, force a PC21 if it is local
 891                         push @rout, $node->del($parent);
 892                         push @rout, $call if $dxchan && @rout == 0;
 893                 }
 894         } else {
 895                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
 896                 return;
 897         }
 898
 899         if (eph_dup($line)) {
 900                 return;
 901         }
 902
 903         if (@rout) {
 904                 $self->route_pc21($origin, $line, @rout);
 905 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 906         }
 907 }
 908
 909
 910 sub handle_22
 911 {
 912         my $self = shift;
 913         my $pcno = shift;
 914         my $line = shift;
 915         my $origin = shift;
 916         my $pc = shift;
 917
 918         if ($self->{do_pc9x}) {
 919                 if ($self->{state} ne 'init92') {
 920                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 921                         $self->{do_pc9x} = 0;
 922                 }
 923         }
 924         $self->{lastping} = 0;
 925         $self->state('normal');
 926         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 927 }
 928
 929 # WWV info
 930 sub handle_23
 931 {
 932         my $self = shift;
 933         my $pcno = shift;
 934         my $line = shift;
 935         my $origin = shift;
 936         my $pc = shift;
 937
 938         # route foreign' pc27s
 939         if ($pcno == 27) {
 940                 if ($pc->[8] ne $main::mycall) {
 941                         $self->route($pc->[8], $line);
 942                         return;
 943                 }
 944         }
 945
 946
 947         # do some de-duping
 948         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
 949         my $sfi = unpad($pc->[3]);
 950         my $k = unpad($pc->[4]);
 951         my $i = unpad($pc->[5]);
 952         my ($r) = $pc->[6] =~ /R=(\d+)/;
 953         $r = 0 unless $r;
 954         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
 955                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
 956                 return;
 957         }
 958
 959         # global wwv filtering on INPUT
 960         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
 961         if ($self->{inwwvfilter}) {
 962                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
 963                 unless ($filter) {
 964                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 965                         return;
 966                 }
 967         }
 968         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
 969         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
 970                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 971                 return;
 972         }
 973
 974         # note this only takes the first one it gets
 975         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 976         dbg("WWV: $d $pc->[2], sfi:$sfi k:$k info:$i $pc->[6] $pc->[7] $pc->[8] $r route: $origin") if isdbg('progress');
 977
 978         if (defined &Local::wwv) {
 979                 my $rep;
 980                 eval {
 981                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
 982                 };
 983                 return if $rep;
 984         }
 985
 986         # DON'T be silly and send on PC27s!
 987         return if $pcno == 27;
 988
 989         # broadcast to the eager world
 990         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
 991 }
 992
 993 # set here status
 994 sub handle_24
 995 {
 996         my $self = shift;
 997         my $pcno = shift;
 998         my $line = shift;
 999         my $origin = shift;
1000         my $pc = shift;
1001
1002         my $call = uc $pc->[1];
1003         my ($nref, $uref);
1004         $nref = Route::Node::get($call);
1005         $uref = Route::User::get($call);
1006         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1007
1008         if (eph_dup($line)) {
1009                 return;
1010         }
1011
1012         $nref->here($pc->[2]) if $nref;
1013         $uref->here($pc->[2]) if $uref;
1014         my $ref = $nref || $uref;
1015         return unless $self->in_filter_route($ref);
1016
1017         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1018 }
1019
1020 # merge request
1021 sub handle_25
1022 {
1023         my $self = shift;
1024         my $pcno = shift;
1025         my $line = shift;
1026         my $origin = shift;
1027         my $pc = shift;
1028
1029         if ($pc->[1] ne $main::mycall) {
1030                 $self->route($pc->[1], $line);
1031                 return;
1032         }
1033         if ($pc->[2] eq $main::mycall) {
1034                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1035                 return;
1036         }
1037
1038         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1039
1040         # spots
1041         if ($pc->[3] > 0) {
1042                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1043                 my $in;
1044                 foreach $in (@in) {
1045                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1046                 }
1047         }
1048
1049         # wwv
1050         if ($pc->[4] > 0) {
1051                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1052                 my $in;
1053                 foreach $in (@in) {
1054                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1055                 }
1056         }
1057 }
1058
1059 sub handle_26 {goto &handle_11}
1060 sub handle_27 {goto &handle_23}
1061
1062 # mail/file handling
1063 sub handle_28
1064 {
1065         my $self = shift;
1066         my $pcno = shift;
1067         my $line = shift;
1068         my $origin = shift;
1069         my $pc = shift;
1070
1071         if ($pc->[1] eq $main::mycall) {
1072                 no strict 'refs';
1073                 my $sub = "DXMsg::handle_$pcno";
1074                 &$sub($self, @$pc);
1075         } else {
1076                 $self->route($pc->[1], $line) unless $self->is_clx;
1077         }
1078 }
1079
1080 sub handle_29 {goto &handle_28}
1081 sub handle_30 {goto &handle_28}
1082 sub handle_31 {goto &handle_28}
1083 sub handle_32 {goto &handle_28}
1084 sub handle_33 {goto &handle_28}
1085
1086 sub handle_34
1087 {
1088         my $self = shift;
1089         my $pcno = shift;
1090         my $line = shift;
1091         my $origin = shift;
1092         my $pc = shift;
1093
1094         if (eph_dup($line, $eph_pc34_restime)) {
1095                 return;
1096         } else {
1097                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1098         }
1099 }
1100
1101 # remote command replies
1102 sub handle_35
1103 {
1104         my $self = shift;
1105         my $pcno = shift;
1106         my $line = shift;
1107         my $origin = shift;
1108         my $pc = shift;
1109
1110         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1111         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1112 }
1113
1114 sub handle_36 {goto &handle_34}
1115
1116 # database stuff
1117 sub handle_37
1118 {
1119         my $self = shift;
1120         my $pcno = shift;
1121         my $line = shift;
1122         my $origin = shift;
1123         my $pc = shift;
1124
1125         if ($pc->[1] eq $main::mycall) {
1126                 no strict 'refs';
1127                 my $sub = "DXDb::handle_$pcno";
1128                 &$sub($self, @$pc);
1129         } else {
1130                 $self->route($pc->[1], $line) unless $self->is_clx;
1131         }
1132 }
1133
1134 # node connected list from neighbour
1135 sub handle_38
1136 {
1137         my $self = shift;
1138         my $pcno = shift;
1139         my $line = shift;
1140         my $origin = shift;
1141         my $pc = shift;
1142 }
1143
1144 # incoming disconnect
1145 sub handle_39
1146 {
1147         my $self = shift;
1148         my $pcno = shift;
1149         my $line = shift;
1150         my $origin = shift;
1151         my $pc = shift;
1152
1153         if ($pc->[1] eq $self->{call}) {
1154                 $self->disconnect(1);
1155         } else {
1156                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1157         }
1158 }
1159
1160 sub handle_40 {goto &handle_28}
1161
1162 # user info
1163 sub handle_41
1164 {
1165         my $self = shift;
1166         my $pcno = shift;
1167         my $line = shift;
1168         my $origin = shift;
1169         my $pc = shift;
1170
1171         my $call = $pc->[1];
1172         my $sort = $pc->[2];
1173         my $val = $pc->[3];
1174
1175         my $l = "PC41^$call^$sort";
1176         if (eph_dup($l, $eph_info_restime)) {
1177                 return;
1178         }
1179
1180         # input filter if required
1181         #                       my $ref = Route::get($call) || Route->new($call);
1182         #                       return unless $self->in_filter_route($ref);
1183
1184         if ($val eq $sort || $val =~ /^\s*$/) {
1185                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1186                 return;
1187         }
1188
1189         if ($call eq $main::mycall || $call eq $main::myalias) {
1190                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1191                 return;
1192         }
1193         my $chan = DXChannel::get($call);
1194         if ($chan) {
1195                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1196                 return;
1197         }
1198
1199         # add this station to the user database, if required
1200         my $user = DXUser::get_current($call);
1201         $user = DXUser->new($call) unless $user;
1202
1203         if ($sort == 1) {
1204                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1205                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1206                         return;
1207                 }
1208                 $user->name($val);
1209         } elsif ($sort == 2) {
1210                 $user->qth($val);
1211         } elsif ($sort == 3) {
1212                 if (is_latlong($val)) {
1213                         my ($lat, $long) = DXBearing::stoll($val);
1214                         $user->lat($lat) if $lat;
1215                         $user->long($long) if $long;
1216                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1217                 } else {
1218                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1219                         return;
1220                 }
1221         } elsif ($sort == 4) {
1222                 $user->homenode($val);
1223         } elsif ($sort == 5) {
1224                 if (is_qra(uc $val)) {
1225                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1226                         $user->lat($lat) if $lat && !$user->lat;
1227                         $user->long($long) if $long && !$user->long;
1228                         $user->qra(uc $val);
1229                 } else {
1230                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1231                         return;
1232                 }
1233         }
1234         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1235         $user->put;
1236
1237         unless ($self->{isolate}) {
1238                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1239         }
1240
1241         #  perhaps this IS what we want after all
1242         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1243 }
1244
1245 sub handle_42 {goto &handle_28}
1246
1247
1248 # database
1249 sub handle_44 {goto &handle_37}
1250 sub handle_45 {goto &handle_37}
1251 sub handle_46 {goto &handle_37}
1252 sub handle_47 {goto &handle_37}
1253 sub handle_48 {goto &handle_37}
1254
1255 # message and database
1256 sub handle_49
1257 {
1258         my $self = shift;
1259         my $pcno = shift;
1260         my $line = shift;
1261         my $origin = shift;
1262         my $pc = shift;
1263
1264         if (eph_dup($line)) {
1265                 return;
1266         }
1267
1268         if ($pc->[1] eq $main::mycall) {
1269                 DXMsg::handle_49($self, @$pc);
1270         } else {
1271                 $self->route($pc->[1], $line) unless $self->is_clx;
1272         }
1273 }
1274
1275 # keep alive/user list
1276 sub handle_50
1277 {
1278         my $self = shift;
1279         my $pcno = shift;
1280         my $line = shift;
1281         my $origin = shift;
1282         my $pc = shift;
1283
1284         return if (eph_dup($line));
1285
1286         my $call = $pc->[1];
1287
1288         my $node = Route::Node::get($call);
1289         if ($node) {
1290                 return unless $node->call eq $self->{call};
1291                 $node->usercount($pc->[2]) unless $node->users;
1292                 $node->reset_obs;
1293                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1294
1295                 # input filter if required
1296 #               return unless $self->in_filter_route($node);
1297
1298                 unless ($self->{isolate}) {
1299                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1300                 }
1301 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1302         }
1303 }
1304
1305 # incoming ping requests/answers
1306 sub handle_51
1307 {
1308         my $self = shift;
1309         my $pcno = shift;
1310         my $line = shift;
1311         my $origin = shift;
1312         my $pc = shift;
1313
1314         my $to = $pc->[1];
1315         my $from = $pc->[2];
1316         my $flag = $pc->[3];
1317
1318         if ($to eq $main::myalias) {
1319                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1320                 return;
1321         }
1322
1323         # is it for us?
1324         if ($to eq $main::mycall) {
1325                 if ($flag == 1) {
1326                         $self->send(pc51($from, $to, '0'));
1327                 } else {
1328                         DXXml::Ping::handle_ping_reply($self, $from);
1329                 }
1330         } else {
1331                 if (eph_dup($line)) {
1332                         return;
1333                 }
1334                 # route down an appropriate thingy
1335                 $self->route($to, $line);
1336         }
1337 }
1338
1339 sub handle_61 { goto &handle_11; }
1340
1341 # dunno but route it
1342 sub handle_75
1343 {
1344         my $self = shift;
1345         my $pcno = shift;
1346         my $line = shift;
1347         my $origin = shift;
1348         my $pc = shift;
1349
1350         my $call = $pc->[1];
1351         if ($call ne $main::mycall) {
1352                 $self->route($call, $line);
1353         }
1354 }
1355
1356 # WCY broadcasts
1357 sub handle_73
1358 {
1359         my $self = shift;
1360         my $pcno = shift;
1361         my $line = shift;
1362         my $origin = shift;
1363         my $pc = shift;
1364
1365         my $call = $pc->[1];
1366
1367         # do some de-duping
1368         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1369         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1370                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1371                 return;
1372         }
1373         $pc = [ map { unpad($_) } @$pc ];
1374         if (WCY::dup($d)) {
1375                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1376                 return;
1377         }
1378
1379         my $wcy = WCY::update($d, @$pc[2..12]);
1380         dbg("WCY: " . join(', ', @$pc[2..12]) . " route: $origin") if isdbg('progress');
1381
1382         if (defined &Local::wcy) {
1383                 my $rep;
1384                 eval {
1385                         $rep = Local::wcy($self, @$pc[1..12]);
1386                 };
1387                 return if $rep;
1388         }
1389
1390         # broadcast to the eager world
1391         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1392 }
1393
1394 # remote commands (incoming)
1395 sub handle_84
1396 {
1397         my $self = shift;
1398         my $pcno = shift;
1399         my $line = shift;
1400         my $origin = shift;
1401         my $pc = shift;
1402
1403         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1404 }
1405
1406 # remote command replies
1407 sub handle_85
1408 {
1409         my $self = shift;
1410         my $pcno = shift;
1411         my $line = shift;
1412         my $origin = shift;
1413         my $pc = shift;
1414
1415         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1416 }
1417
1418 # decode a pc92 call: flag call : version : build
1419 sub _decode_pc92_call
1420 {
1421         my $icall = shift;
1422         my @part = split /:/, $icall;
1423         my ($flag, $call) = unpack "A A*", $part[0];
1424         unless (defined $flag && $flag ge '0' && $flag le '7') {
1425                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1426                 return ();
1427         }
1428         unless ($call && is_callsign($call)) {
1429                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1430                 return ();
1431         }
1432         my $is_node = $flag & 4;
1433         my $is_extnode = $flag & 2;
1434         my $here = $flag & 1;
1435         my $ip  = $part[3];
1436         $ip ||= $part[1] if $part[1] && ($part[1] =~ /^(?:\d+\.)+/ || $part[1] =~ /^(?:(?:[abcdef\d]+)?,)+/);
1437         $ip =~ s/,/:/g if $ip;
1438         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2], $ip);
1439 }
1440
1441 # decode a pc92 call: flag call : version : build
1442 sub _encode_pc92_call
1443 {
1444         my $ref = shift;
1445
1446         # plain call or value
1447         return $ref unless ref $ref;
1448
1449         my $ext = shift || 0;
1450         my $flag = 0;
1451         my $call = $ref->call;
1452         my $extra = '';
1453         $flag |= $ref->here ? 1 : 0;
1454         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1455                 $flag |= 4;
1456                 my $dxchan = DXChannel::get($call);
1457                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1458                 if (($ext & 1) && $ref->version) {
1459                         my $version = $ref->version || 1.0;
1460                         $version =  $version * 100 + 5300 if $version < 50;
1461                         $extra .= ":" . $version;
1462                 }
1463         }
1464         if (($ext & 2) && $ref->ip) {
1465                 my $ip = $ref->ip;
1466                 $ip =~ s/:/,/g;
1467                 $extra .= ':' . $ip;
1468         }
1469         return "$flag$call$extra";
1470 }
1471
1472 my %things_add;
1473 my %things_del;
1474
1475 sub _add_thingy
1476 {
1477         my $parent = shift;
1478         my $s = shift;
1479         my $dxchan = shift;
1480         my $hops = shift;
1481
1482         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1483         my @rout;
1484
1485         # remove spurious IPV6 prefix on IPV4 addresses
1486         $ip =~ s/^::ffff:// if $ip;
1487
1488         if ($call) {
1489                 my $ncall = $parent->call;
1490                 if ($is_node) {
1491                         dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1492                         @rout = $parent->add($call, $version, Route::here($here), $ip);
1493                         my $r = Route::Node::get($call);
1494                         $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1495                         if ($ip) {
1496                                 $r->ip($ip);
1497                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1498                         }
1499                 } else {
1500                         dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1501                         @rout = $parent->add_user($call, Route::here($here), $ip);
1502                         $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1503                         my $r = Route::User::get($call);
1504                         if ($ip) {
1505                                 $r->ip($ip);
1506                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1507                         }
1508                 }
1509                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1510                         $things_add{$call} = Route::get($call);
1511                         delete $things_del{$call};
1512                 }
1513         }
1514         return @rout;
1515 }
1516
1517 sub _del_thingy
1518 {
1519         my $parent = shift;
1520         my $s = shift;
1521         my $dxchan = shift;
1522         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1523         my @rout;
1524         if ($call) {
1525                 my $ref;
1526                 if ($is_node) {
1527                         $ref = Route::Node::get($call);
1528                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1529                         @rout = $ref->del($parent) if $ref;
1530                 } else {
1531                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1532                         $ref = Route::User::get($call);
1533                         if ($ref) {
1534                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1535                                 @rout = $parent->del_user($ref);
1536                         }
1537                 }
1538                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1539                         $things_del{$call} = $ref unless exists $things_add{$call};
1540                         delete $things_add{$call};
1541                 }
1542         }
1543         return @rout;
1544 }
1545
1546 # this will only happen if we are slugging changes and
1547 # there are some changes to be sent, it will create an add or a delete
1548 # or both
1549 sub gen_pc92_changes
1550 {
1551         my @add = values %things_add;
1552         my @del = values %things_del;
1553         return (\@add, \@del);
1554 }
1555
1556 sub clear_pc92_changes
1557 {
1558         %things_add = %things_del = ();
1559         $last_pc92_slug = $main::systime;
1560 }
1561
1562 my $_last_time;
1563 my $_last_occurs;
1564 my $_last_pc9x_id;
1565
1566 sub last_pc9x_id
1567 {
1568         return $_last_pc9x_id;
1569 }
1570
1571 sub gen_pc9x_t
1572 {
1573         if (!$_last_time || $_last_time != $main::systime) {
1574                 $_last_time = $main::systime;
1575                 $_last_occurs = 0;
1576                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1577         } else {
1578                 $_last_occurs++;
1579                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1580         }
1581 }
1582
1583 sub check_pc9x_t
1584 {
1585         my $call = shift;
1586         my $t = shift;
1587         my $pc = shift;
1588         my $create = shift;
1589
1590         # check that the time is between 0 >= $t < 86400
1591         unless ($t >= 0 && $t < 86400) {
1592                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1593                 return undef;
1594         }
1595
1596         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1597         my $now = $main::systime - $main::systime_daystart ;
1598         my $diff = abs($now - $t);
1599         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1600                 my $c = ref $call ? $call->call : $call;
1601                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1602                 return undef;
1603         }
1604
1605         my $parent = ref $call ? $call : Route::Node::get($call);
1606         if ($parent) {
1607                 # we only do this for external calls whose routing table
1608                 # record come and go. The reference for mycall is permanent
1609                 # and not that frequently used, it also never times out, so
1610                 # the id on it is completely unreliable. Besides, only commands
1611                 # originating on this box will go through this code...
1612                 if ($parent->call ne $main::mycall) {
1613                         my $lastid = $parent->lastid;
1614                         if (defined $lastid) {
1615                                 if ($t < $lastid) {
1616                                         # note that this is where we determine whether this pc9x has come in yesterday
1617                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1618                                         # duplicate sentence. To determine this we need to do some module 86400
1619                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1620                                         # low numbers that it is a new sentence.
1621                                         #
1622                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1623                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1624                                         # 86378 respectively in the calculation below).
1625                                         #
1626                                         if ($t+86400-$lastid > $pc9x_past_age) {
1627                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1628                                                 return undef;
1629                                         }
1630                                 } elsif ($t == $lastid) {
1631                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1632                                         return undef;
1633                                 } else {
1634                                         # check that if we have a low number in lastid that yesterday's numbers
1635                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1636                                         if ($lastid+86400-$t < $pc9x_past_age) {
1637                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1638                                                 return undef;
1639                                         }
1640                                 }
1641                         }
1642                 }
1643         } elsif ($create) {
1644                 $parent = Route::Node->new($call);
1645         } else {
1646                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1647                 return undef;
1648         }
1649         if (isdbg('pc92dedupe')) {
1650                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1651                 my $val = $parent->{lastid};
1652                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1653                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1654         }
1655         $parent->lastid($t);
1656
1657         return $parent;
1658 }
1659
1660 sub pc92_handle_first_slot
1661 {
1662         my $self = shift;
1663         my $slot = shift;
1664         my $parent = shift;
1665         my $t = shift;
1666         my $hops = shift;
1667         my $oparent = $parent;
1668
1669         my @radd;
1670
1671         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1672         if ($call && $is_node) {
1673                 if ($call eq $main::mycall) {
1674                         dbg("PCPROT: $call looped back onto \$main::mycall ($main::mycall), ignored") if isdbg('chan');
1675                         return;
1676                 }
1677                 if ($call eq $main::myalias) {
1678                         dbg("PCPROT: $call looped back onto \$main::myalias ($main::myalias), ignored") if isdbg('chan');
1679                         return;
1680                 }
1681                 # this is only accepted from my "self".
1682                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1683                 # locally connected. Local nodes always take precedence. But we remember the lastid
1684                 # to try to reduce the number of dupe PC92s for this external node.
1685                 if (DXChannel::get($call) && $call ne $self->{call}) {
1686                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1687                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1688                         return;
1689                 }
1690                 if ($is_extnode) {
1691                         # reparent to external node (note that we must have received a 'C' or 'A' record
1692                         # from the true parent node for this external before we get one for the this node
1693                         unless ($parent = Route::Node::get($call)) {
1694                                 if ($is_extnode && $oparent) {
1695                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
1696                                         $parent = $radd[0];
1697                                 } else {
1698                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1699                                         return;
1700                                 }
1701                         }
1702                         $parent = check_pc9x_t($call, $t, 92) || return;
1703                         $parent->via_pc92(1);
1704                         $parent->PC92C_dxchan($self->{call}, $hops);
1705                 }
1706         } else {
1707                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1708                 return;
1709         }
1710         $parent->here(Route::here($here));
1711         $parent->version($version || $pc19_version) if $version;
1712         $parent->build($build) if $build;
1713         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1714         return ($parent, @radd);
1715 }
1716
1717 # DXSpider routing entries
1718 sub handle_92
1719 {
1720         my $self = shift;
1721         my $pcno = shift;
1722         my $line = shift;
1723         my $origin = shift;
1724         my $pc = shift;
1725
1726         my (@radd, @rdel);
1727
1728         my $pcall = $pc->[1];
1729         my $t = $pc->[2];
1730         my $sort = $pc->[3];
1731         my $hops = $pc->[-1];
1732
1733         # this catches loops of A/Ds
1734 #       if (eph_dup($line, $pc9x_dupe_age)) {
1735 #               return;
1736 #       }
1737
1738         if ($pcall eq $main::mycall) {
1739                 dbg("PCPROT: looped back, ignored") if isdbg('chan');
1740                 return;
1741         }
1742
1743         if ($pcall eq $main::myalias) {
1744                 dbg("PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored") if isdbg('chan');
1745                 return;
1746         }
1747
1748         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1749                 if ($self->{isolate}) {
1750                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
1751                         return;
1752                 } elsif (!$self->user->wantpc9x) {
1753                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
1754                         return;
1755                 } else {
1756                         $self->state('init92');
1757                         $self->{do_pc9x} = 1;
1758                         dbg("DXPROT: Do pc9x set on $pcall");
1759                 }
1760         }
1761         unless ($self->{do_pc9x}) {
1762                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1763                 return;
1764         }
1765
1766         # don't create routing entries for D records that don't already exist
1767         # this is what causes all those PC92 loops!
1768         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1769         my $oparent = $parent;
1770
1771         $parent->do_pc9x(1);
1772         $parent->via_pc92(1);
1773
1774         if ($sort eq 'F' || $sort eq 'R') {
1775
1776                 # this is the route finding section
1777                 # here is where the consequences of the 'find' command
1778                 # are dealt with
1779
1780                 my $from = $pc->[4];
1781                 my $target = $pc->[5];
1782
1783                 if ($sort eq 'F') {
1784                         my $flag;
1785                         my $ref;
1786                         my $dxchan;
1787                         if ($ref = DXChannel::get($target)) {
1788                                 $flag = 1;              # we are directly connected
1789                         } else {
1790                                 $ref = Route::get($target);
1791                                 $dxchan = $ref->dxchan;
1792                                 $flag = 2;
1793                         }
1794                         if ($ref && $flag && $dxchan) {
1795                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1796                                 return;
1797                         }
1798                 } elsif ($sort eq 'R') {
1799                         if (my $dxchan = DXChannel::get($from)) {
1800                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
1801                         } else {
1802                                 my $ref = Route::get($from);
1803                                 if ($ref) {
1804                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1805                                         if (@dxchan) {
1806                                                 $_->send($line) for @dxchan;
1807                                         } else {
1808                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1809                                         }
1810                                 } else {
1811                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1812                                 }
1813                         }
1814                         return;
1815                 }
1816
1817         } elsif ($sort eq 'K') {
1818                 $pc92Kin += length $line;
1819
1820                 # remember the last channel we arrived on
1821                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1822
1823                 my @ent = _decode_pc92_call($pc->[4]);
1824
1825                 if (@ent) {
1826                         my $add;
1827
1828                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
1829                         return unless $parent; # dupe
1830
1831                         push @radd, $add if $add;
1832                         $parent->reset_obs;
1833                         $parent->version($ent[4]) if $ent[4];
1834                         $parent->build($ent[5]) if $ent[5];
1835
1836                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1837                 }
1838         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1839
1840                 $pc92Ain += length $line if $sort eq 'A';
1841                 $pc92Cin += length $line if $sort eq 'C';
1842                 $pc92Din += length $line if $sort eq 'D';
1843
1844                 # remember the last channel we arrived on
1845                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
1846
1847                 # this is the main route section
1848                 # here is where all the routes are created and destroyed
1849
1850                 # cope with missing duplicate node calls in the first slot
1851                 my $me = $pc->[4] || '';
1852                 $me ||= _encode_pc92_call($parent) unless $me ;
1853
1854                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
1855
1856                 if (@ent) {
1857
1858                         # look at the first one which will always be a node of some sort
1859                         # except in the case of 'A' or 'D' in which the $pcall is used
1860                         # otherwise use the node call and update any information
1861                         # that needs to be done.
1862                         my $add;
1863
1864                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
1865                         return unless $parent; # dupe
1866
1867                         shift @ent;
1868                         push @radd, $add if $add;
1869                 }
1870
1871                 # do a pass through removing any references to either mycall
1872                 my @nent;
1873                 for (@ent) {
1874                         my $dxc;
1875                         next unless $_ && @$_;
1876                         if ($_->[0] eq $main::mycall) {
1877                                 dbg("PCPROT: $_->[0] refers to me, ignored") if isdbg('chanerr');
1878                                 next;
1879                         }
1880                         push @nent, $_;
1881                 }
1882
1883                 if ($sort eq 'A') {
1884                         for (@nent) {
1885                                 push @radd, _add_thingy($parent, $_, $self, $hops);
1886                         }
1887                 } elsif ($sort eq 'D') {
1888                         for (@nent) {
1889                                 push @rdel, _del_thingy($parent, $_, $self);
1890                         }
1891                 } elsif ($sort eq 'C') {
1892                         my (@nodes, @users);
1893
1894                         # we reset obscounts on config records as well as K records
1895                         $parent->reset_obs;
1896                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1897
1898                         #
1899                         foreach my $r (@nent) {
1900                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1901                                 if ($r->[0]) {
1902                                         if ($r->[1]) {
1903                                                 push @nodes, $r->[0];
1904                                         } else {
1905                                                 push @users, $r->[0];
1906                                         }
1907                                 } else {
1908                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1909                                 }
1910                         }
1911
1912                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1913
1914                         # add users here
1915                         foreach my $r (@nent) {
1916                                 my $call = $r->[0];
1917                                 if ($call) {
1918                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
1919                                 }
1920                         }
1921                         # del users here
1922                         foreach my $r (@$dnodes) {
1923                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
1924                         }
1925                         foreach my $r (@$dusers) {
1926                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
1927                         }
1928
1929                         # remember this last PC92C for rebroadcast on demand
1930                         $parent->last_PC92C($line);
1931                 } else {
1932                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1933                         return;
1934                 }
1935
1936                 foreach my $r (@rdel) {
1937                         next unless $r;
1938
1939                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1940                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1941                 }
1942                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1943                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1944                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1945                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1946                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1947         }
1948
1949         # broadcast it if we get here
1950         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1951 }
1952
1953 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
1954 # might be on two or more nodes at the same time or that there may be more than
1955 # one equal distance neighbour to a node.
1956 #
1957 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
1958 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
1959 # each and then combined to give a set of dxchans to send the PC9x record down
1960 #
1961 sub find_pc9x_routes
1962 {
1963         my $to = shift;
1964         my $ref = Route::get($to);
1965         my @parent;
1966         my %cand;
1967
1968         if ($ref->isa('Route::User')) {
1969                 my $dxchan = DXChannel::get($to);
1970                 push @parent, $to if $dxchan;
1971                 push @parent, $ref->parents;
1972         } else {
1973                 @parent = $to;
1974         }
1975         foreach my $p (@parent) {
1976                 my $lasthops;
1977                 my @routes = Route::findroutes($p);
1978                 foreach my $r (@routes) {
1979                         $lasthops = $r->[0] unless defined $lasthops;
1980                         if ($r->[0] == $lasthops) {
1981                                 $cand{$r->[1]->call} = $r->[1];
1982                         } else {
1983                                 last;
1984                         }
1985                 }
1986         }
1987         return values %cand;
1988 }
1989
1990 sub handle_93
1991 {
1992         my $self = shift;
1993         my $pcno = shift;
1994         my $line = shift;
1995         my $origin = shift;
1996         my $pc = shift;
1997
1998 #       $self->{do_pc9x} ||= 1;
1999
2000         my $pcall = $pc->[1];                   # this is now checked earlier
2001
2002         # remember that we are converting PC10->PC93 and self will be $main::me if it
2003         # comes from us
2004         unless ($self->{do_pc9x}) {
2005                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2006                 return;
2007         }
2008
2009         my $t = $pc->[2];
2010         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2011
2012         my $to = uc $pc->[3];
2013         my $from = uc $pc->[4];
2014         my $via = uc $pc->[5];
2015         my $text = $pc->[6];
2016         my $onode = uc $pc->[7];
2017         $onode = $pcall if @$pc <= 8;
2018
2019         # this is catch loops caused by bad software ...
2020         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2021                 return;
2022         }
2023
2024         if (isdbg('progress')) {
2025                 my $vs = $via ne '*' ? " via $via" : '';
2026                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text' route: $origin";
2027                 dbg($s);
2028         }
2029
2030         # will we allow it at all?
2031         if ($censorpc) {
2032                 my @bad;
2033                 if (@bad = BadWords::check($text)) {
2034                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
2035                         return;
2036                 }
2037         }
2038
2039         # if this is a 'bad spotter' user then ignore it
2040         my $nossid = $from;
2041         $nossid =~ s/-\d+$//;
2042         if ($badspotter->in($nossid)) {
2043                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
2044                 return;
2045         }
2046
2047         # ignore PC93 coming in from outside this node with a target of local
2048         if ($to eq 'LOCAL' && $self != $main::me) {
2049                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2050                 return;
2051         }
2052
2053         # if it is routeable then then treat it like a talk
2054         my $ref = Route::get($to);
2055         if ($ref) {
2056                 my $dxchan;
2057
2058                 # convert to PC10 or local talks where appropriate
2059                 # PC93 capable nodes of the same hop count all get a copy
2060                 # if there is a PC10 node then it will get a copy and that
2061                 # will be it. Hopefully such a node will not figure highly
2062                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2063                 # note that both local and PC93s at the same time are possible if the
2064                 # user on more than one node.
2065                 my @routes = find_pc9x_routes($to);
2066                 my $lasthops;
2067                 foreach $dxchan (@routes) {
2068                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2069                                 if ($dxchan->{do_pc9x}) {
2070                                         $dxchan->send($line);
2071                                 } else {
2072                                         $dxchan->talk($from, $to, $via, $text, $onode);
2073                                 }
2074                         } else {
2075                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2076                         }
2077                 }
2078                 return;
2079
2080         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2081                 # announces
2082                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2083                 my $wx = $to eq 'WX' ? '1' : '0';
2084                 my $local = $via eq 'LOCAL' ? '*' : $via;
2085
2086                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2087                 return if $via eq 'LOCAL';
2088         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2089                 # chat messages really only locally connected users
2090                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2091         }
2092
2093         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2094         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2095 }
2096
2097 # if get here then rebroadcast the thing with its Hop count decremented (if
2098 # there is one). If it has a hop count and it decrements to zero then don't
2099 # rebroadcast it.
2100 #
2101 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2102 #        REBROADCAST!!!!
2103 #
2104
2105 sub handle_default
2106 {
2107         my $self = shift;
2108         my $pcno = shift;
2109         my $line = shift;
2110         my $origin = shift;
2111         my $pc = shift;
2112
2113         unless (eph_dup($line)) {
2114                 if ($pcno >= 90) {
2115                         my $pcall = $pc->[1];
2116                         unless (is_callsign($pcall)) {
2117                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2118                                 return;
2119                         }
2120                         my $t = $pc->[2];
2121                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2122                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2123                 } else {
2124                         unless ($self->{isolate}) {
2125                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2126                         }
2127                 }
2128         }
2129 }
2130
2131 1;