perl/DXCluster.pm

   1 #
   2 # DX database control routines
   3 #
   4 # This manages the on-line cluster user 'database'
   5 #
   6 # This should all be pretty trees and things, but for now I
   7 # just can't be bothered. If it becomes an issue I shall
   8 # address it.
   9 #
  10 # Copyright (c) 1998 - Dirk Koopman G1TLH
  11 #
  12 # $Id$
  13 #
  14
  15 package DXCluster;
  16
  17 use Exporter;
  18 @ISA = qw(Exporter);
  19 use DXDebug;
  20 use Carp;
  21
  22 use strict;
  23 use vars qw(%cluster %valid);
  24
  25 %cluster = ();                                  # this is where we store the dxcluster database
  26
  27 %valid = (
  28                   mynode => '0,Parent Node,showcall',
  29                   call => '0,Callsign',
  30                   confmode => '0,Conference Mode,yesno',
  31                   here => '0,Here?,yesno',
  32                   dxchan => '5,Channel ref',
  33                   pcversion => '5,Node Version',
  34                   list => '5,User List,dolist',
  35                   users => '0,No of Users',
  36                  );
  37
  38 sub alloc
  39 {
  40         my ($pkg, $dxchan, $call, $confmode, $here) = @_;
  41         die "$call is already alloced" if $cluster{$call};
  42         my $self = {};
  43         $self->{call} = $call;
  44         $self->{confmode} = $confmode;
  45         $self->{here} = $here;
  46         $self->{dxchan} = $dxchan;
  47
  48         $cluster{$call} = bless $self, $pkg;
  49         return $self;
  50 }
  51
  52 # get an entry exactly as it is
  53 sub get_exact
  54 {
  55         my ($pkg, $call) = @_;
  56
  57         # belt and braces
  58         $call = uc $call;
  59
  60         # search for 'as is' only
  61         return $cluster{$call};
  62 }
  63
  64 #
  65 # search for a call in the cluster
  66 # taking into account SSIDs
  67 #
  68 sub get
  69 {
  70         my ($pkg, $call) = @_;
  71
  72         # belt and braces
  73         $call = uc $call;
  74
  75         # search for 'as is'
  76         my $ref = $cluster{$call};
  77         return $ref if $ref;
  78
  79         # search for the unSSIDed one
  80         $call =~ s/-\d+$//o;
  81         $ref = $cluster{$call};
  82         return $ref if $ref;
  83
  84         # search for the SSIDed one
  85         my $i;
  86         for ($i = 1; $i < 17; $i++) {
  87                 $ref = $cluster{"$call-$i"};
  88                 return $ref if $ref;
  89         }
  90         return undef;
  91 }
  92
  93 # get all
  94 sub get_all
  95 {
  96         return values(%cluster);
  97 }
  98
  99 # return a prompt for a field
 100 sub field_prompt
 101 {
 102         my ($self, $ele) = @_;
 103         return $valid{$ele};
 104 }
 105
 106 # this expects a reference to a list in a node NOT a ref to a node
 107 sub dolist
 108 {
 109         my $self = shift;
 110         my $out;
 111         my $ref;
 112
 113         foreach $ref (@{$self}) {
 114                 my $s = $ref->{call};
 115                 $s = "($s)" if !$ref->{here};
 116                 $out .= "$s ";
 117         }
 118         chop $out;
 119         return $out;
 120 }
 121
 122 # this expects a reference to a node
 123 sub showcall
 124 {
 125         my $self = shift;
 126         return $self->{call};
 127 }
 128
 129 # the answer required by show/cluster
 130 sub cluster
 131 {
 132         my $users = DXCommandmode::get_all();
 133         my $uptime = main::uptime();
 134         my $tot = $DXNode::users;
 135
 136         return " $DXNode::nodes nodes, $users local / $tot total users  Max users $DXNode::maxusers  Uptime $uptime";
 137 }
 138
 139 no strict;
 140 sub AUTOLOAD
 141 {
 142         my $self = shift;
 143         my $name = $AUTOLOAD;
 144
 145         return if $name =~ /::DESTROY$/;
 146         $name =~ s/.*:://o;
 147
 148         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 149         @_ ? $self->{$name} = shift : $self->{$name} ;
 150 }
 151
 152 #
 153 # USER special routines
 154 #
 155
 156 package DXNodeuser;
 157
 158 @ISA = qw(DXCluster);
 159
 160 use DXDebug;
 161
 162 use strict;
 163
 164 sub new
 165 {
 166         my ($pkg, $dxchan, $node, $call, $confmode, $here) = @_;
 167
 168         die "tried to add $call when it already exists" if DXCluster->get_exact($call);
 169
 170         my $self = $pkg->alloc($dxchan, $call, $confmode, $here);
 171         $self->{mynode} = $node;
 172         $node->add_user($call, $self);
 173         dbg('cluster', "allocating user $call to $node->{call} in cluster\n");
 174         return $self;
 175 }
 176
 177 sub del
 178 {
 179         my $self = shift;
 180         my $call = $self->{call};
 181         my $node = $self->{mynode};
 182
 183         $node->del_user($call);
 184         dbg('cluster', "deleting user $call from $node->{call} in cluster\n");
 185 }
 186
 187 sub count
 188 {
 189         return $DXNode::users;          # + 1 for ME (naf eh!)
 190 }
 191
 192 no strict;
 193
 194 #
 195 # NODE special routines
 196 #
 197
 198 package DXNode;
 199
 200 @ISA = qw(DXCluster);
 201
 202 use DXDebug;
 203
 204 use strict;
 205 use vars qw($nodes $users $maxusers);
 206
 207 $nodes = 0;
 208 $users = 0;
 209 $maxusers = 0;
 210
 211
 212 sub new
 213 {
 214         my ($pkg, $dxchan, $call, $confmode, $here, $pcversion) = @_;
 215         my $self = $pkg->alloc($dxchan, $call, $confmode, $here);
 216         $self->{pcversion} = $pcversion;
 217         $self->{list} = { } ;
 218         $self->{mynode} = $self;        # for sh/station
 219         $self->{users} = 0;
 220         $nodes++;
 221         dbg('cluster', "allocating node $call to cluster\n");
 222         return $self;
 223 }
 224
 225 # get all the nodes
 226 sub get_all
 227 {
 228         my $list;
 229         my @out;
 230         foreach $list (values(%DXCluster::cluster)) {
 231                 push @out, $list if $list->{pcversion};
 232         }
 233         return @out;
 234 }
 235
 236 sub del
 237 {
 238         my $self = shift;
 239         my $call = $self->{call};
 240         my $ref;
 241
 242         # delete all the listed calls
 243         foreach $ref (values %{$self->{list}}) {
 244                 $ref->del();                    # this also takes them out of this list
 245         }
 246         delete $DXCluster::cluster{$call}; # remove me from the cluster table
 247         dbg('cluster', "deleting node $call from cluster\n");
 248         $users -= $self->{users};    # it may be PC50 updated only therefore > 0
 249         $users = 0 if $users < 0;
 250         $nodes--;
 251         $nodes = 0 if $nodes < 0;
 252 }
 253
 254 sub add_user
 255 {
 256         my $self = shift;
 257         my $call = shift;
 258         my $ref = shift;
 259
 260         $self->{list}->{$call} = $ref; # add this user to the list on this node
 261         $self->{users} = keys %{$self->{list}};
 262         $users++;
 263         $maxusers = $users+$nodes if $users+$nodes > $maxusers;
 264 }
 265
 266 sub del_user
 267 {
 268         my $self = shift;
 269         my $call = shift;
 270
 271         delete $self->{list}->{$call};
 272         delete $DXCluster::cluster{$call}; # remove me from the cluster table
 273         $self->{users} = keys %{$self->{list}};
 274         $users--;
 275         $users = 0, warn "\$users gone neg, reset" if $users < 0;
 276         $maxusers = $users+$nodes if $users+$nodes > $maxusers;
 277 }
 278
 279 sub update_users
 280 {
 281         my $self = shift;
 282         my $count = shift;
 283         $count = 0 unless $count;
 284
 285         $users -= $self->{users};
 286         $self->{users} = $count unless keys %{$self->{list}};
 287         $users += $self->{users};
 288         $maxusers = $users+$nodes if $users+$nodes > $maxusers;
 289 }
 290
 291 sub count
 292 {
 293         return $nodes;                          # + 1 for ME!
 294 }
 295
 296 sub dolist
 297 {
 298
 299 }
 300
 301 sub DESTROY
 302 {
 303         my $self = shift;
 304         undef $self->{list} if $self->{list};
 305 }
 306
 307
 308 1;
 309 __END__