perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   handle_xml => '9,Handles XML,yesno',
 121                   inqueue => '9,Input Queue,parray',
 122                  );
 123
 124 use vars qw($VERSION $BRANCH);
 125 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 126 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 127 $main::build += $VERSION;
 128 $main::branch += $BRANCH;
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group() if !$user->group;
 157                 $self->{group} = $user->group;
 158                 $self->{sort} = $user->sort;
 159         }
 160         $self->{startt} = $self->{t} = time;
 161         $self->{state} = 0;
 162         $self->{oldstate} = 0;
 163         $self->{lang} = $main::lang if !$self->{lang};
 164         $self->{func} = "";
 165
 166         # add in all the dxcc, itu, zone info
 167         my @dxcc = Prefix::extract($call);
 168         if (@dxcc > 0) {
 169                 $self->{dxcc} = $dxcc[1]->dxcc;
 170                 $self->{itu} = $dxcc[1]->itu;
 171                 $self->{cq} = $dxcc[1]->cq;
 172         }
 173         $self->{inqueue} = [];
 174
 175         $count++;
 176         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 177         bless $self, $pkg;
 178         return $channels{$call} = $self;
 179 }
 180
 181 # rebless this channel as something else
 182 sub rebless
 183 {
 184         my $self = shift;
 185         my $class = shift;
 186         return $channels{$self->{call}} = bless $self, $class;
 187 }
 188
 189 sub rec
 190 {
 191         my ($self, $msg) = @_;
 192
 193         # queue the message and the channel object for later processing
 194         if (defined $msg) {
 195                 push @{$self->{inqueue}}, $msg;
 196         }
 197 }
 198
 199 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 200 sub get
 201 {
 202         my $call = shift;
 203         return $channels{$call};
 204 }
 205
 206 # obtain all the channel objects
 207 sub get_all
 208 {
 209         return values(%channels);
 210 }
 211
 212 #
 213 # gimme all the ak1a nodes
 214 #
 215 sub get_all_nodes
 216 {
 217         my $ref;
 218         my @out;
 219         foreach $ref (values %channels) {
 220                 push @out, $ref if $ref->is_node;
 221         }
 222         return @out;
 223 }
 224
 225 # return a list of all users
 226 sub get_all_users
 227 {
 228         my $ref;
 229         my @out;
 230         foreach $ref (values %channels) {
 231                 push @out, $ref if $ref->is_user;
 232         }
 233         return @out;
 234 }
 235
 236 # return a list of all user callsigns
 237 sub get_all_user_calls
 238 {
 239         my $ref;
 240         my @out;
 241         foreach $ref (values %channels) {
 242                 push @out, $ref->{call} if $ref->is_user;
 243         }
 244         return @out;
 245 }
 246
 247 # obtain a channel object by searching for its connection reference
 248 sub get_by_cnum
 249 {
 250         my ($pkg, $conn) = @_;
 251         my $self;
 252
 253         foreach $self (values(%channels)) {
 254                 return $self if ($self->{conn} == $conn);
 255         }
 256         return undef;
 257 }
 258
 259 # get rid of a channel object [$obj->del()]
 260 sub del
 261 {
 262         my $self = shift;
 263
 264         $self->{group} = undef;         # belt and braces
 265         delete $channels{$self->{call}};
 266 }
 267
 268 # is it a bbs
 269 sub is_bbs
 270 {
 271         my $self = shift;
 272         return $self->{'sort'} eq 'B';
 273 }
 274
 275 sub is_node
 276 {
 277         my $self = shift;
 278         return $self->{'sort'} =~ /[ACRSXW]/;
 279 }
 280 # is it an ak1a node ?
 281 sub is_ak1a
 282 {
 283         my $self = shift;
 284         return $self->{'sort'} eq 'A';
 285 }
 286
 287 # is it a user?
 288 sub is_user
 289 {
 290         my $self = shift;
 291         return $self->{'sort'} eq 'U';
 292 }
 293
 294 # is it a clx node
 295 sub is_clx
 296 {
 297         my $self = shift;
 298         return $self->{'sort'} eq 'C';
 299 }
 300
 301 # it is Aranea
 302 sub is_aranea
 303 {
 304         my $self = shift;
 305         return $self->{'sort'} eq 'W';
 306 }
 307
 308 # is it a spider node
 309 sub is_spider
 310 {
 311         my $self = shift;
 312         return $self->{'sort'} eq 'S';
 313 }
 314
 315 # is it a DXNet node
 316 sub is_dxnet
 317 {
 318         my $self = shift;
 319         return $self->{'sort'} eq 'X';
 320 }
 321
 322 # is it a ar-cluster node
 323 sub is_arcluster
 324 {
 325         my $self = shift;
 326         return $self->{'sort'} eq 'R';
 327 }
 328
 329 # for perl 5.004's benefit
 330 sub sort
 331 {
 332         my $self = shift;
 333         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 334 }
 335
 336 # find out whether we are prepared to believe this callsign on this interface
 337 sub is_believed
 338 {
 339         my $self = shift;
 340         my $call = shift;
 341
 342         return grep $call eq $_, $self->user->believe;
 343 }
 344
 345 # handle out going messages, immediately without waiting for the select to drop
 346 # this could, in theory, block
 347 sub send_now
 348 {
 349         my $self = shift;
 350         my $conn = $self->{conn};
 351         return unless $conn;
 352         my $sort = shift;
 353         my $call = $self->{call};
 354
 355         for (@_) {
 356 #               chomp;
 357         my @lines = split /\n/;
 358                 for (@lines) {
 359                         $conn->send_now("$sort$call|$_");
 360                         dbg("-> $sort $call $_") if isdbg('chan');
 361                 }
 362         }
 363         $self->{t} = time;
 364 }
 365
 366 #
 367 # send later with letter (more control)
 368 #
 369
 370 sub send_later
 371 {
 372         my $self = shift;
 373         my $conn = $self->{conn};
 374         return unless $conn;
 375         my $sort = shift;
 376         my $call = $self->{call};
 377
 378         for (@_) {
 379 #               chomp;
 380         my @lines = split /\n/;
 381                 for (@lines) {
 382                         $conn->send_later("$sort$call|$_");
 383                         dbg("-> $sort $call $_") if isdbg('chan');
 384                 }
 385         }
 386         $self->{t} = time;
 387 }
 388
 389 #
 390 # the normal output routine
 391 #
 392 sub send                                                # this is always later and always data
 393 {
 394         my $self = shift;
 395         my $conn = $self->{conn};
 396         return unless $conn;
 397         my $call = $self->{call};
 398
 399         for (@_) {
 400 #               chomp;
 401         my @lines = split /\n/;
 402                 for (@lines) {
 403                         $conn->send_later("D$call|$_");
 404                         dbg("-> D $call $_") if isdbg('chan');
 405                 }
 406         }
 407         $self->{t} = time;
 408 }
 409
 410 # send a file (always later)
 411 sub send_file
 412 {
 413         my ($self, $fn) = @_;
 414         my $call = $self->{call};
 415         my $conn = $self->{conn};
 416         my @buf;
 417
 418         open(F, $fn) or die "can't open $fn for sending file ($!)";
 419         @buf = <F>;
 420         close(F);
 421         $self->send(@buf);
 422 }
 423
 424 # this will implement language independence (in time)
 425 sub msg
 426 {
 427         my $self = shift;
 428         return DXM::msg($self->{lang}, @_);
 429 }
 430
 431 # stick a broadcast on the delayed queue (but only up to 20 items)
 432 sub delay
 433 {
 434         my $self = shift;
 435         my $s = shift;
 436
 437         $self->{delayed} = [] unless $self->{delayed};
 438         push @{$self->{delayed}}, $s;
 439         if (@{$self->{delayed}} >= 20) {
 440                 shift @{$self->{delayed}};   # lose oldest one
 441         }
 442 }
 443
 444 # change the state of the channel - lots of scope for debugging here :-)
 445 sub state
 446 {
 447         my $self = shift;
 448         if (@_) {
 449                 $self->{oldstate} = $self->{state};
 450                 $self->{state} = shift;
 451                 $self->{func} = '' unless defined $self->{func};
 452                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 453
 454                 # if there is any queued up broadcasts then splurge them out here
 455                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 456                         $self->send (@{$self->{delayed}});
 457                         delete $self->{delayed};
 458                 }
 459         }
 460         return $self->{state};
 461 }
 462
 463 # disconnect this channel
 464 sub disconnect
 465 {
 466         my $self = shift;
 467         my $user = $self->{user};
 468
 469         $user->close() if defined $user;
 470         $self->{conn}->disconnect;
 471         $self->del();
 472 }
 473
 474 #
 475 # just close all the socket connections down without any fiddling about, cleaning, being
 476 # nice to other processes and otherwise telling them what is going on.
 477 #
 478 # This is for the benefit of forked processes to prepare for starting new programs, they
 479 # don't want or need all this baggage.
 480 #
 481
 482 sub closeall
 483 {
 484         my $ref;
 485         foreach $ref (values %channels) {
 486                 $ref->{conn}->disconnect() if $ref->{conn};
 487         }
 488 }
 489
 490 #
 491 # Tell all the users that we have come in or out (if they want to know)
 492 #
 493 sub tell_login
 494 {
 495         my ($self, $m) = @_;
 496
 497         # send info to all logged in thingies
 498         my @dxchan = get_all_users();
 499         my $dxchan;
 500         foreach $dxchan (@dxchan) {
 501                 next if $dxchan == $self;
 502                 next if $dxchan->{call} eq $main::mycall;
 503                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 504         }
 505 }
 506
 507 # various access routines
 508
 509 #
 510 # return a list of valid elements
 511 #
 512
 513 sub fields
 514 {
 515         return keys(%valid);
 516 }
 517
 518 #
 519 # return a prompt for a field
 520 #
 521
 522 sub field_prompt
 523 {
 524         my ($self, $ele) = @_;
 525         return $valid{$ele};
 526 }
 527
 528 # take a standard input message and decode it into its standard parts
 529 sub decode_input
 530 {
 531         my $dxchan = shift;
 532         my $data = shift;
 533         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 534
 535         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 536
 537         # the above regexp must work
 538         unless (defined $sort && defined $call && defined $line) {
 539 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 540                 dbg("DUFF Line on $chcall: $data");
 541                 return ();
 542         }
 543
 544         if(ref($dxchan) && $call ne $chcall) {
 545                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 546                 return();
 547         }
 548
 549         return ($sort, $call, $line);
 550 }
 551
 552 sub rspfcheck
 553 {
 554         my ($self, $flag, $node, $user) = @_;
 555         my $nref = Route::Node::get($node);
 556         my $dxchan = $nref->dxchan if $nref;
 557         if ($nref && $dxchan) {
 558             if ($dxchan == $self) {
 559                         return 1 unless $user;
 560                         return 1 if $user eq $node;
 561                         my @users = $nref->users;
 562                         return 1 if @users == 0 || grep $user eq $_, @users;
 563                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 564                 } else {
 565                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 566                 }
 567         } else {
 568                 return 1 if $flag;
 569                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 570         }
 571         return 0;
 572 }
 573
 574 # broadcast a message to all clusters taking into account isolation
 575 # [except those mentioned after buffer]
 576 sub broadcast_nodes
 577 {
 578         my $s = shift;                          # the line to be rebroadcast
 579         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 580         my @dxchan = get_all_nodes();
 581         my $dxchan;
 582
 583         # send it if it isn't the except list and isn't isolated and still has a hop count
 584         foreach $dxchan (@dxchan) {
 585                 next if grep $dxchan == $_, @except;
 586                 next if $dxchan == $main::me;
 587
 588                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 589
 590                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 591         }
 592 }
 593
 594 # broadcast a message to all clusters ignoring isolation
 595 # [except those mentioned after buffer]
 596 sub broadcast_all_nodes
 597 {
 598         my $s = shift;                          # the line to be rebroadcast
 599         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 600         my @dxchan = get_all_nodes();
 601         my $dxchan;
 602
 603         # send it if it isn't the except list and isn't isolated and still has a hop count
 604         foreach $dxchan (@dxchan) {
 605                 next if grep $dxchan == $_, @except;
 606                 next if $dxchan == $main::me;
 607
 608                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 609                 $dxchan->send($routeit);
 610         }
 611 }
 612
 613 # broadcast to all users
 614 # storing the spot or whatever until it is in a state to receive it
 615 sub broadcast_users
 616 {
 617         my $s = shift;                          # the line to be rebroadcast
 618         my $sort = shift;           # the type of transmission
 619         my $fref = shift;           # a reference to an object to filter on
 620         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 621         my @dxchan = get_all_users();
 622         my $dxchan;
 623         my @out;
 624
 625         foreach $dxchan (@dxchan) {
 626                 next if grep $dxchan == $_, @except;
 627                 push @out, $dxchan;
 628         }
 629         broadcast_list($s, $sort, $fref, @out);
 630 }
 631
 632
 633 # broadcast to a list of users
 634 sub broadcast_list
 635 {
 636         my $s = shift;
 637         my $sort = shift;
 638         my $fref = shift;
 639         my $dxchan;
 640
 641         foreach $dxchan (@_) {
 642                 my $filter = 1;
 643                 next if $dxchan == $main::me;
 644
 645                 if ($sort eq 'dx') {
 646                     next unless $dxchan->{dx};
 647                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 648                         next unless $filter;
 649                 }
 650                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 651                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 652                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 653                 next if $sort eq 'wx' && !$dxchan->{wx};
 654
 655                 $s =~ s/\a//og unless $dxchan->{beep};
 656
 657                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 658                         $dxchan->send($s);
 659                 } else {
 660                         $dxchan->delay($s);
 661                 }
 662         }
 663 }
 664
 665 sub process
 666 {
 667         foreach my $dxchan (get_all()) {
 668
 669                 while (my $data = shift @{$dxchan->{inqueue}}) {
 670                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 671                         next unless defined $sort;
 672
 673                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 674                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 675                         if ($dxchan->{disconnecting}) {
 676                                 dbg('In disconnection, ignored');
 677                                 next;
 678                         }
 679
 680                         # handle A records
 681                         my $user = $dxchan->user;
 682                         if ($sort eq 'A' || $sort eq 'O') {
 683                                 $dxchan->start($line, $sort);
 684                         } elsif ($sort eq 'I') {
 685                                 die "\$user not defined for $call" if !defined $user;
 686
 687                                 # normal input
 688                                 $dxchan->normal($line);
 689                         } elsif ($sort eq 'Z') {
 690                                 $dxchan->disconnect;
 691                         } elsif ($sort eq 'D') {
 692                                 ;                               # ignored (an echo)
 693                         } elsif ($sort eq 'G') {
 694                                 $dxchan->enhanced($line);
 695                         } else {
 696                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 697                         }
 698                 }
 699         }
 700 }
 701
 702 #no strict;
 703 sub AUTOLOAD
 704 {
 705         no strict;
 706         my $name = $AUTOLOAD;
 707         return if $name =~ /::DESTROY$/;
 708         $name =~ s/^.*:://o;
 709
 710         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 711
 712         # this clever line of code creates a subroutine which takes over from autoload
 713         # from OO Perl - Conway
 714         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 715         goto &$AUTOLOAD;
 716 }
 717
 718
 719 1;
 720 __END__;