perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   do_pc9x => '9,Handles PC9x,yesno',
 123                   inqueue => '9,Input Queue,parray',
 124                   next_pc92_update => '9,Next PC92 Update,atime',
 125                  );
 126
 127 # object destruction
 128 sub DESTROY
 129 {
 130         my $self = shift;
 131         for (keys %$self) {
 132                 if (ref($self->{$_})) {
 133                         delete $self->{$_};
 134                 }
 135         }
 136         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 137         $count--;
 138 }
 139
 140 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 141 sub alloc
 142 {
 143         my ($pkg, $call, $conn, $user) = @_;
 144         my $self = {};
 145
 146         die "trying to create a duplicate channel for $call" if $channels{$call};
 147         $self->{call} = $call;
 148         $self->{priv} = 0;
 149         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 150         if (defined $user) {
 151                 $self->{user} = $user;
 152                 $self->{lang} = $user->lang;
 153                 $user->new_group unless $user->group;
 154                 $user->new_buddies unless $user->buddies;
 155                 $self->{group} = $user->group;
 156                 $self->{sort} = $user->sort;
 157         }
 158         $self->{startt} = $self->{t} = time;
 159         $self->{state} = 0;
 160         $self->{oldstate} = 0;
 161         $self->{lang} = $main::lang if !$self->{lang};
 162         $self->{func} = "";
 163
 164         # add in all the dxcc, itu, zone info
 165         my @dxcc = Prefix::extract($call);
 166         if (@dxcc > 0) {
 167                 $self->{dxcc} = $dxcc[1]->dxcc;
 168                 $self->{itu} = $dxcc[1]->itu;
 169                 $self->{cq} = $dxcc[1]->cq;
 170         }
 171         $self->{inqueue} = [];
 172
 173         $count++;
 174         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 175         bless $self, $pkg;
 176         return $channels{$call} = $self;
 177 }
 178
 179 # rebless this channel as something else
 180 sub rebless
 181 {
 182         my $self = shift;
 183         my $class = shift;
 184         return $channels{$self->{call}} = bless $self, $class;
 185 }
 186
 187 sub rec
 188 {
 189         my ($self, $msg) = @_;
 190
 191         # queue the message and the channel object for later processing
 192         if (defined $msg) {
 193                 push @{$self->{inqueue}}, $msg;
 194         }
 195 }
 196
 197 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 198 sub get
 199 {
 200         my $call = shift;
 201         return $channels{$call};
 202 }
 203
 204 # obtain all the channel objects
 205 sub get_all
 206 {
 207         return values(%channels);
 208 }
 209
 210 #
 211 # gimme all the ak1a nodes
 212 #
 213 sub get_all_nodes
 214 {
 215         my $ref;
 216         my @out;
 217         foreach $ref (values %channels) {
 218                 push @out, $ref if $ref->is_node;
 219         }
 220         return @out;
 221 }
 222
 223 # return a list of all users
 224 sub get_all_users
 225 {
 226         my $ref;
 227         my @out;
 228         foreach $ref (values %channels) {
 229                 push @out, $ref if $ref->is_user;
 230         }
 231         return @out;
 232 }
 233
 234 # return a list of all user callsigns
 235 sub get_all_user_calls
 236 {
 237         my $ref;
 238         my @out;
 239         foreach $ref (values %channels) {
 240                 push @out, $ref->{call} if $ref->is_user;
 241         }
 242         return @out;
 243 }
 244
 245 # obtain a channel object by searching for its connection reference
 246 sub get_by_cnum
 247 {
 248         my ($pkg, $conn) = @_;
 249         my $self;
 250
 251         foreach $self (values(%channels)) {
 252                 return $self if ($self->{conn} == $conn);
 253         }
 254         return undef;
 255 }
 256
 257 # get rid of a channel object [$obj->del()]
 258 sub del
 259 {
 260         my $self = shift;
 261
 262         $self->{group} = undef;         # belt and braces
 263         delete $channels{$self->{call}};
 264 }
 265
 266 # is it a bbs
 267 sub is_bbs
 268 {
 269         my $self = shift;
 270         return $self->{'sort'} eq 'B';
 271 }
 272
 273 sub is_node
 274 {
 275         my $self = shift;
 276         return $self->{'sort'} =~ /[ACRSXW]/;
 277 }
 278 # is it an ak1a node ?
 279 sub is_ak1a
 280 {
 281         my $self = shift;
 282         return $self->{'sort'} eq 'A';
 283 }
 284
 285 # is it a user?
 286 sub is_user
 287 {
 288         my $self = shift;
 289         return $self->{'sort'} eq 'U';
 290 }
 291
 292 # is it a clx node
 293 sub is_clx
 294 {
 295         my $self = shift;
 296         return $self->{'sort'} eq 'C';
 297 }
 298
 299 # it is Aranea
 300 sub is_aranea
 301 {
 302         my $self = shift;
 303         return $self->{'sort'} eq 'W';
 304 }
 305
 306 # is it a spider node
 307 sub is_spider
 308 {
 309         my $self = shift;
 310         return $self->{'sort'} eq 'S';
 311 }
 312
 313 # is it a DXNet node
 314 sub is_dxnet
 315 {
 316         my $self = shift;
 317         return $self->{'sort'} eq 'X';
 318 }
 319
 320 # is it a ar-cluster node
 321 sub is_arcluster
 322 {
 323         my $self = shift;
 324         return $self->{'sort'} eq 'R';
 325 }
 326
 327 # for perl 5.004's benefit
 328 sub sort
 329 {
 330         my $self = shift;
 331         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 332 }
 333
 334 # find out whether we are prepared to believe this callsign on this interface
 335 sub is_believed
 336 {
 337         my $self = shift;
 338         my $call = shift;
 339
 340         return grep $call eq $_, $self->user->believe;
 341 }
 342
 343 # handle out going messages, immediately without waiting for the select to drop
 344 # this could, in theory, block
 345 sub send_now
 346 {
 347         my $self = shift;
 348         my $conn = $self->{conn};
 349         return unless $conn;
 350         my $sort = shift;
 351         my $call = $self->{call};
 352
 353         for (@_) {
 354 #               chomp;
 355         my @lines = split /\n/;
 356                 for (@lines) {
 357                         $conn->send_now("$sort$call|$_");
 358                         # debug log it, but not if it is a log message
 359                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 360                 }
 361         }
 362         $self->{t} = time;
 363 }
 364
 365 #
 366 # send later with letter (more control)
 367 #
 368
 369 sub send_later
 370 {
 371         my $self = shift;
 372         my $conn = $self->{conn};
 373         return unless $conn;
 374         my $sort = shift;
 375         my $call = $self->{call};
 376
 377         for (@_) {
 378 #               chomp;
 379         my @lines = split /\n/;
 380                 for (@lines) {
 381                         $conn->send_later("$sort$call|$_");
 382                         # debug log it, but not if it is a log message
 383                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 384                 }
 385         }
 386         $self->{t} = time;
 387 }
 388
 389 #
 390 # the normal output routine
 391 #
 392 sub send                                                # this is always later and always data
 393 {
 394         my $self = shift;
 395         my $conn = $self->{conn};
 396         return unless $conn;
 397         my $call = $self->{call};
 398
 399         foreach my $l (@_) {
 400                 for (ref $l ? @$l : $l) {
 401                         my @lines = split /\n/;
 402                         for (@lines) {
 403                                 $conn->send_later("D$call|$_");
 404                                 dbg("-> D $call $_") if isdbg('chan');
 405                         }
 406                 }
 407         }
 408         $self->{t} = $main::systime;
 409 }
 410
 411 # send a file (always later)
 412 sub send_file
 413 {
 414         my ($self, $fn) = @_;
 415         my $call = $self->{call};
 416         my $conn = $self->{conn};
 417         my @buf;
 418
 419         open(F, $fn) or die "can't open $fn for sending file ($!)";
 420         @buf = <F>;
 421         close(F);
 422         $self->send(@buf);
 423 }
 424
 425 # this will implement language independence (in time)
 426 sub msg
 427 {
 428         my $self = shift;
 429         return DXM::msg($self->{lang}, @_);
 430 }
 431
 432 # stick a broadcast on the delayed queue (but only up to 20 items)
 433 sub delay
 434 {
 435         my $self = shift;
 436         my $s = shift;
 437
 438         $self->{delayed} = [] unless $self->{delayed};
 439         push @{$self->{delayed}}, $s;
 440         if (@{$self->{delayed}} >= 20) {
 441                 shift @{$self->{delayed}};   # lose oldest one
 442         }
 443 }
 444
 445 # change the state of the channel - lots of scope for debugging here :-)
 446 sub state
 447 {
 448         my $self = shift;
 449         if (@_) {
 450                 $self->{oldstate} = $self->{state};
 451                 $self->{state} = shift;
 452                 $self->{func} = '' unless defined $self->{func};
 453                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 454
 455                 # if there is any queued up broadcasts then splurge them out here
 456                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 457                         $self->send (@{$self->{delayed}});
 458                         delete $self->{delayed};
 459                 }
 460         }
 461         return $self->{state};
 462 }
 463
 464 # disconnect this channel
 465 sub disconnect
 466 {
 467         my $self = shift;
 468         my $user = $self->{user};
 469
 470         $user->close() if defined $user;
 471         $self->{conn}->disconnect if $self->{conn};
 472         $self->del();
 473 }
 474
 475 #
 476 # just close all the socket connections down without any fiddling about, cleaning, being
 477 # nice to other processes and otherwise telling them what is going on.
 478 #
 479 # This is for the benefit of forked processes to prepare for starting new programs, they
 480 # don't want or need all this baggage.
 481 #
 482
 483 sub closeall
 484 {
 485         my $ref;
 486         foreach $ref (values %channels) {
 487                 $ref->{conn}->disconnect() if $ref->{conn};
 488         }
 489 }
 490
 491 #
 492 # Tell all the users that we have come in or out (if they want to know)
 493 #
 494 sub tell_login
 495 {
 496         my ($self, $m, $call) = @_;
 497
 498         $call ||= $self->{call};
 499
 500         # send info to all logged in thingies
 501         my @dxchan = get_all_users();
 502         my $dxchan;
 503         foreach $dxchan (@dxchan) {
 504                 next if $dxchan == $self;
 505                 next if $dxchan->{call} eq $main::mycall;
 506                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 507         }
 508 }
 509
 510 #
 511 # Tell all the users if a buddy is logged or out
 512 #
 513 sub tell_buddies
 514 {
 515         my ($self, $m, $call, $node) = @_;
 516
 517         $call ||= $self->{call};
 518         $call =~ s/-\d+$//;
 519         $m .= 'n' if $node;
 520
 521         # send info to all logged in thingies
 522         my @dxchan = get_all_users();
 523         my $dxchan;
 524         foreach $dxchan (@dxchan) {
 525                 next if $dxchan == $self;
 526                 next if $dxchan->{call} eq $main::mycall;
 527                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 528         }
 529 }
 530
 531 # various access routines
 532
 533 #
 534 # return a list of valid elements
 535 #
 536
 537 sub fields
 538 {
 539         return keys(%valid);
 540 }
 541
 542 #
 543 # return a prompt for a field
 544 #
 545
 546 sub field_prompt
 547 {
 548         my ($self, $ele) = @_;
 549         return $valid{$ele};
 550 }
 551
 552 # take a standard input message and decode it into its standard parts
 553 sub decode_input
 554 {
 555         my $dxchan = shift;
 556         my $data = shift;
 557         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 558
 559         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 560
 561         # the above regexp must work
 562         unless (defined $sort && defined $call && defined $line) {
 563 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 564                 dbg("DUFF Line on $chcall: $data");
 565                 return ();
 566         }
 567
 568         if(ref($dxchan) && $call ne $chcall) {
 569                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 570                 return();
 571         }
 572
 573         return ($sort, $call, $line);
 574 }
 575
 576 sub rspfcheck
 577 {
 578         my ($self, $flag, $node, $user) = @_;
 579         my $nref = Route::Node::get($node);
 580         my $dxchan = $nref->dxchan if $nref;
 581         if ($nref && $dxchan) {
 582             if ($dxchan == $self) {
 583                         return 1 unless $user;
 584                         return 1 if $user eq $node;
 585                         my @users = $nref->users;
 586                         return 1 if @users == 0 || grep $user eq $_, @users;
 587                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 588                 } else {
 589                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 590                 }
 591         } else {
 592                 return 1 if $flag;
 593                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 594         }
 595         return 0;
 596 }
 597
 598 # broadcast a message to all clusters taking into account isolation
 599 # [except those mentioned after buffer]
 600 sub broadcast_nodes
 601 {
 602         my $s = shift;                          # the line to be rebroadcast
 603         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 604         my @dxchan = get_all_nodes();
 605         my $dxchan;
 606
 607         # send it if it isn't the except list and isn't isolated and still has a hop count
 608         foreach $dxchan (@dxchan) {
 609                 next if grep $dxchan == $_, @except;
 610                 next if $dxchan == $main::me;
 611
 612                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 613
 614                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 615         }
 616 }
 617
 618 # broadcast a message to all clusters ignoring isolation
 619 # [except those mentioned after buffer]
 620 sub broadcast_all_nodes
 621 {
 622         my $s = shift;                          # the line to be rebroadcast
 623         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 624         my @dxchan = get_all_nodes();
 625         my $dxchan;
 626
 627         # send it if it isn't the except list and isn't isolated and still has a hop count
 628         foreach $dxchan (@dxchan) {
 629                 next if grep $dxchan == $_, @except;
 630                 next if $dxchan == $main::me;
 631
 632                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 633                 $dxchan->send($routeit);
 634         }
 635 }
 636
 637 # broadcast to all users
 638 # storing the spot or whatever until it is in a state to receive it
 639 sub broadcast_users
 640 {
 641         my $s = shift;                          # the line to be rebroadcast
 642         my $sort = shift;           # the type of transmission
 643         my $fref = shift;           # a reference to an object to filter on
 644         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 645         my @dxchan = get_all_users();
 646         my $dxchan;
 647         my @out;
 648
 649         foreach $dxchan (@dxchan) {
 650                 next if grep $dxchan == $_, @except;
 651                 push @out, $dxchan;
 652         }
 653         broadcast_list($s, $sort, $fref, @out);
 654 }
 655
 656
 657 # broadcast to a list of users
 658 sub broadcast_list
 659 {
 660         my $s = shift;
 661         my $sort = shift;
 662         my $fref = shift;
 663         my $dxchan;
 664
 665         foreach $dxchan (@_) {
 666                 my $filter = 1;
 667                 next if $dxchan == $main::me;
 668
 669                 if ($sort eq 'dx') {
 670                     next unless $dxchan->{dx};
 671                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 672                         next unless $filter;
 673                 }
 674                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 675                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 676                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 677                 next if $sort eq 'wx' && !$dxchan->{wx};
 678
 679                 $s =~ s/\a//og unless $dxchan->{beep};
 680
 681                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 682                         $dxchan->send($s);
 683                 } else {
 684                         $dxchan->delay($s);
 685                 }
 686         }
 687 }
 688
 689 sub process
 690 {
 691         foreach my $dxchan (get_all()) {
 692
 693                 while (my $data = shift @{$dxchan->{inqueue}}) {
 694                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 695                         next unless defined $sort;
 696
 697                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 698                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 699                         if ($dxchan->{disconnecting}) {
 700                                 dbg('In disconnection, ignored');
 701                                 next;
 702                         }
 703
 704                         # handle A records
 705                         my $user = $dxchan->user;
 706                         if ($sort eq 'A' || $sort eq 'O') {
 707                                 $dxchan->start($line, $sort);
 708                         } elsif ($sort eq 'I') {
 709                                 die "\$user not defined for $call" if !defined $user;
 710
 711                                 # normal input
 712                                 $dxchan->normal($line);
 713                         } elsif ($sort eq 'Z') {
 714                                 $dxchan->disconnect;
 715                         } elsif ($sort eq 'D') {
 716                                 ;                               # ignored (an echo)
 717                         } elsif ($sort eq 'G') {
 718                                 $dxchan->enhanced($line);
 719                         } else {
 720                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 721                         }
 722                 }
 723         }
 724 }
 725
 726 sub handle_xml
 727 {
 728         my $self = shift;
 729         my $r = 0;
 730
 731         if (DXXml::available()) {
 732                 $r = $self->{handle_xml} || 0;
 733         } else {
 734                 delete $self->{handle_xml} if exists $self->{handle_xml};
 735         }
 736         return $r;
 737 }
 738
 739 #no strict;
 740 sub AUTOLOAD
 741 {
 742         no strict;
 743         my $name = $AUTOLOAD;
 744         return if $name =~ /::DESTROY$/;
 745         $name =~ s/^.*:://o;
 746
 747         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 748
 749         # this clever line of code creates a subroutine which takes over from autoload
 750         # from OO Perl - Conway
 751         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 752         goto &$AUTOLOAD;
 753 }
 754
 755
 756 1;
 757 __END__;