perl/AsyncMsg.pm

   1 #
   2 # This class is the internal subclass that does various Async connects and
   3 # retreivals of info. Typical uses (and specific support) include http get and
   4 # post.
   5 #
   6 # This merely starts up a Msg handler (and no DXChannel) ($conn in other words)
   7 # does the GET, parses out the result and the data and then (assuming a positive
   8 # result and that the originating callsign is still online) punts out the data
   9 # to the caller.
  10 #
  11 # It isn't designed to be very clever.
  12 #
  13 # Copyright (c) 2013 - Dirk Koopman G1TLH
  14 #
  15
  16 package AsyncMsg;
  17
  18 use Msg;
  19 use DXDebug;
  20 use DXUtil;
  21 use DXChannel;
  22
  23 use vars qw(@ISA $deftimeout);
  24
  25 @ISA = qw(Msg);
  26 $deftimeout = 15;
  27
  28 my %outstanding;
  29
  30 #
  31 # standard http get handler
  32 #
  33 sub handle_get
  34 {
  35         my $conn = shift;
  36         my $msg = shift;
  37
  38         my $state = $conn->{state};
  39
  40         dbg("asyncmsg: $msg") if isdbg('async');
  41
  42         # no point in going on if there is no-one wanting the output anymore
  43         my $dxchan = DXChannel::get($conn->{caller});
  44         unless ($dxchan) {
  45                 $conn->disconnect;
  46                 return;
  47         }
  48
  49         if ($state eq 'waitreply') {
  50                 # look at the reply code and decide whether it is a success
  51                 my ($http, $code, $ascii) = $msg =~ m|(HTTP/\d\.\d)\s+(\d+)\s+(.*)|;
  52                 if ($code == 200) {
  53                         # success
  54                         $conn->{state} = 'waitblank';
  55                 } else {
  56                         $dxchan->send("$code $ascii");
  57                         $conn->disconnect;
  58                 }
  59         } elsif ($state eq 'waitblank') {
  60                 unless ($msg) {
  61                         $conn->{state} = 'indata';
  62                 }
  63         } else {
  64                 if (my $filter = $conn->{filter}) {
  65                         no strict 'refs';
  66                         # this will crash if the command has been redefined and the filter is a
  67                         # function defined there whilst the request is in flight,
  68                         # but this isn't exactly likely in a production environment.
  69                         $filter->($conn, $msg, $dxchan);
  70                 } else {
  71                         my $prefix = $conn->{prefix} || '';
  72                         $dxchan->send("$prefix$msg");
  73                 }
  74         }
  75 }
  76
  77 #
  78 # simple raw handler
  79 #
  80 # Just outputs everything
  81 #
  82 sub handle_raw
  83 {
  84         my $conn = shift;
  85         my $msg = shift;
  86
  87         # no point in going on if there is no-one wanting the output anymore
  88         my $dxchan = DXChannel::get($conn->{caller});
  89         unless ($dxchan) {
  90                 $conn->disconnect;
  91                 return;
  92         }
  93
  94         # send out the data
  95         my $prefix = $conn->{prefix} || '';
  96         $dxchan->send("$prefix$msg");
  97 }
  98
  99 sub new
 100 {
 101         my $pkg = shift;
 102         my $call = shift;
 103         my $handler = shift;
 104
 105         my $conn = $pkg->SUPER::new($handler);
 106         $conn->{caller} = ref $call ? $call->call : $call;
 107
 108         # make it persistent
 109         $outstanding{$conn} = $conn;
 110
 111         return $conn;
 112 }
 113
 114 # This does a http get on a path on a host and
 115 # returns the result (through an optional filter)
 116 #
 117 # expects to be called something like from a cmd.pl file:
 118 #
 119 # AsyncMsg->get($self, <host>, <port>, <path>, [<key=>value>...]
 120 #
 121 # Standard key => value pairs are:
 122 #
 123 # filter => CODE ref (e.g. sub { ... })
 124 # prefix => <string>                 prefix output with this string
 125 #
 126 # Anything else is taken and sent as (extra) http header stuff e.g:
 127 #
 128 # 'User-Agent' => qq{DXSpider;$main::version;$main::build;$^O}
 129 # 'Content-Type' => q{text/xml; charset=utf-8}
 130 # 'Content-Length' => $lth
 131 #
 132 # Host: is always set to the name of the host (unless overridden)
 133 # User-Agent: is set to default above (unless overridden)
 134 #
 135 sub get
 136 {
 137         my $pkg = shift;
 138         my $call = shift;
 139         my $host = shift;
 140         my $port = shift;
 141         my $path = shift;
 142         my %args = @_;
 143
 144         my $filter = shift;
 145
 146         my $conn = $pkg->new($call, \&handle_get);
 147         $conn->{state} = 'waitreply';
 148         $conn->{filter} = delete $args{filter} if exists $args{filter};
 149         $conn->{prefix} = delete $args{prefix} if exists $args{prefix};
 150         $conn->{path} = $path;
 151
 152         $r = $conn->connect($host, $port);
 153         if ($r) {
 154                 dbg("Sending 'GET $path HTTP/1.0'") if isdbg('async');
 155                 $conn->send_later("GET $path HTTP/1.0\n");
 156                 my $h = delete $args{Host} || $host;
 157                 my $u = delete $args{'User-Agent'} || "DxSpider;$main::version;$main::build;$^O;$main::mycall";
 158             $conn->send_later("Host: $h\n");
 159                 $conn->send_later("User-Agent: $u\n");
 160                 while (my ($k,$v) = each %args) {
 161                         $conn->send_later("$k: $v\n");
 162                 }
 163                 $conn->send_later("\n");
 164         }
 165
 166         return $r ? $conn : undef;
 167 }
 168
 169 # do a raw connection
 170 #
 171 # Async->raw($self, <host>, <port>, [handler => CODE ref], [prefix => <string>]);
 172 #
 173 # With no handler defined, everything sent by the connection will be sent to
 174 # the caller.
 175 #
 176 # One can send stuff out on the connection by doing a standard "$conn->send_later(...)"
 177 # inside the (custom) handler.
 178
 179 sub raw
 180 {
 181         my $pkg = shift;
 182         my $call = shift;
 183         my $host = shift;
 184         my $port = shift;
 185
 186         my %args = @_;
 187
 188         my $handler = delete $args{handler} || \&handle_raw;
 189         my $conn = $pkg->new($call, $handler);
 190         $conn->{prefix} = delete $args{prefix} if exists $args{prefix};
 191         $r = $conn->connect($host, $port);
 192         return $r ? $conn : undef;
 193 }
 194
 195 sub connect
 196 {
 197         my $conn = shift;
 198         my $host = shift;
 199         my $port = shift;
 200
 201         # start a connection
 202         my $r = $conn->SUPER::connect($host, $port);
 203         if ($r) {
 204                 dbg("HTTPMsg: Connected $conn->{cnum} to $host $port") if isdbg('async');
 205         } else {
 206                 dbg("HTTPMsg: ***Connect $conn->{cnum} Failed to $host $port $!") if isdbg('async');
 207         }
 208
 209         return $r;
 210 }
 211
 212 sub disconnect
 213 {
 214         my $conn = shift;
 215         delete $outstanding{$conn};
 216         $conn->SUPER::disconnect;
 217 }
 218
 219 sub DESTROY
 220 {
 221         my $conn = shift;
 222         delete $outstanding{$conn};
 223         $conn->SUPER::DESTROY;
 224 }
 225
 226 1;
 227