perl/AGWMsg.pm

   1 #
   2 # This class is the internal subclass that deals with AGW Engine connections
   3 #
   4 # The complication here is that there only one 'real' (and from the node's point
   5 # of view, invisible) IP connection. This connection then has multiplexed
   6 # connections passed down it, a la BPQ native host ports (but not as nicely).
   7 #
   8 # It is a shame that the author has chosen an inherently dangerous binary format
   9 # which is non-framed and has the potential for getting out of sync and not
  10 # being able to recover. Relying on length fields is recipe for disaster (esp.
  11 # for him!). DoS attacks are a wonderful thing....
  12 #
  13 # Also making the user handle the distinction between a level 2 and 4 connection
  14 # and especially Digis, in the way that he has, is a bit of a cop out! If I can
  15 # be arsed to do anything other than straight ax25 connects then it will only
  16 # because I have the 'power of perl' available that avoids me getting
  17 # terminally bored sorting out other people's sloppyness.
  18 #
  19 # $Id$
  20 #
  21 # Copyright (c) 2001 - Dirk Koopman G1TLH
  22 #
  23
  24 package AGWMsg;
  25
  26 use strict;
  27 use IO::Socket;
  28 use Msg;
  29 use AGWConnect;
  30 use DXDebug;
  31
  32 use vars qw(@ISA $sock @outqueue $send_offset $inmsg $rproc $noports $lastytime
  33                         $lasthtime $ypolltime $hpolltime %circuit);
  34
  35 @ISA = qw(Msg ExtMsg);
  36 $sock = undef;
  37 @outqueue = ();
  38 $send_offset = 0;
  39 $inmsg = '';
  40 $rproc = undef;
  41 $noports = 0;
  42 $lastytime = $lasthtime = time;
  43 $ypolltime = 10 unless defined $ypolltime;
  44 $hpolltime = 300 unless defined $hpolltime;
  45 %circuit = ();
  46
  47 sub init
  48 {
  49         return unless $enable;
  50         $rproc = shift;
  51
  52         finish();
  53         dbg('err', "AGW initialising and connecting to $addr/$port ...");
  54         $sock = IO::Socket::INET->new(PeerAddr => $addr, PeerPort => $port, Proto=>'tcp', Timeout=>15);
  55         unless ($sock) {
  56                 dbg('err', "Cannot connect to AGW Engine at $addr/$port $!");
  57                 return;
  58         }
  59         Msg::blocking($sock, 0);
  60         Msg::set_event_handler($sock, read=>\&_rcv, error=>\&_error);
  61
  62         # send a P frame for the login if required
  63         if ($login) {
  64                 my $data = pack "a255 a255", $login, $passwd;
  65                 _sendf('P', undef, undef, undef, undef, $data);
  66         }
  67
  68         # send:
  69         # R frame for the release number
  70         # G frame to ask for ports
  71         # X frame to say who we are
  72         # optional m frame to enable monitoring
  73         _sendf('R');
  74         _sendf('G');
  75         _sendf('X', $main::mycall);
  76         _sendf('m') if $monitor;
  77 }
  78
  79 my $finishing = 0;
  80
  81 sub finish
  82 {
  83         return if $finishing;
  84         if ($sock) {
  85                 $finishing = 1;
  86                 dbg('err', "AGW ending...");
  87                 for (values %circuit) {
  88                         &{$_->{eproc}}() if $_->{eproc};
  89                         $_->disconnect;
  90                 }
  91                 # say we are going
  92                 _sendf('m') if $monitor;
  93                 _sendf('x', $main::mycall);
  94                 Msg->sleep(2);
  95                 Msg::set_event_handler($sock, read=>undef, write=>undef, error=>undef);
  96                 $sock->close;
  97         }
  98 }
  99
 100 sub _sendf
 101 {
 102         my $sort = shift || confess "need a valid AGW command letter";
 103         my $from = shift || '';
 104         my $to   = shift || '';
 105         my $port = shift || 0;
 106         my $pid  = shift || 0;
 107         my $data = shift || '';
 108         my $len  = 0;
 109
 110         $len = length $data;
 111         if ($sort eq 'y' || $sort eq 'H') {
 112                 dbg('agwpoll', "AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$data\"");
 113         } elsif ($sort eq 'D') {
 114                 if (isdbg('agw')) {
 115                         my $d = $data;
 116                         $d =~ s/\cM$//;
 117                         dbg('agw', "AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$d\"");
 118                 }
 119         } else {
 120                 dbg('agw', "AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$data\"");
 121         }
 122         push @outqueue, pack('C x3 a1 x1 C x1 a10 a10 V x4 a*', $port, $sort, $pid, $from, $to, $len, $data);
 123         Msg::set_event_handler($sock, write=>\&_send);
 124 }
 125
 126 sub _send
 127 {
 128     return unless $sock;
 129
 130     # If $flush is set, set the socket to blocking, and send all
 131     # messages in the queue - return only if there's an error
 132     # If $flush is 0 (deferred mode) make the socket non-blocking, and
 133     # return to the event loop only after every message, or if it
 134     # is likely to block in the middle of a message.
 135
 136     my $offset = $send_offset;
 137
 138     while (@outqueue) {
 139         my $msg            = $outqueue[0];
 140                 my $mlth           = length($msg);
 141         my $bytes_to_write = $mlth - $offset;
 142         my $bytes_written  = 0;
 143                 confess("Negative Length! msg: '$msg' lth: $mlth offset: $offset") if $bytes_to_write < 0;
 144         while ($bytes_to_write > 0) {
 145             $bytes_written = syswrite ($sock, $msg,
 146                                        $bytes_to_write, $offset);
 147             if (!defined($bytes_written)) {
 148                 if (Msg::_err_will_block($!)) {
 149                     # Should happen only in deferred mode. Record how
 150                     # much we have already sent.
 151                     $send_offset = $offset;
 152                     # Event handler should already be set, so we will
 153                     # be called back eventually, and will resume sending
 154                     return 1;
 155                 } else {    # Uh, oh
 156                                         _error();
 157                     return 0; # fail. Message remains in queue ..
 158                 }
 159             }
 160             $offset         += $bytes_written;
 161             $bytes_to_write -= $bytes_written;
 162         }
 163         $send_offset = $offset = 0;
 164         shift @outqueue;
 165         last;  # Go back to select and wait
 166                        # for it to fire again.
 167     }
 168
 169     # Call me back if queue has not been drained.
 170     if (@outqueue) {
 171         Msg::set_event_handler ($sock, write => \&_send);
 172     } else {
 173         Msg::set_event_handler ($sock, write => undef);
 174     }
 175     1;  # Success
 176 }
 177
 178 sub _rcv {                     # Complement to _send
 179     return unless $sock;
 180     my ($msg, $offset, $bytes_read);
 181
 182         $bytes_read = sysread ($sock, $msg, 1024, 0);
 183         if (defined ($bytes_read)) {
 184                 if ($bytes_read > 0) {
 185                         $inmsg .= $msg;
 186                 }
 187         } else {
 188                 if (Msg::_err_will_block($!)) {
 189                         return;
 190                 } else {
 191                         $bytes_read = 0;
 192                 }
 193     }
 194
 195 FINISH:
 196     if (defined $bytes_read && $bytes_read == 0) {
 197                 finish();
 198     } else {
 199                 _decode() if length $inmsg > 36;
 200         }
 201 }
 202
 203 sub _error
 204 {
 205         dbg('agw', "error on AGW connection $addr/$port $!");
 206         Msg::set_event_handler($sock, read=>undef, write=>undef, error=>undef);
 207         $sock = undef;
 208         for (%circuit) {
 209                 &{$_->{eproc}}() if $_->{eproc};
 210                 $_->disconnect;
 211         }
 212 }
 213
 214 sub _decode
 215 {
 216         return unless $sock;
 217
 218         # we have at least 36 bytes of data (ugh!)
 219         my ($port, $sort, $pid, $from, $to, $len) = unpack('C x3 a1 x1 C x1 Z10 Z10 V x4', $inmsg);
 220         my $data;
 221
 222         # do a sanity check on the length
 223         if ($len > 2000) {
 224                 dbg('err', "AGW: invalid length $len > 2000 received ($sort $port $pid '$from'->'$to')");
 225                 finish();
 226                 return;
 227         }
 228         if ($len == 0){
 229                 if (length $inmsg > 36) {
 230                         $inmsg = substr($inmsg, 36);
 231                 } else {
 232                         $inmsg = '';
 233                 }
 234         } elsif (length $inmsg > $len + 36) {
 235                 $data = substr($inmsg, 36, $len);
 236                 $inmsg = substr($inmsg, $len + 36);
 237         } elsif (length $inmsg == $len + 36) {
 238                 $data = substr($inmsg, 36);
 239                 $inmsg = '';
 240         } else {
 241                 # we don't have enough data or something
 242                 # or we have screwed up
 243                 return;
 244         }
 245
 246         $data = '' unless defined $data;
 247         if ($sort eq 'D') {
 248                 my $d = unpack "Z*", $data;
 249                 $d =~ s/\cM$//;
 250                 dbg('agw', "AGW Data In port: $port pid: $pid '$from'->'$to' length: $len \"$d\"");
 251                 my $conn = _find($from eq $main::mycall ? $to : $from);
 252                 if ($conn) {
 253                         if ($conn->{state} eq 'WC') {
 254                                 if (exists $conn->{cmd}) {
 255                                         if (@{$conn->{cmd}}) {
 256                                                 dbg('connect', $d);
 257                                                 $conn->_docmd($d);
 258                                         }
 259                                 }
 260                                 if ($conn->{state} eq 'WC' && exists $conn->{cmd} && @{$conn->{cmd}} == 0) {
 261                                         $conn->to_connected($conn->{call}, 'O', $conn->{csort});
 262                                 }
 263                         } else {
 264                                 my @lines = split /\cM/, $data;
 265                                 if (@lines) {
 266                                         for (@lines) {
 267                                                 &{$conn->{rproc}}($conn, "I$conn->{call}|$_");
 268                                         }
 269                                 } else {
 270                                         &{$conn->{rproc}}($conn, "I$conn->{call}|");
 271                                 }
 272                         }
 273                 } else {
 274                         dbg('err', "AGW error Unsolicited Data!");
 275                 }
 276         } elsif ($sort eq 'I' || $sort eq 'S' || $sort eq 'U' || $sort eq 'M' || $sort eq 'T') {
 277                 my $d = unpack "Z*", $data;
 278                 $d =~ s/\cM$//;
 279                 my @lines = split /\cM/, $d;
 280
 281                 for (@lines) {
 282                         s/([\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 283                         dbg('agw', "AGW Monitor port: $port \"$_\"");
 284                 }
 285         } elsif ($sort eq 'C') {
 286                 my $d = unpack "Z*", $data;
 287                 $d =~ s/\cM$//;
 288                 dbg('agw', "AGW Connect port: $port pid: $pid '$from'->'$to' \"$d\"");
 289                 my $call = $from eq $main::mycall ? $to : $from;
 290                 my $conn = _find($call);
 291                 if ($conn) {
 292                         if ($conn->{state} eq 'WC') {
 293                                 if (exists $conn->{cmd} && @{$conn->{cmd}}) {
 294                                         $conn->_docmd($d);
 295                                         if ($conn->{state} eq 'WC' && exists $conn->{cmd} &&  @{$conn->{cmd}} == 0) {
 296                                                 $conn->to_connected($conn->{call}, 'O', $conn->{csort});
 297                                         }
 298                                 }
 299                         }
 300                 } else {
 301                         $conn = AGWMsg->new($rproc);
 302                         $conn->{agwpid} = $pid;
 303                         $conn->{agwport} = $port;
 304                         $conn->{lineend} = "\cM";
 305                         $conn->{incoming} = 1;
 306                         $conn->{agwcall} = $call;
 307                         $circuit{$call} = $conn;
 308                         if ($call =~ /^(\w+)-(\d\d?)$/) {
 309                                 my $c = $1;
 310                                 my $s = $2;
 311                                 $s = 15 - $s;
 312                                 if ($s <= 8 && $s > 0) {
 313                                         $call = "${c}-${s}";
 314                                 } else {
 315                                         $call = $c;
 316                                 }
 317                         }
 318                         $conn->to_connected($call, 'A', $conn->{csort} = 'ax25');
 319                 }
 320         } elsif ($sort eq 'd') {
 321                 dbg('agw', "AGW '$from'->'$to' port: $port Disconnected");
 322                 my $conn = _find($from eq $main::mycall ? $to : $from);
 323                 if ($conn) {
 324                         &{$conn->{eproc}}() if $conn->{eproc};
 325                         $conn->in_disconnect;
 326                 }
 327         } elsif ($sort eq 'y') {
 328                 my ($frames) = unpack "V", $data;
 329                 dbg('agwpollans', "AGW Frames Outstanding on port $port = $frames");
 330                 my $conn = _find($from);
 331                 $conn->{oframes} = $frames if $conn;
 332         } elsif ($sort eq 'Y') {
 333                 my ($frames) = unpack "V", $data;
 334                 dbg('agw', "AGW Frames Outstanding on circuit '$from'->'$to' = $frames");
 335                 my $conn = _find($from eq $main::mycall ? $to : $from);
 336                 $conn->{oframes} = $frames if $conn;
 337         } elsif ($sort eq 'H') {
 338                 unless ($from =~ /^\s+$/) {
 339                         my $d = unpack "Z*", $data;
 340                         $d =~ s/\cM$//;
 341                         dbg('agw', "AGW Heard port: $port \"$d\"");
 342                 }
 343         } elsif ($sort eq 'X') {
 344                 my ($r) = unpack "C", $data;
 345                 $r = $r ? "Successful" : "Failed";
 346                 dbg('err', "AGW Register $from $r");
 347                 finish() unless $r;
 348         } elsif ($sort eq 'R') {
 349                 my ($major, $minor) = unpack "v x2 v x2", $data;
 350                 dbg('agw', "AGW Version $major.$minor");
 351         } elsif ($sort eq 'G') {
 352                 my @ports = split /;/, $data;
 353             $noports = shift @ports || '0';
 354                 dbg('agw', "AGW $noports Ports available");
 355                 pop @ports while @ports > $noports;
 356                 for (@ports) {
 357                         next unless $_;
 358                         dbg('agw', "AGW Port: $_");
 359                 }
 360                 for (my $i = 0; $i < $noports; $i++) {
 361                         _sendf('y', undef, undef, $i );
 362                 }
 363         } else {
 364                 my $d = unpack "Z*", $data;
 365                 dbg('agw', "AGW decode $sort port: $port pid: $pid '$from'->'$to' length: $len \"$d\"");
 366         }
 367 }
 368
 369 sub _find
 370 {
 371         my $call = shift;
 372         return $circuit{$call};
 373 }
 374
 375 sub connect
 376 {
 377         my ($conn, $line) = @_;
 378
 379         my ($port, $call) = split /\s+/, $line;
 380         $conn->{agwpid} = ord "\xF0";
 381         $conn->{agwport} = $port - 1;
 382         $conn->{lineend} = "\cM";
 383         $conn->{incoming} = 0;
 384         $conn->{csort} = 'ax25';
 385         $conn->{agwcall} = uc $call;
 386         $circuit{$conn->{agwcall}} = $conn;
 387
 388         _sendf('C', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid});
 389         $conn->{state} = 'WC';
 390
 391         return 1;
 392 }
 393
 394 sub in_disconnect
 395 {
 396         my $conn = shift;
 397         delete $circuit{$conn->{agwcall}};
 398         $conn->SUPER::disconnect;
 399 }
 400
 401 sub disconnect
 402 {
 403         my $conn = shift;
 404         delete $circuit{$conn->{agwcall}};
 405         if ($conn->{incoming}) {
 406                 _sendf('d', $conn->{agwcall}, $main::mycall, $conn->{agwport}, $conn->{agwpid});
 407         } else {
 408                 _sendf('d', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid});
 409         }
 410         $conn->SUPER::disconnect;
 411 }
 412
 413 sub enqueue
 414 {
 415         my ($conn, $msg) = @_;
 416         if ($msg =~ /^D/) {
 417                 $msg =~ s/^[-\w]+\|//;
 418 #               _sendf('Y', $main::mycall, $conn->{call}, $conn->{agwport}, $conn->{agwpid});
 419                 _sendf('D', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid}, $msg . $conn->{lineend});
 420                 my $len = length($msg) + 1;
 421                 dbg('agw', "AGW Data Out port: $conn->{agwport} pid: $conn->{agwpid} '$main::mycall'->'$conn->{agwcall}' length: $len \"$msg\"");
 422         }
 423 }
 424
 425 sub process
 426 {
 427         return unless $sock;
 428         if ($ypolltime && $main::systime - $lastytime >= $ypolltime) {
 429                 for (my $i = 0; $i < $noports; $i++) {
 430                         _sendf('y', undef, undef, $i );
 431                 }
 432                 $lastytime = $main::systime;
 433         }
 434         if ($hpolltime && $main::systime - $lasthtime >= $hpolltime) {
 435                 for (my $i = 0; $i < $noports; $i++) {
 436                         _sendf('H', undef, undef, $i );
 437                 }
 438                 $lasthtime = $main::systime;
 439         }
 440 }
 441
 442 1;
 443